وسائل لوڈ ہو رہے ہیں... لوڈنگ...
  1. مربع
  2. اے ٹی آر فیوژن ٹرینڈ آپٹیمائزیشن ماڈل کی حکمت عملی

اے ٹی آر فیوژن ٹرینڈ آپٹیمائزیشن ماڈل کی حکمت عملی

مصنف:چاؤ ژانگ، تاریخ: 2024-11-28 17:06:21
ٹیگز:اے ٹی آرایس ایم اےٹی پیبلڈ پریشرٹی آرSL

img

جائزہ

یہ حکمت عملی اے ٹی آر اور فبونیکی ویٹڈ اوسطوں پر مبنی ایک جدید رجحان کے بعد کا نظام ہے۔ یہ ایک ذمہ دار اور موافقت پذیر تجارتی ماڈل بنانے کے لئے متعدد ٹائم فریموں میں اتار چڑھاؤ کے تجزیے کو فبونیکی ویٹڈ اوسط کے ساتھ جوڑتا ہے۔ بنیادی طاقت اے ٹی آر کا استعمال کرتے ہوئے بہتر رجحان کی گرفتاری اور عین مطابق منافع کمانے کے لئے اس کے متحرک وزن کی تقسیم میں ہے۔

حکمت عملی کا اصول

یہ حکمت عملی ایک کثیر پرت تکنیکی اشارے کے نقطہ نظر کا استعمال کرتی ہے۔ یہ پہلے حقیقی رینج (TR) اور خریدنے کے دباؤ (BP) کا حساب لگاتا ہے ، پھر فبونیکی ترتیب کے ادوار (8,13,21,34,55) پر مبنی دباؤ کے تناسب کا حساب لگاتا ہے۔ مختلف ادوار (5,4,3,2,1) پر مختلف وزن (5,4,3,2,1) لگائے جاتے ہیں تاکہ وزن شدہ اوسط تیار کیا جاسکے ، جس کو 3 ادوار کے ایس ایم اے کے ذریعہ مزید ہموار کیا جاسکے۔ تجارتی سگنل پہلے سے طے شدہ حدوں (58.0 اور 42.0) کے ساتھ ایس ایم اے کراس اوورز کے ذریعہ متحرک ہوتے ہیں ، اور اے ٹی آر کا استعمال کرتے ہوئے چار مرحلے کا منافع کمانے کا طریقہ کار ڈیزائن کیا گیا ہے۔

حکمت عملی کے فوائد

  1. کثیر جہتی تجزیہ: جامع مارکیٹ کے نقطہ نظر کے لئے متعدد ٹائم فریم سے ڈیٹا کو یکجا کرتا ہے
  2. متحرک موافقت: اے ٹی آر کے ذریعے مارکیٹ کی اتار چڑھاؤ کے مطابق ڈھالنا، حکمت عملی کے استحکام کو بڑھانا
  3. ذہین منافع کا حصول: چار مرحلے کے منافع کے طریقہ کار کو مختلف مارکیٹ کے حالات کے مطابق لچکدار طریقے سے ایڈجسٹ کیا جاتا ہے
  4. کنٹرول شدہ خطرہ: داخلہ اور باہر نکلنے کے واضح حالات ذہنی فیصلے کے خطرات کو کم کرتے ہیں
  5. منظم آپریشن: واضح حکمت عملی منطق، آسان مقدار اور بیک ٹیسٹ

حکمت عملی کے خطرات

  1. پیرامیٹر حساسیت: متعدد حد اور وزن پیرامیٹرز کو احتیاط سے ایڈجسٹ کرنے کی ضرورت ہے
  2. تاخیر کا خطرہ: ایس ایم اے کو ہموار کرنے سے سگنل میں تاخیر ہوسکتی ہے
  3. مارکیٹ کے ماحول پر انحصار: مختلف مارکیٹوں میں غلط سگنل پیدا کر سکتا ہے
  4. پیرامیٹر فٹنگ: پیرامیٹرز کو مختلف مارکیٹ کے حالات کے لئے اصلاح کی ضرورت ہے حل: مارکیٹ کے مختلف مراحل کے لئے متحرک پیرامیٹر ایڈجسٹمنٹ کے ساتھ پیرامیٹر کی مکمل اصلاح اور بیک ٹسٹنگ کی سفارش کریں۔

حکمت عملی کی اصلاح کی ہدایات

  1. پیرامیٹر ایڈجسٹمنٹ: موافقت پذیر پیرامیٹر ایڈجسٹمنٹ میکانزم تیار کریں
  2. مارکیٹ فلٹرنگ: مارکیٹ ماحول کی شناخت ماڈیول شامل کریں
  3. سگنل کی اصلاح: معاون تصدیق کے اشارے متعارف کروائیں
  4. خطرے کے کنٹرول میں اضافہ: متحرک سٹاپ نقصان اور پوزیشن مینجمنٹ شامل کریں
  5. ڈرائنگ کنٹرول: زیادہ سے زیادہ ڈرائنگ کی حد کو نافذ کریں

خلاصہ

اس حکمت عملی میں اے ٹی آر اور فبونیکی ویٹڈ اوسط کو مربوط کیا گیا ہے تاکہ ایک جامع رجحان کی پیروی کرنے والا نظام بنایا جاسکے۔ اس کی طاقت کثیر جہتی تجزیہ اور متحرک موافقت کی صلاحیتوں میں ہے ، جبکہ پیرامیٹر کی اصلاح اور مارکیٹ کے ماحول کی فلٹرنگ پر بھی توجہ دی جانی چاہئے۔ مسلسل اصلاح اور رسک کنٹرول میں بہتری کے ذریعے ، حکمت عملی مختلف مارکیٹ کے حالات میں مستحکم کارکردگی برقرار رکھ سکتی ہے۔

