রিসোর্স লোড হচ্ছে... লোডিং...

মুনাফা সর্বাধিকীকরণকারী PMax

লেখক:চাওঝাং, তারিখ: ২০২২-০৫-২৫ ১৭ঃ১৩ঃ৪৫
ট্যাগঃএসএমএইএমএডব্লিউএমএটিএমএএটিআরZLEMA

সর্বাধিক এবং সুপার ট্রেন্ড সূচক উভয়ই ট্রেন্ড অনুসরণকারী সিস্টেমে খুব ভাল তবে বিপরীতভাবে তাদের পারফরম্যান্স অন্যান্য সূচকের মতো পার্শ্ববর্তী বাজারের অবস্থার মধ্যে উজ্জ্বল নয়।

মুনাফা সর্বাধিকীকরণকারী - পিএমএক্স এই সমস্যাটি সমাধান করার চেষ্টা করে। পিএমএক্স একটি সূচকে সর্বাধিক (চলমান গড় প্রবণতা পরিবর্তনকারী) এবং সুপারট্রেন্ড (এটিআর মূল্য সনাক্তকরণ) এর শক্তিশালী দিকগুলিকে একত্রিত করে।

পিএমএক্সের ব্যাকটেস্ট এবং অপ্টিমাইজেশান ফলাফলগুলি এর পূর্বসূরিদের তুলনায় অনেক ভাল। এটি পাশের দিকে মিথ্যা সংকেতগুলির সংখ্যা হ্রাস করে এবং আরও নির্ভরযোগ্য ট্রেডিং সংকেত দেয়।

PMax প্রবণতা নির্ধারণ করা সহজ এবং যে কোনও ধরণের বাজার এবং যন্ত্রগুলিতে ব্যবহার করা যেতে পারে। এটি পুনরায় আঁকা হয় না।

তিনটি পরামিতি দ্বারা নির্ধারিত PMax সূচকের প্রথম পরামিতি হল ATR এর সময়কাল/দৈর্ঘ্য।

দ্বিতীয় প্যারামিটারটি হল ATR এর মাল্টিপ্লায়ার যা অন্তর্নির্মিত চলমান গড় থেকে দূরত্বের মান সেট করতে কার্যকর হবে।

আমি ব্যক্তিগতভাবে মনে করি সবচেয়ে গুরুত্বপূর্ণ পরামিতি হল চলমান গড় দৈর্ঘ্য এবং প্রকার।

PMax প্রবণতা আন্দোলনের প্রতি অনেক বেশি সংবেদনশীল হবে যদি চলমান গড় দৈর্ঘ্য ছোট হয়। এবং বিপরীতভাবে, এটি দীর্ঘ হলে কম সংবেদনশীল হবে।

সময় বাড়ার সাথে সাথে এটি ছোটখাট প্রবণতা এবং দামের ক্রিয়াকলাপের প্রতি কম সংবেদনশীল হয়ে উঠবে।

এইভাবে, আপনার সময়কালের পছন্দটি আপনার আগ্রহের প্রবণতার সাথে ঘনিষ্ঠভাবে সম্পর্কিত হবে।

চলমান গড় PMax এর উপরে থাকলে আমরা আপট্রেন্ডের প্রভাবের অধীনে থাকি; বিপরীতভাবে, যখন চলমান গড় PMax এর নিচে থাকে তখন নিম্নগামী প্রবণতার প্রভাবের অধীনে।

নির্মিত মুভিং গড় টাইপ ডিফল্টরূপে ইএমএ হিসাবে সেট কিন্তু ব্যবহারকারীরা 8 বিভিন্ন মুভিং গড় ধরনের থেকে চয়ন করতে পারেন যেমনঃ

এসএমএঃ সরল চলমান গড় EMA: এক্সপোনেনশিয়াল মুভিং মিডিয়ার WMA: ওয়েটেড মুভিং এভারেজ TMA: ত্রিভুজীয় চলমান গড় VAR: ভেরিয়েবল ইনডেক্স ডায়নামিক মুভিং এভারেজ ডব্লিউডব্লিউএমএ: ওয়েলস ওয়াইল্ডারের চলমান গড় ZLEMA: শূন্য বিলম্ব এক্সপোনেনশিয়াল মুভিং গড় টিএসএফ: সত্যিকারের শক্তির শক্তি

টিপঃ পাশের দিকে VAR একটি ভাল পছন্দ হবে

আপনি PMax ডিফল্ট এলার্ম এবং কিনুন বিক্রয় সংকেত যেমন ব্যবহার করতে পারেনঃ

১- মুভিং এভারেজ PMax এর উপরে ক্রস করলে কিনুন মুভিং এভারেজ PMax এর নিচে ক্রস করলে বিক্রি করুন

২- যখন দাম PMax লাইনের ওপরে যায় তখন কিনুন। যখন দাম Pmax লাইনের নিচে যায় তখন বিক্রি করে দাও।

ব্যাকটেস্ট

