FMZ PINE اسکرپٹ Doc

t قدر NaN ہے.

• trail_price(سیریز انٹ / فلوٹ) ایک اختیاری دلیل۔ ٹریلنگ اسٹاپ ایکٹیویشن لیول (ایک مخصوص قیمت کی ضرورت ہوتی ہے) ۔ اگر اس کی وضاحت کی گئی ہے تو ، جب مخصوص قیمت کی سطح تک پہنچ جائے تو ٹریلنگ اسٹاپ آرڈر دیا جائے گا۔ ٹریلنگ اسٹاپ آرڈر کی ابتدائی قیمت کا تعین کرنے کے لئے آفسیٹ (ٹِکس میں) ٹریل_آفسٹ دلیل میں بیان کیا گیا ہے۔ طویل پوزیشن سے باہر نکلنے کے لئے ایکٹیویشن لیول سے کم ایکس ٹِکس؛ مختصر پوزیشن سے باہر نکلنے کے لئے ایکٹیویشن لیول سے زیادہ ایکس ٹِکس۔ ڈیفالٹ قیمت NaN ہے۔
• trail_points(سیریز انٹ / فلوٹ) ایک اختیاری دلیل۔ ٹریلنگ اسٹاپ ایکٹیویشن لیول (ٹکس میں بیان کردہ منافع) ۔ اگر یہ مخصوص کیا گیا ہے تو ، حساب کتاب کی قیمت کی سطح (مخصوص منافع کی رقم) تک پہنچنے پر ٹریلنگ اسٹاپ آرڈر لگایا جائے گا۔ ٹریلنگ اسٹاپ آرڈر کی ابتدائی قیمت کا تعین کرنے کے لئے آفسیٹ (ٹکس میں) ٹریل_آفسٹ دلیل میں بیان کیا گیا ہے۔ X ٹکس طویل پوزیشن سے باہر نکلنے کے لئے ایکٹیویشن لیول سے کم ہیں؛ X ٹکس مختصر پوزیشن سے باہر نکلنے کے لئے ایکٹیویشن لیول سے زیادہ ہیں۔ ڈیفالٹ قیمت NaN ہے۔
• trail_offset(سیریز انٹ / فلوٹ) ایک اختیاری دلیل۔ ٹریلنگ اسٹاپ کی قیمت (ٹکس میں بیان کردہ) ۔ ٹریلنگ اسٹاپ آرڈر کی ابتدائی قیمت کا تعین کرنے کے لئے ٹکس میں آفسیٹ: طویل پوزیشن سے باہر نکلنے کے لئے ٹریل_پریس یا ٹریل_پوائنٹس سے کم ایکس ٹکس۔ مختصر پوزیشن سے باہر نکلنے کے لئے ٹریل_پریس یا ٹریل_پوائنٹس سے زیادہ ایکس ٹکس۔ ڈیفالٹ قیمت NaN ہے۔
• oca_name(سیریز سٹرنگ) ایک اختیاری دلیل۔ او سی اے گروپ کا نام (oca_type = strategy.oca.reduce) منافع کا ہدف ، اسٹاپ نقصان / ٹریلنگ اسٹاپ آرڈرز کا تعلق ہے۔ اگر نام متعین نہیں کیا گیا ہے تو ، یہ خود بخود تیار ہوجائے گا۔نوٹ کریں کہ ایف ایم زیڈ اس دلیل کی حمایت نہیں کرتا ہے۔
• comment(سلسلہ تار) ایک اختیاری دلیل. حکم کے لئے اضافی ہدایات.
• when(سیریز بول) ایک اختیاری دلیل۔ آرڈر کی شرط۔ اگر شرط true ہے۔ اگر شرط false ہے تو ، کچھ نہیں ہوتا ہے (اس سے پہلے رکھی گئی آرڈر اسی ID کے ساتھ منسوخ نہیں ہوتی ہے۔ ڈیفالٹ ویلیو true ہے۔
• alert_message(سیریز سٹرنگ) جب آپ {{strategy.order.alert_message}} کو استعمال کرتے ہیں تو ایک اختیاری دلیل Message فیلڈ میں Create Alert ڈائیلاگ۔

strategy.cancel

یہ ایک کمانڈ ہے جس میں زیر التواء احکامات کو منسوخ / غیر فعال کرنے کے لئے ان کے ناموں کا حوالہ دیتے ہوئے ، جو افعال کے ذریعہ تیار کیے گئے تھے: حکمت عملی.آرڈر ، حکمت عملی.انٹری اورstrategy.exit.

strategy.cancel(id, when) 

مثال

strategy(title = "simple order cancellation example")
conditionForBuy = open > high[1]
strategy.entry("long", strategy.long, 1, limit = low, when = conditionForBuy) // enter long using limit order at low price of current bar if conditionForBuy is true
strategy.cancel("long", when = not conditionForBuy) // cancel the entry order with name "long" if conditionForBuy is false

دلائل

• id(سیریز سٹرنگ) ایک مطلوبہ دلیل۔ آرڈر کا شناخت کنندہ۔ اس کے شناخت کنندہ کا حوالہ دے کر آرڈر کو منسوخ کرنا ممکن ہے۔
• when(سیریز bool) ایک اختیاری دلیل۔ مخصوص ID کے ساتھ آرڈر منسوخ کرنے کی شرط۔ اگر شرط true ہے تو ، مخصوص ID کے ساتھ آرڈر منسوخ ہوجائے گا۔ ڈیفالٹ ویلیو true ہے۔

حکمت عملی.cancel_all

یہ تمام زیر التواء احکامات کو منسوخ / غیر فعال کرنے کے لئے ایک کمانڈ ہے، جو افعال کی طرف سے پیدا کیا گیا تھا: حکمت عملی.order، حکمت عملی.entry اورstrategy.exit.

strategy.cancel_all(when) 

مثال

strategy(title = "simple all orders cancellation example")
conditionForBuy1 = open > high[1]
strategy.entry("long entry 1", strategy.long, 1, limit = low, when = conditionForBuy1) // enter long by limit if conditionForBuy1 is true
conditionForBuy2 = conditionForBuy1 and open[1] > high[2]
strategy.entry("long entry 2", strategy.long, 1, limit = ta.lowest(low, 2), when = conditionForBuy2) // enter long by limit if conditionForBuy2 is true
conditionForStopTrading = open < ta.lowest(low, 2)
strategy.cancel_all(conditionForStopTrading) // cancel both limit orders if the conditon conditionForStopTrading is true

دلائل

• when(سیریز بول) ایک اختیاری دلیل۔ تمام احکامات کو منسوخ کرنے کی شرط۔ اگر شرط درست ہے تو ، پھر تمام فعال احکامات منسوخ ہوجائیں گے۔ ڈیفالٹ ویلیو true ہے۔

strategy.order

یہ آرڈر دینے کا ایک کمانڈ ہے۔ اگر ایک ہی آئی ڈی والا آرڈر پہلے ہی زیر التواء ہے تو ، آرڈر میں ترمیم کرنا ممکن ہے۔ اگر مخصوص آئی ڈی والا کوئی آرڈر نہیں ہے تو ، ایک نیا آرڈر دیا جاتا ہے۔ آرڈر کو غیر فعال کرنے کے لئے ، کمانڈ strategy.cancel یا strategy.cancel_all استعمال کرنا چاہئے۔ فنکشن strategy.entry کے مقابلے میں ، فنکشن strategy.order پر اہرام سازی کا اثر نہیں پڑتا ہے۔ اگر دونوں حد اور stop پیرامیٹر NaN ہیں تو ، آرڈر کی قسم مارکیٹ آرڈر ہے۔

strategy.order(id, direction, qty, limit, stop, oca_name, oca_type, comment, when, alert_message)

مثال

strategy(title = "simple strategy order example")
strategy.order("buy", strategy.long, 1, when = open > high[1]) // buy by market if current open great then previous high
strategy.order("sell", strategy.short, 1, when = open < low[1]) // sell by market if current open less then previous low

دلائل

• id(سیریز سٹرنگ) ایک مطلوبہ پیرامیٹر۔ آرڈر کا شناخت کنندہ۔ اس کے شناخت کنندہ کا حوالہ دے کر آرڈر کو منسوخ یا تبدیل کرنا ممکن ہے۔
• direction(strategy_direction) ایک مطلوبہ پیرامیٹر۔ آرڈر کی سمت: strategy.long خریدنے کے لئے ہے، strategy.short فروخت کے لئے ہے.
• qty(سیریز انٹ / فلوٹ) ایک اختیاری پیرامیٹر۔ تجارت کے لئے معاہدوں / حصص / لاٹس / یونٹوں کی تعداد۔ ڈیفالٹ قیمت NaN ہے۔
• limit(سیریز انٹ / فلوٹ) ایک اختیاری پیرامیٹر۔ آرڈر کی حد کی قیمت۔ اگر یہ مخصوص ہے تو ، آرڈر کی قسم یا تو ہے حد، یا اسٹاپ-حد۔ کسی بھی دوسری آرڈر کی قسم کے لئے NaN کی وضاحت کی جانی چاہئے۔
• stop(سیریز انٹ / فلوٹ) ایک اختیاری پیرامیٹر۔ آرڈر کی اسٹاپ قیمت۔ اگر یہ مخصوص ہے تو ، آرڈر کی قسم یا تو اسٹاپ ، یا اسٹاپ-حد ہے۔ کسی بھی دوسری آرڈر کی قسم کے لئے NaN کی وضاحت کی جانی چاہئے۔
• oca_name(سیریز سٹرنگ) ایک اختیاری پیرامیٹر۔ OCA گروپ کا نام جس کا آرڈر ہے۔ اگر آرڈر کسی خاص OCA گروپ سے تعلق نہیں رکھنا چاہئے تو ، ایک خالی سٹرنگ ہونی چاہئے۔نوٹ کریں کہ ایف ایم زیڈ اس دلیل کی حمایت نہیں کرتا ہے۔
• oca_type(ان پٹ سٹرنگ) ایک اختیاری پیرامیٹر۔ او سی اے گروپ کی قسم۔ اجازت شدہ اقدار یہ ہیں: strategy.oca.none - آرڈر کسی خاص او سی اے گروپ سے تعلق نہیں رکھنا چاہئے۔ strategy.oca.cancel - آرڈر او سی اے گروپ سے تعلق رکھنا چاہئے ، جہاں جیسے ہی کوئی آرڈر پورا ہوتا ہے ، اسی گروپ کے تمام دوسرے آرڈر منسوخ ہوجاتے ہیں۔ strategy.oca.reduce - آرڈر او سی اے گروپ سے تعلق رکھنا چاہئے ، جہاں اگر کسی آرڈر کے ایکس معاہدوں کی تعداد پوری ہوجاتی ہے تو ، اسی او سی اے گروپ کے ہر دوسرے آرڈر کے لئے معاہدوں کی تعداد ایکس سے کم ہوجاتی ہے۔نوٹ کریں کہ ایف ایم زیڈ اس دلیل کی حمایت نہیں کرتا ہے۔
• comment(سیریز سٹرنگ) ایک اختیاری پیرامیٹر. آرڈر پر اضافی نوٹ.
• when(سلسلہ bool) ایک اختیاری پیرامیٹر۔ آرڈر کی شرط۔ اگر شرط true ہے تو آرڈر رکھا جاتا ہے۔ اگر شرط false ہے تو ، کچھ بھی نہیں ہوتا ہے (اس سے پہلے رکھی گئی آرڈر کو اسی ID کے ساتھ منسوخ نہیں کیا جاتا ہے۔ ڈیفالٹ ویلیو true ہے۔
• alert_message(سیریز سٹرنگ) ایک اختیاری پیرامیٹر جو {{strategy.order.alert_message}} پلیس ہولڈر کی جگہ لیتا ہے جب اسے Create Alert ڈائیلاگ باکس s Message فیلڈ میں استعمال کیا جاتا ہے۔

حکمت عملی.اوپن ٹریڈز.انٹری_بار_انڈیکس

کھلی تجارت کی اندراج کا بار_انڈیکس لوٹاتا ہے۔

strategy.opentrades.entry_bar_index(trade_num)

10 بار کے لئے انتظار کریں اور پوزیشن کو بند.

مثال

strategy("`strategy.opentrades.entry_bar_index` Example")

barsSinceLastEntry() =>
    strategy.opentrades > 0 ? bar_index - strategy.opentrades.entry_bar_index(strategy.opentrades - 1) : na

// Enter a long position if there are no open positions.
if strategy.opentrades == 0
    strategy.entry("Long",  strategy.long)

// Close the long position after 10 bars. 
if barsSinceLastEntry() >= 10
    strategy.close("Long")

دلائل

• trade_num(سیریز int) کھلی تجارت کا ٹرانزیکشن نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.closedtrades.entry_bar_index strategy.closedtrades.exit_bar_index

حکمت عملی.اوپن ٹریڈز.انٹری_آئی ڈی

کھلی تجارت کی اندراج کی شناخت لوٹاتا ہے.

strategy.opentrades.entry_id(trade_num)

مثال

strategy("`strategy.opentrades.entry_id` Example", overlay = true)

// We enter a long position when 14 period sma crosses over 28 period sma.
// We enter a short position when 14 period sma crosses under 28 period sma.
longCondition = ta.crossover(ta.sma(close, 14), ta.sma(close, 28))
shortCondition = ta.crossunder(ta.sma(close, 14), ta.sma(close, 28))

// Strategy calls to enter a long or short position when the corresponding condition is met.
if longCondition
    strategy.entry("Long entry at bar #" + str.tostring(bar_index), strategy.long)
if shortCondition
    strategy.entry("Short entry at bar #" + str.tostring(bar_index), strategy.short)

// Display ID of the latest open position.
if barstate.islastconfirmedhistory
    runtime.log("Last opened position is " + strategy.opentrades.entry_id(strategy.opentrades - 1))

واپسیکھلی تجارت کی اندراج کی شناخت لوٹاتا ہے.

دلائل

• trade_num(سیریز int) کھلی تجارت کا ٹرانزیکشن نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

تبصرےفنکشن واپسی na اگر trade_num رینج میں نہیں ہے: 0 کرنے کے لئے strategy.opentrades-1.

یہ بھی ملاحظہ کریں strategy.opentrades.entry_bar_index strategy.opentrades.entry_time

حکمت عملی.اوپن ٹریڈز.اندراج_قیمت

کھلی تجارت کی اندراج کی قیمت لوٹاتا ہے۔

strategy.opentrades.entry_price(trade_num)

مثال

strategy("strategy.closedtrades.entry_price Example 1")

// Strategy calls to enter long trades every 15 bars and exit long trades every 20 bars.
if bar_index % 15 == 0
    strategy.entry("Long", strategy.long)
if bar_index % 20 == 0
    strategy.close("Long")

// Return the entry price for the latest closed trade.
entryPrice = strategy.closedtrades.entry_price(strategy.closedtrades - 1)

plot(entryPrice, "Long entry price")

اوسط کھلی پوزیشن کی قیمت کا حساب لگائیں۔

مثال

strategy("strategy.opentrades.entry_price Example 2", pyramiding = 2)

// Strategy calls to enter long trades every 15 bars and exit long trades every 20 bars.
if bar_index % 15 == 0
    strategy.entry("Long", strategy.long)
if bar_index % 20 == 0
    strategy.close("Long")

// Calculate average open position price.
avgOpenPositionPrice() =>
    sumOpenPositionPrice = 0.0
    for tradeNo = 0 to strategy.opentrades - 1
        sumOpenPositionPrice += strategy.opentrades.entry_price(tradeNo) * strategy.opentrades.size(tradeNo) / strategy.position_size
    result = nz(sumOpenPositionPrice / strategy.opentrades)

plot(avgOpenPositionPrice())

دلائل

• trade_num(سیریز int) کھلی تجارت کا ٹرانزیکشن نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.closedtrades.exit_price

حکمت عملی.اوپن ٹریڈز.انٹری_ٹائم

کھلی تجارت کے اندراج کا UNIX وقت لوٹاتا ہے۔

strategy.opentrades.entry_time(trade_num)

مثال

strategy("strategy.opentrades.entry_time Example")

// Strategy calls to enter long trades every 15 bars and exit long trades every 20 bars.
if bar_index % 15 == 0
    strategy.entry("Long", strategy.long)
if bar_index % 20 == 0
    strategy.close("Long")

// Calculates duration in milliseconds since the last position was opened.
timeSinceLastEntry()=>
    strategy.opentrades > 0 ? (time - strategy.opentrades.entry_time(strategy.opentrades - 1)) : na

plot(timeSinceLastEntry() / 1000 * 60 * 60 * 24, "Days since last entry")

دلائل

• trade_num(سیریز int) کھلی تجارت کا ٹرانزیکشن نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.closedtrades.entry_time strategy.closedtrades.exit_time

strategy.opentrades.profit

کھلی تجارت کا منافع / نقصان واپس کرتا ہے۔ نقصانات منفی اقدار کے طور پر ظاہر ہوتے ہیں۔

strategy.opentrades.profit(trade_num)

آخری کھلی ہوئی تجارت کا منافع واپس کریں۔

مثال

strategy("`strategy.opentrades.profit` Example 1", commission_type = strategy.commission.percent, commission_value = 0.1)

// Strategy calls to enter long trades every 15 bars and exit long trades every 20 bars.
if bar_index % 15 == 0
    strategy.entry("Long", strategy.long)
if bar_index % 20 == 0
    strategy.close("Long")

plot(strategy.opentrades.profit(strategy.opentrades - 1), "Profit of the latest open trade")

تمام کھلی پوزیشنوں کے منافع کا حساب لگائیں۔

مثال

strategy("`strategy.opentrades.profit` Example 2", pyramiding = 5)

// Strategy calls to enter 5 long positions every 2 bars.
if bar_index % 2 == 0
    strategy.entry("Long", strategy.long, qty = 5)

// Calculate open profit or loss for the open positions.
tradeOpenPL() =>
    sumProfit = 0.0
    for tradeNo = 0 to strategy.opentrades - 1
        sumProfit += strategy.opentrades.profit(tradeNo)
    result = sumProfit
    
plot(tradeOpenPL(), "Profit of all open trades")

دلائل

• trade_num(سیریز int) کھلی تجارت کا ٹرانزیکشن نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.closedtrades.profit strategy.openprofit strategy.netprofit strategy.grossprofit

strategy.opentrades.size

کھلی تجارت میں تجارت کی جانے والی معاہدوں کی سمت اور تعداد واپس کرتا ہے۔ اگر قیمت > 0 ہے تو ، مارکیٹ کی پوزیشن لمبی تھی۔ اگر قیمت < 0 ہے تو ، مارکیٹ کی پوزیشن مختصر تھی۔

strategy.opentrades.size(trade_num)

مثال

strategy("`strategy.opentrades.size` Example 1")

// We calculate the max amt of shares we can buy.
amtShares = math.floor(strategy.equity / close)
// Strategy calls to enter long trades every 15 bars and exit long trades every 20 bars
if bar_index % 15 == 0
    strategy.entry("Long", strategy.long, qty = amtShares)
if bar_index % 20 == 0
    strategy.close("Long")

// Plot the number of contracts in the latest open trade.
plot(strategy.opentrades.size(strategy.opentrades - 1), "Amount of contracts in latest open trade")

کھلی پوزیشنوں کا اوسط منافع کا فیصد شمار کریں۔

مثال

strategy("`strategy.opentrades.size` Example 2")

// Strategy calls to enter long trades every 15 bars and exit long trades every 20 bars.
if bar_index % 15 == 0
    strategy.entry("Long", strategy.long)
if bar_index % 20 == 0
    strategy.close("Long")

// Calculate profit for all open trades.
profitPct = 0.0
for tradeNo = 0 to strategy.opentrades - 1
    entryP = strategy.opentrades.entry_price(tradeNo)
    exitP = close
    profitPct += (exitP - entryP) / entryP * strategy.opentrades.size(tradeNo) * 100
    
// Calculate average profit percent for all open trades.
avgProfitPct = nz(profitPct / strategy.opentrades)

دلائل

• trade_num(سیریز int) کھلی تجارت کا ٹرانزیکشن نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.closedtrades.size strategy.position_size strategy.opentrades strategy.closedtrades

حکمت عملی۔ بند تجارت۔ اندراج_بار_انڈیکس

بند تجارت کی اندراج کا بار_انڈیکس لوٹاتا ہے۔

strategy.closedtrades.entry_bar_index(trade_num)

مثال

strategy("strategy.closedtrades.entry_bar_index Example")
// Enter long trades on three rising bars; exit on two falling bars.
if ta.rising(close, 3)
    strategy.entry("Long", strategy.long)
if ta.falling(close, 2)
    strategy.close("Long")
// Function that calculates the average amount of bars in a trade.
avgBarsPerTrade() =>
    sumBarsPerTrade = 0
    for tradeNo = 0 to strategy.closedtrades - 1
        // Loop through all closed trades, starting with the oldest.
        sumBarsPerTrade += strategy.closedtrades.exit_bar_index(tradeNo) - strategy.closedtrades.entry_bar_index(tradeNo) + 1
    result = nz(sumBarsPerTrade / strategy.closedtrades)
plot(avgBarsPerTrade())

دلائل

• trade_num(سیریز int) بند تجارت کا تجارتی نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.closedtrades.exit_bar_index strategy.opentrades.entry_bar_index

حکمت عملی۔ بند تجارت۔ اخراج_قیمت

بند تجارت کی exit قیمت واپس کرتا ہے.

strategy.closedtrades.exit_price(trade_num)

مثال

strategy("strategy.closedtrades.exit_price Example 1")

// We are creating a long trade every 5 bars
if bar_index % 5 == 0
    strategy.entry("Long",  strategy.long)
strategy.close("Long")

// Return the exit price from the latest closed trade.
exitPrice = strategy.closedtrades.exit_price(strategy.closedtrades - 1)

plot(exitPrice, "Long exit price")

تمام بند تجارتوں کے لئے اوسط منافع کی فیصد کا حساب لگائیں.

مثال

strategy("strategy.closedtrades.exit_price Example 2")

// Strategy calls to create single short and long trades.
if bar_index == last_bar_index - 15
    strategy.entry("Long Entry",  strategy.long)
else if bar_index == last_bar_index - 10
    strategy.close("Long Entry")
    strategy.entry("Short", strategy.short)
else if bar_index == last_bar_index - 5
    strategy.close("Short")

// Calculate profit for both closed trades.
profitPct = 0.0
for tradeNo = 0 to strategy.closedtrades - 1
    entryP = strategy.closedtrades.entry_price(tradeNo)
    exitP = strategy.closedtrades.exit_price(tradeNo)
    profitPct += (exitP - entryP) / entryP * strategy.closedtrades.size(tradeNo) * 100
    
// Calculate average profit percent for both closed trades.
avgProfitPct = nz(profitPct / strategy.closedtrades)

plot(avgProfitPct)

دلائل

• trade_num(سیریز int) بند ٹرانزیکشن کا ٹرانزیکشن نمبر۔ پہلے ٹرانزیکشن کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.closedtrades.entry_price

حکمت عملی۔ بند تجارت۔ exit_bar_index

بند تجارت کے باہر نکلنے کا بار_انڈیکس واپس کریں۔

strategy.closedtrades.exit_bar_index(trade_num)

مثال

strategy("strategy.closedtrades.exit_bar_index Example 1")

// Strategy calls to place a single short trade. We enter the trade at the first bar and exit the trade at 10 bars before the last chart bar.
if bar_index == 0
    strategy.entry("Short",  strategy.short)
if bar_index == last_bar_index - 10
    strategy.close("Short")

// Calculate the amount of bars since the last closed trade.
barsSinceClosed = strategy.closedtrades > 0 ? bar_index - strategy.closedtrades.exit_bar_index(strategy.closedtrades - 1) : na

plot(barsSinceClosed, "Bars since last closed trade")

فی ٹرانزیکشن K لائنز کی اوسط تعداد کا حساب لگائیں۔

مثال

strategy("strategy.closedtrades.exit_bar_index Example 2")

// Enter long trades on three rising bars; exit on two falling bars.
if ta.rising(close, 3)
    strategy.entry("Long", strategy.long)
if ta.falling(close, 2)
    strategy.close("Long")

// Function that calculates the average amount of bars per trade.
avgBarsPerTrade() =>
    sumBarsPerTrade = 0
    for tradeNo = 0 to strategy.closedtrades - 1
        // Loop through all closed trades, starting with the oldest.
        sumBarsPerTrade += strategy.closedtrades.exit_bar_index(tradeNo) - strategy.closedtrades.entry_bar_index(tradeNo) + 1
    result = nz(sumBarsPerTrade / strategy.closedtrades)

plot(avgBarsPerTrade())

دلائل

• trade_num(سیریز int) بند تجارت کا تجارتی نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں bar_index

حکمت عملی۔ بند تجارت۔ اندراج_آئی ڈی

بند تجارت کی اندراج کی شناخت لوٹاتا ہے.

strategy.closedtrades.entry_id(trade_num)

مثال

strategy("strategy.closedtrades.entry_id Example", overlay = true)
var isOpen = false 
var openIndex = -1
// Enter a short position and close at the previous to last bar.
if not barstate.ishistory and not isOpen
    strategy.entry("Short at bar #" + str.tostring(bar_index), strategy.short)
    isOpen := true
    openIndex := bar_index
if openIndex != -1 and bar_index > openIndex + 100
    strategy.close_all()
    
// Display ID of the last entry position.
if barstate.islastconfirmedhistory
    runtime.log("Last Entry ID is: " + strategy.closedtrades.entry_id(strategy.closedtrades - 1))

واپسیبند تجارت کی اندراج کی شناخت لوٹاتا ہے.

دلائل

• trade_num(سیریز int) بند تجارت کا تجارتی نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

تبصرےاگر trade_num حد میں نہیں ہے تو فنکشن na لوٹاتا ہے: 0 سے strategy.closedtrades-1.

یہ بھی ملاحظہ کریں strategy.closedtrades.entry_bar_index strategy.closedtrades.entry_time

حکمت عملی۔ بند تجارت۔ اندراج_قیمت

بند تجارت کی اندراج کی قیمت لوٹاتا ہے۔

strategy.closedtrades.entry_price(trade_num)

مثال

strategy("strategy.closedtrades.entry_price Example 1")

// Strategy calls to enter long trades every 15 bars and exit long trades every 20 bars.
if bar_index % 15 == 0
    strategy.entry("Long", strategy.long)
if bar_index % 20 == 0
    strategy.close("Long")

// Return the entry price for the latest  entry.
entryPrice = strategy.closedtrades.entry_price(strategy.closedtrades - 1)

plot(entryPrice, "Long entry price")

تمام بند تجارتوں کے لئے اوسط منافع کی فیصد کا حساب لگائیں.

مثال

strategy("strategy.closedtrades.entry_price Example 2")

// Strategy calls to create single short and long trades
if bar_index == last_bar_index - 15
    strategy.entry("Long Entry",  strategy.long)
else if bar_index == last_bar_index - 10
    strategy.close("Long Entry")
    strategy.entry("Short", strategy.short)
else if bar_index == last_bar_index - 5
    strategy.close("Short")

// Calculate profit for both closed trades.
profitPct = 0.0
for tradeNo = 0 to strategy.closedtrades - 1
    entryP = strategy.closedtrades.entry_price(tradeNo)
    exitP = strategy.closedtrades.exit_price(tradeNo)
    profitPct += (exitP - entryP) / entryP * strategy.closedtrades.size(tradeNo) * 100
    
// Calculate average profit percent for both closed trades.
avgProfitPct = nz(profitPct / strategy.closedtrades)

plot(avgProfitPct)

دلائل

• trade_num(سیریز int) بند تجارت کا تجارتی نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.closedtrades.exit_price strategy.closedtrades.size strategy.closedtrades

حکمت عملی۔ بند تجارت۔ اندراج کا وقت

بند تجارت کی اندراج کا UNIX وقت لوٹاتا ہے۔

strategy.closedtrades.entry_time(trade_num)

مثال

strategy("strategy.closedtrades.entry_time Example", overlay = true)

// Enter long trades on three rising bars; exit on two falling bars.
if ta.rising(close, 3)
    strategy.entry("Long", strategy.long)
if ta.falling(close, 2)
    strategy.close("Long")

// Calculate the average trade duration 
avgTradeDuration() =>
    sumTradeDuration = 0
    for i = 0 to strategy.closedtrades - 1
        sumTradeDuration += strategy.closedtrades.exit_time(i) - strategy.closedtrades.entry_time(i)
    result = nz(sumTradeDuration / strategy.closedtrades)

// Display average duration converted to seconds and formatted using 2 decimal points
if barstate.islastconfirmedhistory
    runtime.log(str.tostring(avgTradeDuration() / 1000, "#.##") + " seconds")

دلائل

• trade_num(سیریز int) بند تجارت کا تجارتی نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.opentrades.entry_time strategy.closedtrades.exit_time time

strategy.closedtrades.profit

بند تجارت کا منافع / نقصان واپس کرتا ہے۔ نقصانات منفی اقدار کے طور پر ظاہر ہوتے ہیں۔

strategy.closedtrades.profit(trade_num)

مثال

strategy("`strategy.closedtrades.profit` Example")

// Strategy calls to enter long trades every 15 bars and exit long trades every 20 bars.
if bar_index % 15 == 0
    strategy.entry("Long", strategy.long)
if bar_index % 20 == 0
    strategy.close("Long")

// Calculate average gross profit by adding the difference between gross profit and commission.
avgGrossProfit() =>
    sumGrossProfit = 0.0
    for tradeNo = 0 to strategy.closedtrades - 1
        sumGrossProfit += strategy.closedtrades.profit(tradeNo) - strategy.closedtrades.commission(tradeNo)
    result = nz(sumGrossProfit / strategy.closedtrades)
    
plot(avgGrossProfit(), "Average gross profit")

دلائل

• trade_num(سیریز int) بند تجارت کا تجارتی نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.opentrades.profit strategy.closedtrades.commission

strategy.closedtrades.size

بند تجارت میں تجارت کی گئی سمت اور معاہدوں کی تعداد لوٹاتا ہے۔ اگر قیمت > 0 ہے تو ، مارکیٹ پوزیشن لمبی تھی۔ اگر قیمت < 0 ہے تو ، مارکیٹ پوزیشن مختصر تھی۔

strategy.closedtrades.size(trade_num)

مثال

strategy("`strategy.closedtrades.size` Example 1")

// We calculate the max amt of shares we can buy.
amtShares = math.floor(strategy.equity / close)
// Strategy calls to enter long trades every 15 bars and exit long trades every 20 bars
if bar_index % 15 == 0
    strategy.entry("Long", strategy.long, qty = amtShares)
if bar_index % 20 == 0
    strategy.close("Long")

// Plot the number of contracts traded in the last closed trade.     
plot(strategy.closedtrades.size(strategy.closedtrades - 1), "Number of contracts traded")

بند تجارتوں پر اوسط منافع کی فیصد کا حساب لگائیں۔

مثال

strategy("`strategy.closedtrades.size` Example 2")

// Strategy calls to enter long trades every 15 bars and exit long trades every 20 bars.
if bar_index % 15 == 0
    strategy.entry("Long", strategy.long)
if bar_index % 20 == 0
    strategy.close("Long")


// Calculate profit for both closed trades.
profitPct = 0.0
for tradeNo = 0 to strategy.closedtrades - 1
    entryP = strategy.closedtrades.entry_price(tradeNo)
    exitP = strategy.closedtrades.exit_price(tradeNo)
    profitPct += (exitP - entryP) / entryP * strategy.closedtrades.size(tradeNo) * 100
    
// Calculate average profit percent for both closed trades.
avgProfitPct = nz(profitPct / strategy.closedtrades)

plot(avgProfitPct)

دلائل

• trade_num(سیریز int) بند تجارت کا تجارتی نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.opentrades.size strategy.position_size strategy.closedtrades strategy.opentrades

حکمت عملی۔ بند تجارت۔ باہر نکلنے کا وقت

بند تجارت کے باہر نکلنے کا UNIX وقت لوٹاتا ہے۔

strategy.closedtrades.exit_time(trade_num)

مثال

strategy("strategy.closedtrades.exit_time Example 1")

// Enter long trades on three rising bars; exit on two falling bars.
if ta.rising(close, 3)
    strategy.entry("Long", strategy.long)
if ta.falling(close, 2)
    strategy.close("Long")

// Calculate the average trade duration. 
avgTradeDuration() =>
    sumTradeDuration = 0
    for i = 0 to strategy.closedtrades - 1
        sumTradeDuration += strategy.closedtrades.exit_time(i) - strategy.closedtrades.entry_time(i)
    result = nz(sumTradeDuration / strategy.closedtrades)

// Display average duration converted to seconds and formatted using 2 decimal points.
if barstate.islastconfirmedhistory
    label.new(bar_index, high, str.tostring(avgTradeDuration() / 1000, "#.##") + " seconds")

X سیکنڈ کے بعد بند تجارت دوبارہ کھولیں۔

مثال

strategy("strategy.closedtrades.exit_time Example 2")

// Strategy calls to emulate a single long trade at the first bar.
if bar_index == 0
    strategy.entry("Long", strategy.long)

reopenPositionAfter(timeSec) =>
    if strategy.closedtrades > 0
        if time - strategy.closedtrades.exit_time(strategy.closedtrades - 1) >= timeSec * 1000
            strategy.entry("Long", strategy.long)

// Reopen last closed position after 120 sec.                
reopenPositionAfter(120)

if ta.change(strategy.opentrades)
    strategy.exit("Long", stop = low * 0.9, profit = high * 2.5)

دلائل

• trade_num(سیریز int) بند تجارت کا تجارتی نمبر۔ پہلی تجارت کا نمبر صفر ہے۔

یہ بھی ملاحظہ کریں strategy.closedtrades.entry_time

حکمت عملی.خطرے.اندراج کی اجازت

یہ فنکشن اس بات کی وضاحت کرنے کے لئے استعمال کیا جا سکتا ہے کہ مارکیٹ کی سمت میں حکمت عملی.انٹری فنکشن کو پوزیشن کھولنے کی اجازت ہے.

strategy.risk.allow_entry_in(value)

مثال

strategy("strategy.risk.allow_entry_in")

strategy.risk.allow_entry_in(strategy.direction.long)
strategy.entry("Long", strategy.long, when = open > close)
// Instead of opening a short position with 10 contracts, this command will close long entries.
strategy.entry("Short", strategy.short, when = open < close, qty = 10)

دلائل

• value(سادہ تار) اجازت دی سمت. ممکنہ اقدار:strategy.direction.all, strategy.direction.long, strategy.direction.short

حکمت عملی.خطرہ.زیادہ سے زیادہ_پوزیشن_سائز

اس اصول کا مقصد مارکیٹ پوزیشن کے زیادہ سے زیادہ سائز کا تعین کرنا ہے۔ یہ اصول مندرجہ ذیل فنکشن کو متاثر کرتا ہے:strategy.entry اندراج مقدار کو (اگر ضرورت ہو تو) معاہدوں / حصص / لاٹس / یونٹوں کی اس تعداد میں کم کیا جاسکتا ہے ، لہذا پوزیشن کا کل سائز strategy.risk.max_position_size میں بیان کردہ قیمت سے زیادہ نہیں ہے۔ اگر کم سے کم ممکن مقدار پھر بھی اصول کی خلاف ورزی کرتی ہے تو ، آرڈر نہیں دیا جائے گا۔

strategy.risk.max_position_size(contracts)

مثال

strategy("risk.max_position_size Demo", default_qty_value = 100)
strategy.risk.max_position_size(10)
strategy.entry("buy", strategy.long, when = open > close)
plot(strategy.position_size)  // max plot value will be 10

دلائل

• contracts(سادہ انٹ / فلوٹ) ایک مطلوبہ پیرامیٹر۔ پوزیشن میں معاہدوں / حصص / لاٹس / یونٹوں کی زیادہ سے زیادہ تعداد۔

ریاضی

math.abs

کی مطلق قیمتnumberہےnumberاگرnumber>= 0، یا -number otherwise.

math.abs(number) 

واپسیکی مطلق قیمتnumber.

math.acos

acos فنکشن arccosine (ریڈینز میں) کو ایسی تعداد میں واپس کرتا ہے کہ cos ((acos ((y)) = y for y in range [-1, 1]۔

math.acos(angle)

واپسیایک قدر کا آرک کوسینوس؛ واپس آنے والا زاویہ [0، پائی] کی حد میں ہے، یا اگر y کی حد سے باہر ہے تو [-1، 1]۔

math.random

ایک جھوٹا بے ترتیب قدر لوٹاتا ہے۔ فنکشن ہر اسکرپٹ کے عمل درآمد کے لئے اقدار کا ایک مختلف سلسلہ تیار کرے گا۔ اختیاری بیج دلیل کے لئے ایک ہی قدر کا استعمال کرتے ہوئے ایک دہرانے والا سلسلہ تیار کرے گا۔

math.random(min, max, seed)

واپسیایک بے ترتیب قدر.

دلائل

• min(سیریز انٹ / فلوٹ) بے ترتیب اقدار کی حد کی نیچے کی حد۔ قدر کو حد میں شامل نہیں کیا گیا ہے۔ ڈیفالٹ 0 ہے۔
• max(سیریز انٹ / فلوٹ) بے ترتیب اقدار کی حد کی اوپری حد۔ قدر کو حد میں شامل نہیں کیا گیا ہے۔ ڈیفالٹ 1 ہے۔
• seed(ان پٹ انٹ) اختیاری دلیل۔ جب ایک ہی بیج کا استعمال کیا جاتا ہے تو ، فنکشن کو ایک کے بعد ایک کال کرنے کی اجازت دیتا ہے تاکہ اقدار کا ایک قابل تکرار سیٹ تیار کیا جاسکے۔

math.asin

اسائن فنکشن نمبر کا آرکسائن (ریڈینز میں) لوٹاتا ہے تاکہ sin ((asin ((y)) = y y کی حد میں [-1، 1]۔

math.asin(angle) 

واپسیایک قدر کا آرکسینس؛ واپس آنے والا زاویہ [-پی / 2، پی / 2] کی حد میں ہے، یا اگر y حد سے باہر ہے تو [-1، 1]۔

math.atan

ایٹان فنکشن کسی بھی ی کے لئے نمبر کا آرکٹینجنٹ (ریڈینز میں) لوٹاتا ہے تاکہ tan ((atan ((y)) = y۔

math.atan(angle) 

واپسیایک قدر کا قوس ٹینجنٹ؛ واپس آنے والا زاویہ [-پی / 2، پی / 2] کی حد میں ہے۔

math.ceil

چھت کا فنکشن سب سے چھوٹا (منفی لامحدود کے قریب) انٹیجر واپس کرتا ہے جو دلیل سے بڑا یا برابر ہے۔

math.ceil(number)

واپسیدی گئی تعداد سے کم یا برابر سب سے چھوٹی عدد.

یہ بھی ملاحظہ کریں math.floor math.round

math.cos

cos فنکشن ایک زاویہ کے trigonometric cosine واپس.

math.cos(angle) 

واپسیایک زاویہ کا مثلثاتی کوسینوس۔

دلائل

• angle(سلسلہ int/float) زاویہ، ریڈینز میں

math.exp

کی exp تقریبnumberکی طاقت تک اٹھایا جاتا ہےnumber، جہاں e ایولر نمبر ہے.

math.exp(number) 

واپسیایک قدر نمائندگی کرتا ہے e کی طاقت کو بڑھا دیاnumber.

یہ بھی ملاحظہ کریں math.pow

math.floor

math.floor(number) 

واپسیدی گئی تعداد سے کم یا برابر سب سے بڑا عدد۔

یہ بھی ملاحظہ کریں math.ceil math.round

math.log

کسی بھی کی قدرتی لوگرتھمnumber> 0 منفرد y ہے کہ e ^ y =number.

math.log(number)

واپسیکے قدرتی لوگرتھمnumber.

یہ بھی ملاحظہ کریں math.log10

math.log10

عام (یا بیس 10) لوگرتھمnumber10 کی طاقت ہے جس کو حاصل کرنے کے لئے 10 کو بڑھانا ہوگاnumber. 10 ^ y =number.

math.log10(number)

واپسیکی بنیاد 10 لوگرتھمnumber.

یہ بھی ملاحظہ کریں math.log

math.pow

ریاضیاتی طاقت کا فنکشن

math.pow(base, exponent)

مثال

// math.pow
plot(math.pow(close, 2))

واپسی baseکی طاقت کے لئے اٹھایاexponent. اگرbaseایک سیریز ہے، یہ عنصر کے لحاظ سے شمار کیا جاتا ہے.

دلائل

• base(سیریز int/float) استعمال کرنے کے لئے بیس کی وضاحت کریں.
• exponent(سیریز int/float) ایکسپونینٹ کی وضاحت کرتا ہے۔

یہ بھی ملاحظہ کریں math.sqrt math.exp

math.sign

نمبر کا نشان (سگنوم) صفر ہے اگر نمبر صفر ہے، 1.0 اگر نمبر صفر سے بڑا ہے، -1.0 اگر نمبر صفر سے کم ہے۔

math.sign(number)

واپسیدلیل کا نشان

math.sin

سین فنکشن زاویہ کی مثلثاتی سینس واپس کرتا ہے۔

math.sin(angle)

واپسیایک زاویہ کی مثلثاتی سینس.

دلائل

• angle(سلسلہ int/float) زاویہ، ریڈینز میں

math.sqrt

کسی بھی کی مربع جڑnumber>= 0 منفرد y ہے >= 0 اس طرح کہ y ^ 2 =number.

math.sqrt(number)

واپسیکی مربع جڑnumber.

یہ بھی ملاحظہ کریں math.pow

math.tan

ٹین فنکشن زاویہ کا مثلثی ٹینجنٹ واپس کرتا ہے۔

math.tan(angle)

واپسیایک زاویہ کا مثلثاتی ٹینجنٹ۔

دلائل

• angle(سلسلہ int/float) زاویہ، ریڈینز میں

math.round

کی قدر لوٹاتا ہےnumberقریبی عددی تک راؤنڈ، تعلقات کے ساتھ راؤنڈ اپ.precisionپیرامیٹر استعمال کیا جاتا ہے، ایک فلوٹ قدر اعشاریہ مقامات کی اس تعداد کو گول لوٹاتا ہے.

math.round(number) 

math.round(number, precision) 

واپسیکی قدرnumberقریبی عددی تک یا درستگی کے مطابق راؤنڈ کیا جاتا ہے۔

دلائل

• number(سلسلہ int/float) اس قدر کو گول کرنا ہے۔
• precision(سلسلہ int) اختیاری دلیل. اعشاریہ مقامات جہاں تکnumberجب کوئی دلیل فراہم نہیں کی جاتی ہے تو، قریبی عددی تعداد تک گول ہے.

تبصرےنوٹ کریں کہ na اقدار کے لئے فنکشن na لوٹاتا ہے۔

یہ بھی ملاحظہ کریں math.ceil math.floor

math.max

متعدد اقدار میں سے سب سے بڑا لوٹاتا ہے۔

math.max(number0, number1, ...) 

مثال

// math.max
plot(math.max(close, open))
plot(math.max(close, math.max(open, 42)))

واپسیمتعدد دی گئی اقدار میں سے سب سے بڑا.

یہ بھی ملاحظہ کریں math.min

math.min

ایک سے زیادہ اقدار میں سے سب سے چھوٹی قدر واپس کرتا ہے۔

math.min(number0, number1, ...) 

مثال

// math.min
plot(math.min(close, open))
plot(math.min(close, math.min(open, 42)))

واپسیمتعدد دی گئی اقدار میں سے سب سے چھوٹا۔

یہ بھی ملاحظہ کریں math.max

math.avg

تمام دی گئی سیریز کا اوسط شمار کرتا ہے (عنصر کے لحاظ سے) ۔

math.avg(number0, number1, ...)

واپسی Average.

یہ بھی ملاحظہ کریں math.sum ta.cum ta.sma

math.round_to_mintick

علامت s منٹک پر گول شدہ قدر واپس کرتا ہے، یعنی قریب ترین قدر جو باقی کے بغیر، تعلقات کو گول کرنے کے ساتھ، syminfo.mintick کی طرف سے تقسیم کیا جا سکتا ہے.

math.round_to_mintick(number) 

واپسیکےnumberدرستگی کے لئے راؤنڈ.

دلائل

• number(سلسلہ int/float) اس قدر کو گول کرنا ہے۔

یہ بھی ملاحظہ کریں math.ceil math.floor

math.sum

مجموعہ فنکشن x کی آخری y اقدار کا سلائیڈنگ مجموعہ لوٹاتا ہے۔

math.sum(source, length)

واپسیرقمsourceکے لئےlengthسلاخوں کے پیچھے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.cum for

math.todegrees

ریڈینز میں ماپا زاویہ سے ڈگری میں تقریبا مساوی زاویہ واپس کرتا ہے۔

math.todegrees(radians) 

واپسیڈگری میں زاویہ کی قدر.

دلائل

• radians(سیریز int/float) ریڈینز میں زاویہ

math.toradians

ڈگری میں ماپا زاویہ سے ریڈینز میں تقریبا مساوی زاویہ واپس کرتا ہے۔

math.toradians(degrees) 

واپسیریڈینز میں زاویہ کی قدر.

دلائل

• degrees(سیریز int/float) ڈگری میں زاویہ.

دیگر

فکسنان

ایک دی گئی سیریز کے لئے NaN اقدار کو پچھلے قریب ترین غیر NaN قدر کے ساتھ تبدیل کرتا ہے۔

fixnan(source) 

واپسیسیریز کے بغیر کوئی خلا.

دلائل

• source(سیریز int/float/bool/color)

یہ بھی ملاحظہ کریں na nz

این زیڈ

NaN اقدار کو صفر (یا دی گئی قدر) کے ساتھ سیریز میں تبدیل کرتا ہے۔

nz(source, replacement) 

nz(source)

مثال

// nz
plot(nz(ta.sma(close, 100)))

واپسیکی قدرsourceاگر ایسا نہیں ہےna. اگر قدرsourceہےna، صفر لوٹاتا ہے، یاreplacementدلیل جب ایک استعمال کیا جاتا ہے.

دلائل

• source(سیریز int/float/bool/color) عمل کرنے کے لئے اقدار کی سیریز.
• replacement(سیریز int/float/bool/color) وہ قدر جو na کی تمام اقدار کی جگہ لے گیsource series.

یہ بھی ملاحظہ کریں na fixnan

ن

ٹیسٹ کی قدر اگر یہ ایک NaN ہے.

na(x)

واپسیاگر x ایک درست نمبر نہیں ہے (x NaN ہے) ، دوسری صورت میں غلط ہے.

یہ بھی ملاحظہ کریں fixnan nz

int

فلوٹ ویلیو کو int میں ڈالتا ہے یا کاٹتا ہے۔

int(x) 

واپسیint میں کاسٹنگ کے بعد دلیل کی قدر.

یہ بھی ملاحظہ کریں float bool color string

فلوٹ

فلوٹ کرنے کے لئے نہیں ڈالتا.

float(x) 

واپسیفلوٹنگ میں ڈالنے کے بعد دلیل کی قدر.

یہ بھی ملاحظہ کریں int bool color string

انتباہ

ریئل ٹائم بار کے دوران بلایا جب ایک انتباہ واقعہ ٹرگر اور انتباہ تقریب واقعات کی بنیاد پر پہلے اشارے یا حکمت عملی کے لئے Create Alert ڈائیلاگ باکس کے ذریعے پیدا کیا گیا تھا.

alert(message, freq)

مثال

// alert() example
ma = ta.sma(close, 14)
xUp = ta.crossover(close, ma)
if xUp
    // Trigger the alert the first time a cross occurs during the real-time bar.
    alert("Price (" + str.tostring(close) + ") crossed over MA (" + str.tostring(ma) +  ").", alert.freq_once_per_bar)
plot(ma)
plotchar(xUp, "xUp", "▲", location.top, size = size.tiny)

دلائل

• message(سلسلہ تار) پیغام بھیجا جب انتباہ ٹرگر. مطلوبہ دلیل.
• freq(ان پٹ سٹرنگ) ٹرگرنگ فریکوئنسی۔ ممکنہ اقدار یہ ہیں: alert.freq_all (تمام فنکشن کالز انتباہ کو متحرک کرتی ہیں) ، alert.freq_once_per_bar (بار کے دوران پہلی فنکشن کال انتباہ کو متحرک کرتی ہے) ، alert.freq_once_per_bar_close (فنکشن کال صرف اس وقت انتباہ کو متحرک کرتی ہے جب یہ حقیقی وقت بار کی آخری اسکرپٹ تکرار کے دوران ہوتا ہے ، جب یہ بند ہوجاتا ہے۔ ڈیفالٹ alert.freq_once_per_bar ہے۔

تبصرےمدد کا مرکز اس طرح کے انتباہات بنانے کا طریقہ بتاتا ہے۔ انتباہی حالت کے برعکس، انتباہی کالز کو اضافی پلاٹ کے طور پر شمار نہیں کیا جاتا ہے۔ فنکشن کالز عالمی اور مقامی دونوں دائرہ کاروں میں واقع ہوسکتی ہیں۔ فنکشن کالز چارٹ پر کچھ بھی ظاہر نہیں کرتے. freq دلائل صرف فنکشن کال کی ٹرگرنگ فریکوئنسی کو متاثر کرتے ہیں جہاں اس کا استعمال کیا جاتا ہے۔

یہ بھی ملاحظہ کریں alertcondition

ہوشیار حالت

انتباہ کی حالت تخلیق کرتا ہے، جو انتباہ تخلیق کریں ڈائیلاگ میں دستیاب ہے۔ براہ کرم نوٹ کریں، کہ انتباہ کی حالت انتباہ نہیں بناتی، یہ صرف آپ کو انتباہ تخلیق کریں ڈائیلاگ میں مزید اختیارات فراہم کرتی ہے۔ اس کے علاوہ، انتباہ کی حالت کا اثر چارٹ پر پوشیدہ ہے۔

alertcondition(condition, title, message)

مثال

// alertcondition
alertcondition(close >= open, title='Alert on Green Bar', message='Green Bar!')

دلائل

• condition(سلسلہ بول) بولین اقدار کا سلسلہ جو انتباہ کے لئے استعمال ہوتا ہے۔ سچ اقدار کا مطلب انتباہ آگ ، غلط - کوئی انتباہ نہیں۔ مطلوبہ دلیل۔
• title(const string) انتباہ کی شرط کا عنوان۔ اختیاری دلیل۔
• message(const string) جب انتباہ فائرنگ ہوتا ہے تو پیغام دکھایا جائے گا۔ اختیاری دلیل۔

تبصرےبراہ کرم نوٹ کریں کہ پائن اسکرپٹ v4/v5 میں ایک الرٹ کنڈیشن کال ایک اضافی پلاٹ تیار کرتی ہے۔ جب ہم ہر اسکرپٹ میں آؤٹ پٹ سیریز کی تعداد کا حساب لگاتے ہیں تو اس طرح کے تمام کالز کو مدنظر رکھا جاتا ہے۔

یہ بھی ملاحظہ کریں alert

اشارے

کے ساتھ ہم آہنگ ہونے کے لئےTrading Viewحکمت عملی کوڈ، یہ اصل میں بلایا جا کرنے کی ضرورت نہیں ہے.

یہ بھی ملاحظہ کریں strategy

وقت

ٹائم فنکشن مخصوص ٹائم فریم اور سیشن کے لئے موجودہ بار کا UNIX وقت یا NaN لوٹاتا ہے اگر ٹائم پوائنٹ سیشن سے باہر ہے۔ نوٹ کریں کہ FMZ اس کی حمایت نہیں کرتا ہےsession arguments.

time(timeframe, session, timezone)

time(timeframe, session)

time(timeframe)

مثال

timeinrange(res, sess) => not na(time(res, sess, "America/New_York")) ? 1 : 0
plot(timeinrange("1", "1300-1400"), color=color.red)

// This plots 1.0 at every start of 10 minute bar on a 1 minute chart:
newbar(res) => ta.change(time(res)) == 0 ? 0 : 1
plot(newbar("10"))

سیشن ترتیب دیتے وقت آپ صرف گھنٹوں اور منٹوں کو نہیں بلکہ ہفتے کے دنوں کو بھی اس سیشن میں شامل کیا جائے گا. اگر دن مخصوص نہیں ہیں تو ، یہ سمجھا جاتا ہے کہ اجلاس اتوار (1) سے ہفتہ (7) تک طے ہوا ہے ، یعنی 1100-2000 1100-1200:1234567 کے برابر ہے۔ آپ دن کی وضاحت کرکے اس کو تبدیل کرسکتے ہیں۔ مثال کے طور پر ، ایک علامت پر جو ہفتے میں سات دن 24 گھنٹے کے تجارتی سیشن کے ساتھ تجارت کی جاتی ہے ، مندرجہ ذیل اسکرپٹ ہفتہ اور اتوار کو رنگ نہیں کرے گا:

مثال

// Time
t1 = time(timeframe.period, "0000-0000:23456")
bgcolor(t1 ? color.new(color.blue, 90) : na)

ایکsessionargument میں کئی مختلف سیشن شامل ہوسکتے ہیں ، جن کو کوما سے الگ کیا جاتا ہے۔ مثال کے طور پر ، مندرجہ ذیل اسکرپٹ 10:00 سے 11:00 اور 14:00 سے 15:00 (صرف کاروباری دن) تک باروں کو اجاگر کرے گا:

مثال

// Time
t1 = time(timeframe.period, "1000-1100,1400-1500:23456")
bgcolor(t1 ? color.new(color.blue, 90) : na)

واپسیUNIX وقت.

دلائل

• timeframe(سادہ تار) ٹائم فریم۔ ایک خالی تار کو چارٹ کے موجودہ ٹائم فریم کے طور پر سمجھا جاتا ہے۔
• session(سادہ تار) سیشن کی تفصیلات۔ اختیاری دلیل ، علامت کا سیشن ڈیفالٹ کے مطابق استعمال ہوتا ہے۔ ایک خالی تار کو علامت کے سیشن کے طور پر تشریح کیا جاتا ہے۔ ایف ایم زیڈ اس کی حمایت نہیں کرتا ہے۔
• timezone(سادہ تار) وقت زون کےsessionیہ صرف اس وقت استعمال کیا جاسکتا ہے جب سیشن کی وضاحت کی جائے۔ اختیاری۔ ڈیفالٹ syminfo.timezone ہے۔ GMT اشارے میں (جیسے GMT-5) یا IANA ٹائم زون ڈیٹا بیس نام (جیسے امریکہ / نیو یارک) کے طور پر بیان کیا جاسکتا ہے۔

تبصرےیونکس وقت وہ ملی سیکنڈ کی تعداد ہے جو 00:00:00 UTC ، 1 جنوری 1970 سے گزر چکی ہے۔

سال

year(time)

year(time, timezone)

واپسیسال (ایکسچینج ٹائم زون میں) فراہم کردہ UNIX وقت کے لئے.

دلائل

• time(سیریز int) ملسی سیکنڈ میں UNIX وقت.
• timezoneایک اختیاری دلیل۔ ٹائم زون۔

نوٹیونیکس وقت 00:00:00 UTC ، 1 جنوری 1970 سے گزرنے والے ملی سیکنڈ کی تعداد ہے۔ ڈیفالٹ کے مطابق ، ٹائم زون syminfo.timezone ہے ، ممکنہ اقدار ٹائم اسٹیمپ میں دیکھے جاسکتے ہیں۔ نوٹ کریں کہ یہ فنکشن بار کھلے وقت کی بنیاد پر سال لوٹاتا ہے۔ راتوں رات سیشن (جیسے EURUSD ، جہاں پیر کا سیشن اتوار ، 17: 00 UTC-4 پر شروع ہوتا ہے) کے لئے یہ قدر تجارتی دن کے سال سے 1 کم ہوسکتی ہے۔

یہ بھی ملاحظہ کریں year time month dayofmonth dayofweek hour minute second

مہینہ

month(time)

month(time, timezone)

واپسیمہینہ (ایکسچینج ٹائم زون میں) فراہم کردہ UNIX وقت کے لئے.

دلائل

• time(سیریز int) ملسی سیکنڈ میں UNIX وقت.
• timezoneایک اختیاری دلیل۔ ٹائم زون۔

تبصرےیونیکس وقت 00:00:00 UTC ، 1 جنوری 1970 سے گزرنے والے ملی سیکنڈ کی تعداد ہے۔ ڈیفالٹ کے مطابق ، ٹائم زون syminfo.timezone ہے ، ممکنہ اقدار ٹائم اسٹیمپ میں دیکھے جاسکتے ہیں۔ نوٹ کریں کہ یہ فنکشن بار کے کھلے وقت کی بنیاد پر مہینہ لوٹاتا ہے۔ راتوں رات سیشن (جیسے EURUSD ، جہاں پیر کا سیشن اتوار ، 17: 00 UTC-4 پر شروع ہوتا ہے) کے لئے ، یہ قدر تجارتی دن کے مہینے سے 1 کم ہوسکتی ہے۔

یہ بھی ملاحظہ کریں month time year dayofmonth dayofweek hour minute second

گھنٹا

hour(time)

hour(time, timezone)

واپسیگھنٹہ (ایکسچینج ٹائم زون میں) فراہم کردہ UNIX وقت کے لئے.

دلائل

• time(سیریز int) ملسی سیکنڈ میں UNIX وقت.
• timezoneایک اختیاری پیرامیٹر۔ ٹائم زون۔

تبصرےیونیکس وقت 00:00:00 UTC ، 1 جنوری 1970 سے گزرنے والے ملی سیکنڈ کی تعداد ہے۔ ڈیفالٹ کے مطابق ، ٹائم زون syminfo.timezone ہے ، ممکنہ اقدار ٹائم اسٹیمپ میں دیکھے جاسکتے ہیں۔

یہ بھی ملاحظہ کریں hour time year month dayofmonth dayofweek minute second

منٹ

minute(time)

minute(time, timezone)

واپسیمنٹ (ایکسچینج ٹائم زون میں) فراہم کردہ UNIX وقت کے لئے.

دلائل

• time(سیریز int) ملسی سیکنڈ میں UNIX وقت.
• timezoneایک اختیاری دلیل۔ ٹائم زون۔

تبصرےیونیکس وقت 00:00:00 UTC ، 1 جنوری 1970 سے گزرنے والے ملی سیکنڈ کی تعداد ہے۔ ڈیفالٹ کے مطابق ، ٹائم زون syminfo.timezone ہے ، ممکنہ اقدار ٹائم اسٹیمپ میں دیکھے جاسکتے ہیں۔

یہ بھی ملاحظہ کریں minute time year month dayofmonth dayofweek hour second

دوسرا

second(time)

second(time, timezone)

واپسیسیکنڈ (ایکسچینج ٹائم زون میں) فراہم کردہ UNIX وقت کے لئے.

دلائل

• time(سیریز int) ملسی سیکنڈ میں UNIX وقت.
• timezoneایک اختیاری پیرامیٹر۔ ٹائم زون۔

تبصرےیونیکس وقت 00:00:00 UTC ، 1 جنوری 1970 سے گزرنے والے ملی سیکنڈ کی تعداد ہے۔ ڈیفالٹ کے مطابق ، ٹائم زون syminfo.timezone ہے ، ممکنہ اقدار ٹائم اسٹیمپ میں دیکھے جاسکتے ہیں۔

یہ بھی ملاحظہ کریں second time year month dayofmonth dayofweek hour minute

ہفتہ وار

weekofyear(time)

weekofyear(time, timezone)

واپسیفراہم کردہ UNIX وقت کے لئے سال کا ہفتہ (تبادلے کے ٹائم زون میں) ۔

دلائل

• time(سیریز int) ملسی سیکنڈ میں UNIX وقت.
• timezoneایک اختیاری پیرامیٹر۔ ٹائم زون۔

تبصرےیونکس وقت 00:00:00 UTC ، 1 جنوری 1970 سے گزرنے والے ملی سیکنڈ کی تعداد ہے۔ ڈیفالٹ کے مطابق ، ٹائم زون syminfo.timezone ہے ، ممکنہ اقدار ٹائم اسٹیمپ میں دیکھے جاسکتے ہیں۔ نوٹ کریں کہ یہ فنکشن بار کے کھلے وقت کی بنیاد پر ہفتہ لوٹاتا ہے۔ راتوں رات سیشن کے لئے (مثال کے طور پر EURUSD ، جہاں پیر کا سیشن اتوار ، 17:00 بجے شروع ہوتا ہے) ، یہ قدر تجارتی دن کے ہفتے سے 1 کم ہوسکتی ہے۔

یہ بھی ملاحظہ کریں weekofyear time year month dayofmonth dayofweek hour minute second

دن ہفتہ

dayofweek(time)

dayofweek(time, timezone)

واپسیہفتہ کا دن (تبادلے کے ٹائم زون میں) فراہم کردہ UNIX وقت کے لئے۔

دلائل

• time(سیریز int) ملسی سیکنڈ میں UNIX وقت.
• timezoneایک اختیاری پیرامیٹر۔ ٹائم زون۔

تبصرےنوٹ کریں کہ یہ فنکشن بار کے کھلے وقت کی بنیاد پر دن لوٹاتا ہے۔ راتوں رات سیشن کے لئے (مثال کے طور پر EURUSD ، جہاں پیر کا سیشن اتوار ، 17:00 بجے شروع ہوتا ہے) ، یہ قدر تجارتی دن کے دن سے 1 کم ہوسکتی ہے۔ یونکس وقت 00:00:00 UTC ، 1 جنوری 1970 سے گزرنے والے ملی سیکنڈ کی تعداد ہے۔ ڈیفالٹ کے مطابق ، ٹائم زون syminfo.timezone ہے ، ممکنہ اقدار ٹائم اسٹیمپ میں دیکھے جاسکتے ہیں۔

یہ بھی ملاحظہ کریں time dayofmonth

دن ماہ

dayofmonth(time)

dayofmonth(time, timezone)

واپسیمہینے کا دن (ایکسچینج ٹائم زون میں) فراہم کردہ UNIX وقت کے لئے۔

دلائل

• time(سیریز int) ملی سیکنڈ میں یونیکس وقت.
• timezoneایک اختیاری پیرامیٹر۔ ٹائم زون۔

تبصرےیونیکس وقت 00:00:00 UTC ، 1 جنوری 1970 سے گزرنے والے ملی سیکنڈ کی تعداد ہے۔ ڈیفالٹ کے مطابق ، ٹائم زون syminfo.timezone ہے ، ممکنہ اقدار ٹائم اسٹیمپ میں دیکھے جاسکتے ہیں۔ نوٹ کریں کہ یہ فنکشن بار کے کھلے وقت کی بنیاد پر دن لوٹاتا ہے۔ راتوں رات سیشن (جیسے EURUSD ، جہاں پیر کا سیشن اتوار ، 17: 00 UTC-4 پر شروع ہوتا ہے) کے لئے ، یہ قدر تجارتی دن کے دن سے 1 کم ہوسکتی ہے۔

یہ بھی ملاحظہ کریں time dayofweek

ٹائم اسٹیمپ

فنکشن ٹائم اسٹیمپ مخصوص تاریخ اور وقت کا UNIX وقت لوٹاتا ہے۔

timestamp(dateString)

timestamp(year, month, day, hour, minute, second)

timestamp(timezone, year, month, day, hour, minute, second)

مثال

// timestamp
plot(timestamp(2016, 01, 19, 09, 30), linewidth=3, color=color.green)
plot(timestamp(syminfo.timezone, 2016, 01, 19, 09, 30), color=color.blue)
plot(timestamp(2016, 01, 19, 09, 30), color=color.yellow)
plot(timestamp("GMT+6", 2016, 01, 19, 09, 30))
plot(timestamp(2019, 06, 19, 09, 30, 15), color=color.lime)
plot(timestamp("GMT+3", 2019, 06, 19, 09, 30, 15), color=color.fuchsia)
plot(timestamp("Feb 01 2020 22:10:05"))
plot(timestamp("2011-10-10T14:48:00"))

مزید