В процессе загрузки ресурсов... загрузка...

Стратегия вывода средств EMA

Автор:Чао Чжан, Дата: 21-12-2023 11:48:54
Тэги:

Обзор

Стратегия EMA pullback - это количественная стратегия торговли, основанная на индикаторе EMA. Она конструирует торговые сигналы с использованием трех кривых EMA с различными периодами и устанавливает стоп-лосс и прибыль на основе ценовых pullbacks для автоматизации торговли.

Принцип стратегии

Стратегия использует три кривые EMA:

EMA1: для оценки уровня поддержки/сопротивления ценового отступления, с относительно коротким периодом, дефолт до 33 периодов.
EMA2: для фильтрации некоторых сигналов обворота, с периодом 5 раз больше EMA1, по умолчанию до 165 периодов.
EMA3: для определения общего направления тренда, с периодом 11 раз больше EMA1, по умолчанию до 365 периодов.

Торговые сигналы генерируются согласно следующей логике:

Долгий сигнал: цена пересекает верхнюю часть ЕМА1, отступает ниже ЕМА1, образуя более высокие минимумы, при этом откат не достигает ЕМА2.

Короткий сигнал: цена пересекает ниже EMA1, отступает выше EMA1, образуя более низкие максимумы, при этом откат не достигает EMA2.

Стоп-лосс устанавливается на минимальной/максимальной цене pullback для длинного/короткого.

Преимущества стратегии

Стратегия имеет следующие преимущества:

Торговые сигналы, построенные с использованием надежного индикатора EMA.
Снижение цен эффективно избегает ловушки.
Стоп-потеря, установленная на предыдущих высоких/низких контролях риска эффективно.
Принимать прибыль, удовлетворяющее соотношение риск-вознаграждение.
Параметры EMA регулируются для различных циклов.

Стратегические риски

Стратегия также сопряжена с некоторыми рисками:

EMA имеет эффект задержки, может пропустить точки переворота тренда.
Слишком большой диапазон отклонения, превышающий EMA2, может вызвать ложные сигналы.
Стоп-лосс может быть нарушен на трендовых рынках.
Неправильное настройка параметров приводит к чрезмерной торговле или упущенным возможностям.

Риски могут быть смягчены путем корректировки периодов EMA, лимита обратного движения и т. д. Другие показатели также могут быть добавлены к сигналам фильтра.

Руководство по оптимизации

Стратегия также может быть оптимизирована в следующих аспектах:

Добавить индикатор тренда, чтобы избежать торговли с противоположным трендом, например MACD.
Добавить индикатор объема торговли для предотвращения ложного прорыва, например OBV.
Оптимизировать периоды EMA или использовать адаптивную EMA.
Динамически оптимизируйте параметры с помощью моделей машинного обучения, таких как мешок слов.
Добавьте модель предсказания для адаптивной остановки потери и получения прибыли.

Заключение

Стратегия EMA Pullback создает торговую систему с использованием трех EMA и устанавливает стоп-потери и получает прибыль на основе ценовых pullbacks для автоматизации торговли. Она эффективно контролирует торговые риски и может быть оптимизирована путем корректировки параметров на основе рыночных условий.

