Chỉ số MA là viết tắt của tiếng Anh ((Moving average) và được gọi là chỉ số trung bình chuyển động. Đường trung bình chuyển động ((MA) có đặc điểm xu hướng, tương đối ổn định, không giống như đường K ngày sẽ tăng và giảm. Đường trung bình chuyển động càng dài, hiệu suất càng ổn định. Không dễ dàng tăng và giảm, bạn phải chờ đợi sự rõ ràng thực sự của xu hướng giá cổ phiếu. Đường trung bình chuyển động là, trong phân tích cuối cùng, một công cụ theo dõi xu hướng giúp dễ dàng xác định xem xu hướng đã kết thúc hay đảo ngược và liệu xu hướng mới đang nổi lên hay không.
Trong số này, chúng tôi chia sẻ chiến lược kết hợp chỉ số MACD + MA. Trong phân tích kỹ thuật, sự kết hợp của các chỉ số rất phổ biến. Các chỉ số khác nhau có các điểm hoạt động và phương pháp phân tích khác nhau. Sự kết hợp của các chỉ số có thể tăng cường độ chính xác của tín hiệu. Chiến lược là so sánh mối quan hệ giữa giá và MA, và sau đó đo tốc độ chuyển động giá bằng chỉ số MACD để đánh giá tình trạng thị trường và xây dựng một chiến lược giao dịch thời gian đơn giản.
(*backtest
start: 2018-11-01 00:00:00
end: 2018-11-22 00:00:00
period: 1h
exchanges: [{"eid":"Bitfinex","currency":"BTC_USD"}]
*)
// MACD calculation
FASTLENGTH:=12;
SLOWLENGTH:=26;
MACDLENGTH:=9;
// Length of MA
L1:=50;
L2:=120;
// stop loss 止损 5%
STOPLOSS:=5;
//MACD
MACDVALUE:=EMA(CLOSE,FASTLENGTH)-EMA(CLOSE,SLOWLENGTH);
AVGMACD:=EMA(MACDVALUE,MACDLENGTH);
MACDDIFF:=MACDVALUE-AVGMACD;
//MA1、MA2
DMA1:=MA(C,L1);
DMA2:=MA(C,L2);
BUYCONDITION:=MACDVALUE>0 && DMA1>DMA2 && MACDDIFF>0 && C>DMA1 && REF(C,1)>REF(DMA1,1);
SELLCONDITION:=MACDVALUE<0 && DMA1<DMA2 && MACDDIFF<0 && C<DMA1 && REF(C,1)<REF(DMA1,1);
// 开仓条件 When to open position
BKVOL=0 AND BUYCONDITION,BK;
SETSIGPRICETYPE(BK,NEW_ORDER);
SKVOL=0 AND SELLCONDITION,SK;
SETSIGPRICETYPE(SK,NEW_ORDER);
// 离场条件 When to close position
BKVOL>0 AND (REF(MACDVALUE,1)<0 OR REF(DMA1,1)<REF(DMA2,1)),SP;
SKVOL>0 AND (REF(MACDVALUE,1)>0 OR REF(DMA1,1)>REF(DMA2,1)),BP;
// 启动止损 Start stop loss
SKVOL>0 AND HIGH>=SKPRICE*(1+STOPLOSS*0.01),BP;
BKVOL>0 AND LOW<=BKPRICE*(1-STOPLOSS*0.01),SP;
AUTOFILTER;