/*backtest
start: 2019-12-23 08:00:00
end: 2024-11-27 00:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © PresentTrading

// The Fibonacci ATR Fusion Strategy is an advanced trading methodology that uniquely integrates Fibonacci-based weighted averages with the Average True Range (ATR) to 
// identify and exploit significant market trends. Unlike traditional strategies that rely on single indicators or fixed parameters, this approach leverages multiple timeframes and 
// dynamic volatility measurements to enhance accuracy and adaptability. 

//@version=5
strategy("Fibonacci ATR Fusion - Strategy [presentTrading]", overlay=false, precision=3, commission_value= 0.1, commission_type=strategy.commission.percent, slippage= 1, currency=currency.USD, default_qty_type = strategy.percent_of_equity, default_qty_value = 10, initial_capital=10000)

// Calculate True High and True Low
tradingDirection = input.string(title="Trading Direction", defval="Both", options=["Long", "Short", "Both"])

// Trading Condition Thresholds
long_entry_threshold = input.float(58.0, title="Long Entry Threshold")
short_entry_threshold = input.float(42.0, title="Short Entry Threshold")
long_exit_threshold = input.float(42.0, title="Long Exit Threshold")
short_exit_threshold = input.float(58.0, title="Short Exit Threshold")

// Enable or Disable 4-Step Take Profit
useTakeProfit = input.bool(false, title="Enable 4-Step Take Profit")

// Take Profit Levels (as multiples of ATR)
tp1ATR = input.float(3.0, title="Take Profit Level 1 ATR Multiplier")
tp2ATR = input.float(8.0, title="Take Profit Level 2 ATR Multiplier")
tp3ATR = input.float(14.0, title="Take Profit Level 3 ATR Multiplier")

// Take Profit Percentages
tp1_percent = input.float(12.0, title="TP Level 1 Percentage", minval=0.0, maxval=100.0)
tp2_percent = input.float(12.0, title="TP Level 2 Percentage", minval=0.0, maxval=100.0)
tp3_percent = input.float(12.0, title="TP Level 3 Percentage", minval=0.0, maxval=100.0)

true_low = math.min(low, close[1])
true_high = math.max(high, close[1])

// Calculate True Range
true_range = true_high - true_low

// Calculate BP (Buying Pressure)
bp = close - true_low

// Calculate ratios for different periods
calc_ratio(len) =>
    sum_bp = math.sum(bp, len)
    sum_tr = math.sum(true_range, len)
    100 * sum_bp / sum_tr

// Calculate weighted average of different timeframes
weighted_avg = (5 * calc_ratio(8) + 4 * calc_ratio(13) + 3 * calc_ratio(21) + 2 * calc_ratio(34) + calc_ratio(55)) / (5 + 4 + 3 + 2 + 1)
weighted_avg_sma = ta.sma(weighted_avg,3)

// Plot the indicator
plot(weighted_avg, "Fibonacci ATR", color=color.blue, linewidth=2)
plot(weighted_avg_sma, "SMA Fibonacci ATR", color=color.yellow, linewidth=2)

// Define trading conditions
longCondition = ta.crossover(weighted_avg_sma, long_entry_threshold)  // Enter long when weighted average crosses above threshold
shortCondition = ta.crossunder(weighted_avg_sma, short_entry_threshold) // Enter short when weighted average crosses below threshold
longExit = ta.crossunder(weighted_avg_sma, long_exit_threshold)
shortExit = ta.crossover(weighted_avg_sma, short_exit_threshold)


atrPeriod = 14
atrValue = ta.atr(atrPeriod)

if (tradingDirection == "Long" or tradingDirection == "Both")
    if (longCondition)
        strategy.entry("Long", strategy.long)
        // Set Take Profit levels for Long positions
        if useTakeProfit
            tpPrice1 = strategy.position_avg_price + tp1ATR * atrValue
            tpPrice2 = strategy.position_avg_price + tp2ATR * atrValue
            tpPrice3 = strategy.position_avg_price + tp3ATR * atrValue
            // Close partial positions at each Take Profit level
            strategy.exit("TP1 Long", from_entry="Long", qty_percent=tp1_percent, limit=tpPrice1)
            strategy.exit("TP2 Long", from_entry="Long", qty_percent=tp2_percent, limit=tpPrice2)
            strategy.exit("TP3 Long", from_entry="Long", qty_percent=tp3_percent, limit=tpPrice3)
    if (longExit)
        strategy.close("Long")

if (tradingDirection == "Short" or tradingDirection == "Both")
    if (shortCondition)
        strategy.entry("Short", strategy.short)
        // Set Take Profit levels for Short positions
        if useTakeProfit
            tpPrice1 = strategy.position_avg_price - tp1ATR * atrValue
            tpPrice2 = strategy.position_avg_price - tp2ATR * atrValue
            tpPrice3 = strategy.position_avg_price - tp3ATR * atrValue
            // Close partial positions at each Take Profit level
            strategy.exit("TP1 Short", from_entry="Short", qty_percent=tp1_percent, limit=tpPrice1)
            strategy.exit("TP2 Short", from_entry="Short", qty_percent=tp2_percent, limit=tpPrice2)
            strategy.exit("TP3 Short", from_entry="Short", qty_percent=tp3_percent, limit=tpPrice3)
    if (shortExit)
        strategy.close("Short")
متعلقہ
مزید

2019 FMZ - تمام حقوق محفوظ ہیں