/*backtest
start: 2023-11-20 00:00:00
end: 2023-12-20 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// created by Space Jellyfish
//@version=4

strategy("EMA pullback strategy", overlay = true, initial_capital=10000, commission_value = 0.075)

target_stop_ratio = input(title="Take Profit Stop Loss ratio", type=input.float, defval=2.06, minval=0.5, maxval=100)
riskLimit_low =  input(title="lowest risk per trade", type=input.float, defval=0.008, minval=0, maxval=100)
riskLimit_high =  input(title="highest risk per trade", type=input.float, defval=0.02, minval=0, maxval=100)
//give up the trade, if the risk is smaller than limit, adjust position size if risk is bigger than limit

ema_pullbackLevel_period = input(title="EMA1 for pullback level Period", type=input.integer, defval=33, minval=1, maxval=10000)
ema_pullbackLimiit_period = input(title="EMA2 for pullback limit Period", type=input.integer, defval=165, minval=1, maxval=10000)
ema_trend_period = input(title="EMA3 for trend Period", type=input.integer, defval=365, minval=1, maxval=10000)

startDate = input(title="Start Date", type=input.integer, defval=1, minval=1, maxval=31)
startMonth = input(title="Start Month", type=input.integer, defval=1, minval=1, maxval=12)
startYear = input(title="Start Year", type=input.integer, defval=2018, minval=2008, maxval=2200)

inDateRange = (time >= timestamp(syminfo.timezone, startYear, startMonth, startDate, 0, 0))

ema_pullbackLevel = ema(close, ema_pullbackLevel_period)
ema_pullbackLimit = ema(close, ema_pullbackLimiit_period)
ema_trendDirection = ema(close, ema_trend_period)

//ema pullback 
float pricePullAboveEMA_maxClose = na
float pricePullAboveEMA_maxHigh = na

float pricePullBelowEMA_minClose = na
float pricePullBelowMA_minLow = na

if(crossover(close, ema_pullbackLevel))
    pricePullAboveEMA_maxClose := close
    pricePullAboveEMA_maxHigh := high
else
    pricePullAboveEMA_maxClose := pricePullAboveEMA_maxClose[1]
    pricePullAboveEMA_maxHigh := pricePullAboveEMA_maxHigh[1]

if(close > pricePullAboveEMA_maxClose)
    pricePullAboveEMA_maxClose := close
if(high > pricePullAboveEMA_maxHigh)
    pricePullAboveEMA_maxHigh := high

if(crossunder(close, ema_pullbackLevel))
    pricePullBelowEMA_minClose := close
    pricePullBelowMA_minLow := low
else
    pricePullBelowEMA_minClose :=pricePullBelowEMA_minClose[1]
    pricePullBelowMA_minLow:=pricePullBelowMA_minLow[1]
    
if(close < pricePullBelowEMA_minClose)
    pricePullBelowEMA_minClose := close
if(low < pricePullBelowMA_minLow)
    pricePullBelowMA_minLow := low


long_strategy = crossover(close, ema_pullbackLevel) and pricePullBelowEMA_minClose < ema_pullbackLimit and ema_pullbackLevel>ema_trendDirection 
short_strategy = crossunder(close, ema_pullbackLevel) and pricePullAboveEMA_maxClose > ema_pullbackLimit and ema_pullbackLevel<ema_trendDirection


var open_long_or_short = 0// long = 10000, short = -10000, no open = 0

//check if position is closed
if(strategy.position_size == 0)
    open_long_or_short := 0
else
    open_long_or_short := open_long_or_short[1]

float risk_long = na
float risk_short = na
float stopLoss = na
float takeProfit = na
float entry_price = na

float entryContracts = 0



risk_long := risk_long[1]
risk_short := risk_short[1]
    
//open a position determine the position size
if (strategy.position_size == 0 and long_strategy and inDateRange)
    risk_long := (close - pricePullBelowMA_minLow) / close

    if(risk_long < riskLimit_high)
        entryContracts := strategy.equity / close
    else
        entryContracts := (strategy.equity * riskLimit_high / risk_long)/close
    
    if(risk_long > riskLimit_low)
        strategy.entry("long", strategy.long, qty = entryContracts, when = long_strategy)


    open_long_or_short := 10000
    
if (strategy.position_size == 0 and short_strategy and inDateRange)
    risk_short := (pricePullAboveEMA_maxHigh - close) / close
    if(risk_short < riskLimit_high)
        entryContracts := strategy.equity / close
    else
        entryContracts := (strategy.equity * riskLimit_high / risk_short)/close

    if(risk_short > riskLimit_low)
        strategy.entry("short", strategy.short, qty = entryContracts, when = short_strategy)

    
    open_long_or_short := -10000

//take profit / stop loss
if(open_long_or_short == 10000)

    stopLoss :=   strategy.position_avg_price*(1 - risk_long)
    takeProfit :=  strategy.position_avg_price*(1 + target_stop_ratio * risk_long)
    entry_price := strategy.position_avg_price
    strategy.exit("Long exit","long", limit = takeProfit , stop = stopLoss)
    
if(open_long_or_short == -10000)
    stopLoss :=  strategy.position_avg_price*(1 + risk_short)
    takeProfit :=  strategy.position_avg_price*(1 - target_stop_ratio * risk_short)
    entry_price := strategy.position_avg_price
    strategy.exit("Short exit","short", limit = takeProfit, stop = stopLoss)



plot(ema_pullbackLevel, color=color.aqua,  title="ema pullback level")
plot(ema_pullbackLimit, color=color.purple,  title="ema pullback limit")
plot(ema_trendDirection, color=color.white,  title="ema trend")

plot(entry_price, color = color.yellow, linewidth = 1, style = plot.style_linebr)
plot(stopLoss, color = color.red, linewidth = 1, style = plot.style_linebr)
plot(takeProfit, color = color.green, linewidth = 1, style = plot.style_linebr)





//

Больше