/*backtest
start: 2022-04-24 00:00:00
end: 2022-05-23 23:59:00
period: 15m
basePeriod: 5m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © KivancOzbilgic
//developer: @KivancOzbilgic
//author: @KivancOzbilgic

study("Profit Maximizer","PMax", overlay=true, format=format.price, precision=2, resolution="")
src = input(hl2, title="Source")
Periods = input(title="ATR Length", type=input.integer, defval=10)
Multiplier = input(title="ATR Multiplier", type=input.float, step=0.1, defval=3.0)
mav = input(title="Moving Average Type", defval="EMA", options=["SMA", "EMA", "WMA", "TMA", "VAR", "WWMA", "ZLEMA", "TSF"])
length =input(10, "Moving Average Length", minval=1)
changeATR= input(title="Change ATR Calculation Method ?", type=input.bool, defval=true)
Normalize= input(title="Normalize ATR ?", type=input.bool, defval=false)
showsupport = input(title="Show Moving Average?", type=input.bool, defval=true)
showsignalsk = input(title="Show Crossing Signals?", type=input.bool, defval=true)
showsignalsc = input(title="Show Price/Pmax Crossing Signals?", type=input.bool, defval=false)
highlighting = input(title="Highlighter On/Off ?", type=input.bool, defval=true)
atr2 = sma(tr, Periods)
atr= changeATR ? atr(Periods) : atr2
valpha=2/(length+1)
vud1=src>src[1] ? src-src[1] : 0
vdd1=src<src[1] ? src[1]-src : 0
vUD=sum(vud1,9)
vDD=sum(vdd1,9)
vCMO=nz((vUD-vDD)/(vUD+vDD))
VAR=0.0
VAR:=nz(valpha*abs(vCMO)*src)+(1-valpha*abs(vCMO))*nz(VAR[1])
wwalpha = 1/ length
WWMA = 0.0
WWMA := wwalpha*src + (1-wwalpha)*nz(WWMA[1])
zxLag = length/2==round(length/2) ? length/2 : (length - 1) / 2
zxEMAData = (src + (src - src[zxLag]))
ZLEMA = ema(zxEMAData, length)
lrc = linreg(src, length, 0)
lrc1 = linreg(src,length,1)
lrs = (lrc-lrc1)
TSF = linreg(src, length, 0)+lrs
getMA(src, length) =>
    ma = 0.0
    if mav == "SMA"
        ma := sma(src, length)
        ma

    if mav == "EMA"
        ma := ema(src, length)
        ma

    if mav == "WMA"
        ma := wma(src, length)
        ma

    if mav == "TMA"
        ma := sma(sma(src, ceil(length / 2)), floor(length / 2) + 1)
        ma

    if mav == "VAR"
        ma := VAR
        ma

    if mav == "WWMA"
        ma := WWMA
        ma

    if mav == "ZLEMA"
        ma := ZLEMA
        ma

    if mav == "TSF"
        ma := TSF
        ma
    ma
    
MAvg=getMA(src, length)
longStop = Normalize ? MAvg - Multiplier*atr/close : MAvg - Multiplier*atr
longStopPrev = nz(longStop[1], longStop)
longStop := MAvg > longStopPrev ? max(longStop, longStopPrev) : longStop
shortStop = Normalize ? MAvg + Multiplier*atr/close : MAvg + Multiplier*atr
shortStopPrev = nz(shortStop[1], shortStop)
shortStop := MAvg < shortStopPrev ? min(shortStop, shortStopPrev) : shortStop
dir = 1
dir := nz(dir[1], dir)
dir := dir == -1 and MAvg > shortStopPrev ? 1 : dir == 1 and MAvg < longStopPrev ? -1 : dir
PMax = dir==1 ? longStop: shortStop
plot(showsupport ? MAvg : na, color=#0585E1, linewidth=2, title="Moving Avg Line")
pALL=plot(PMax, color=color.red, linewidth=2, title="PMax", transp=0)
alertcondition(cross(MAvg, PMax), title="Cross Alert", message="PMax - Moving Avg Crossing!")
alertcondition(crossover(MAvg, PMax), title="Crossover Alarm", message="Moving Avg BUY SIGNAL!")
alertcondition(crossunder(MAvg, PMax), title="Crossunder Alarm", message="Moving Avg SELL SIGNAL!")
alertcondition(cross(src, PMax), title="Price Cross Alert", message="PMax - Price Crossing!")
alertcondition(crossover(src, PMax), title="Price Crossover Alarm", message="PRICE OVER PMax - BUY SIGNAL!")
alertcondition(crossunder(src, PMax), title="Price Crossunder Alarm", message="PRICE UNDER PMax - SELL SIGNAL!")

buySignalk = crossover(MAvg, PMax)
plotshape(buySignalk and showsignalsk ? PMax*0.995 : na, title="Buy", text="Buy", location=location.absolute, style=shape.labelup, size=size.tiny, color=color.green, textcolor=color.white, transp=0)

sellSignallk = crossunder(MAvg, PMax)
plotshape(sellSignallk and showsignalsk ? PMax*1.005 : na, title="Sell", text="Sell", location=location.absolute, style=shape.labeldown, size=size.tiny, color=color.red, textcolor=color.white, transp=0)

buySignalc = crossover(src, PMax)
plotshape(buySignalc and showsignalsc ? PMax*0.995 : na, title="Buy", text="Buy", location=location.absolute, style=shape.labelup, size=size.tiny, color=#0F18BF, textcolor=color.white, transp=0)

sellSignallc = crossunder(src, PMax)
plotshape(sellSignallc and showsignalsc ? PMax*1.005 : na, title="Sell", text="Sell", location=location.absolute, style=shape.labeldown, size=size.tiny, color=#0F18BF, textcolor=color.white, transp=0)

mPlot = plot(ohlc4, title="", style=plot.style_circles, linewidth=0,display=display.none)
longFillColor = highlighting ? (MAvg>PMax ? color.green : na) : na
shortFillColor = highlighting ? (MAvg<PMax ? color.red : na) : na

fill(mPlot, pALL, title="UpTrend Highligter", color=longFillColor)
fill(mPlot, pALL, title="DownTrend Highligter", color=shortFillColor)


if buySignalk
    strategy.entry("Enter Long", strategy.long)
else if sellSignallk
    strategy.entry("Enter Short", strategy.short)

সম্পর্কিত

আরো

2019 FMZ - সমস্ত অধিকার সংরক্ষিত