La estrategia de ruptura de día dentro de un rango estrecho identifica oscilaciones de rango estrecho y rupturas cerradas dentro del día para seguir tendencias largas.
Utilice NR7 para identificar el día de rango más estrecho entre los últimos 7 días.
Usar dentro del día para determinar si el máximo del día anterior es menor que el máximo del día actual y si el mínimo del día anterior es mayor que el mínimo del día actual.
Cuando NR7 y el día dentro ocurren juntos, con el precio de cierre más alto que el precio de apertura, vaya largo.
Salida cuando el cierre del día siguiente sea más alto que el abierto.
La estrategia utiliza tanto el estrechamiento del precio como las señales dentro del día para identificar las etapas de acumulación.
Además, el enfoque basado únicamente en el largo plazo evita las trampas de consolidación y las operaciones innecesarias.
Considera las señales de estrechamiento y dentro del día
La dirección de la SMA determina la existencia de la tendencia
El filtrado multicondicional mejora la precisión de la señal
Solo el tiempo evita las trampas de la consolidación
Parámetros de pruebas de retroceso óptimables, flexibles
La sintonización de SMA es necesaria para optimizar las señales
Puede haber retraso en la entrada, concéntrate en el momento de la salida.
Incapaz de sacar provecho de las tendencias a la baja
Evitar una nueva expansión de los rangos
La estrategia de breakout dentro del día examina a fondo la estructura del mercado y genera señales de alta probabilidad. Con el ajuste de parámetros, es altamente adaptable.
/*backtest
start: 2023-09-11 00:00:00
end: 2023-09-14 00:00:00
period: 10m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=2
strategy("NR7ID: Narrow Range + Inside Day, Long Only Strategy (by ChartArt)", shorttitle="CA_-_NR7ID_Strat", overlay=true) // max_bars_back=5000
// ChartArt's Narrow Range + Inside Day Strategy (Long Only)
//
// Version 1.0
// Idea by ChartArt on Oktober 16, 2016.
//
// This long only strategy determines when there is both
// a NR7 (narrow range 7, a trading day in which the range
// is narrower than any of the previous six days), plus a
// inside day (high of the current day is lower than the high
// of the previous day and the low of the current day is higher
// than the low of the previous day) both on the same trading day
// and enters a long trade when the close is larger than the
// open and the slope of the simple moving average is upwards, too.
//
// The strategy exits the long trade next time the close is
// larger than the open in any of the next trading days.
//
// In addition the NR7ID can be colored (if close large open
// colored in green, else in red) and the SMA can be drawn
// with a color based on the direction of the SMA slope.
//
// List of my work:
// https://www.tradingview.com/u/ChartArt/
//
// __ __ ___ __ ___
// / ` |__| /\ |__) | /\ |__) |
// \__, | | /~~\ | \ | /~~\ | \ |
//
//
// NR7 Identifier
show_NR7=input(true, type=bool,title="Show Narrow Range 7 (NR7) ?")
range=(high-low)
nr7=(range < range[1]) and (range < range[2]) and (range < range[3]) and (range < range[4]) and (range < range[5]) and (range < range[6])
plotchar(show_NR7?nr7:na, char="7", location=location.abovebar, color=blue)
// Inside Day Identifier
show_insidebar = input(true, type=bool,title="Show Inside Day (I) ?")
insidebar = (high < high[1] and low > low[1])
plotchar(show_insidebar?insidebar:na, char="i", location=location.abovebar, color=blue)
// NR7 + Inside Day Identifier
show_NR7ID = input(true, type=bool,title="Show NR7ID (NR7 + Inside Day) colors ?")
NR7ID = nr7 and insidebar
NR7ID_color = NR7ID and open < close ? green : NR7ID and open > close ? red : gray
barcolor(show_NR7ID?NR7ID_color:na)
// Simple Moving Average
show_ma = input(true, type=bool,title="Show SMA ?")
ma_length = input(14,title="SMA Length")
ma = sma(close,ma_length)
ma_change = change(ma) > 0
ma_change_color = change(ma) > 0 ? green : change(ma) < 0 ? red : blue
plot(show_ma?ma:na,color=ma_change_color,linewidth=3)
// (not enabled) Short Strategy: NR7 + Inside Day + close is smaller than open + change of SMA is downwards
//strategy.entry("sell", strategy.short, when = NR7ID and open > close and ma_change == false, comment="Short")
//strategy.close("sell", when = open > close )
// Long Strategy: NR7 + Inside Day + close is larger than open + change of SMA is upwards
strategy.entry("long", strategy.long, when = NR7ID and open < close and ma_change == true, comment="Long")
strategy.close("long", when = open < close )