Sumber daya yang dimuat... Pemuatan...

Strategi Divergensi RSI berbasis pivot

Penulis:ChaoZhang, Tanggal: 2023-11-28 13:43:05
Tag:

Gambaran umum

Strategi ini disebut Pivot-based RSI Divergence Strategy. Ini menggunakan divergensi antara indikator RSI pada siklus yang berbeda untuk menentukan titik masuk dan keluar, dan menambahkan RSI jangka panjang sebagai kondisi filter untuk meningkatkan stabilitas strategi.

Logika Strategi

Strategi ini terutama menilai peluang untuk membeli ketika ada perbedaan bullish tersembunyi atau perbedaan bullish reguler antara RSI jangka pendek (seperti RSI 5 hari) dan harga; dan untuk menjual ketika ada perbedaan bearish tersembunyi atau perbedaan bearish reguler.

divergensi bullish reguler berarti bahwa harga membuat low baru sementara RSI tidak membuat low baru; divergensi bullish tersembunyi adalah sebaliknya, harga tidak membuat low baru sementara RSI membuat low baru.

Selain itu, strategi ini juga memperkenalkan RSI jangka panjang (seperti RSI 50 hari) sebagai kondisi filter. Ini hanya mempertimbangkan sinyal beli ketika RSI panjang lebih besar dari 50; dan mempertimbangkan stop loss atau take profit exit ketika RSI panjang kurang dari 30.

Keuntungan

Keuntungan terbesar dari strategi ini adalah bahwa ia memanfaatkan kedua sinyal divergensi RSI pada jangka pendek dan filter RSI jangka panjang, yang dapat menghindari terjebak dan kehilangan tren sampai batas tertentu. Secara khusus, ia memiliki keuntungan utama berikut:

Sinyal divergensi RSI jangka pendek dapat memberikan penilaian awal tentang peluang pembalikan harga dan tepat waktu menangkap titik balik;
Filter RSI jangka panjang menghindari pergi lama secara buta ketika tren tidak pasti;
Berbagai jenis metode mengambil keuntungan dan mengambil keuntungan parsial membantu mengurangi risiko;
Mekanisme piramida memungkinkan penambahan posisi dan lebih memperluas potensi keuntungan.

Risiko

Strategi ini juga memiliki beberapa risiko yang perlu dicatat:

Perbedaan RSI tidak selalu valid dan mungkin ada sinyal palsu;
Risiko meningkat setelah piramida. kerugian bisa dipercepat jika penilaian salah;
Pengaturan mengambil keuntungan yang tidak tepat juga dapat menyebabkan pengambilan keuntungan yang dini atau keuntungan yang tidak cukup.

Langkah-langkah manajemen risiko yang sesuai meliputi: menetapkan kondisi stop loss/take profit yang wajar, mengendalikan ukuran posisi, mengambil keuntungan parsial untuk meratakan kurva ekuitas, dll.

Arahan Optimasi

Ada ruang untuk optimalisasi strategi lebih lanjut:

Parameter RSI dapat dioptimalkan lebih lanjut untuk menemukan kombinasi terbaik;
Sinyal divergensi dari indikator lain seperti MACD dan KD dapat diuji;
Parameter dapat secara khusus dioptimalkan pada produk tertentu (seperti minyak mentah, logam mulia, dll.) untuk meningkatkan kemampuan beradaptasi.

Ringkasan

Strategi ini menggabungkan sinyal divergensi RSI jangka pendek dan jangka panjang untuk meningkatkan profitabilitas sambil mengendalikan risiko. Strategi ini mencerminkan beberapa prinsip dalam desain strategi kuantitatif, termasuk kapan harus masuk, kapan harus keluar, mengambil keuntungan parsial, pengaturan stop loss/take profit, dll. Ini adalah strategi divergensi RSI teladan untuk referensi.

/*backtest
start: 2023-11-20 00:00:00
end: 2023-11-27 00:00:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © mohanee

//@version=4

//GOOGL setting  5 ,50 close, 3 , 1  profitLevel at 75 and No stop Loss shows win rate 99.03 % profit factor 5830.152

strategy(title="RSI5_50 with Divergence", overlay=false,pyramiding=2, default_qty_type=strategy.fixed, default_qty_value=3,    initial_capital=10000, currency=currency.USD)

len = input(title="RSI Period", minval=1, defval=5)
longRSILen = input(title="Long RSI Period", minval=10, defval=50)
src = input(title="RSI Source", defval=close)
lbR = input(title="Pivot Lookback Right", defval=3)
lbL = input(title="Pivot Lookback Left", defval=1)
takeProfitRSILevel = input(title="Take Profit at RSI Level", minval=50, defval=75)
stopLoss = input(title="Stop Loss%(if checked 8% rule applied)", defval=false)

shortTermRSI = rsi(close,len)
longTermRSI = rsi(close,longRSILen)

rangeUpper = input(title="Max of Lookback Range", defval=60)
rangeLower = input(title="Min of Lookback Range", defval=5)
plotBull = input(title="Plot Bullish", defval=true)
plotHiddenBull = input(title="Plot Hidden Bullish", defval=true)
plotBear = input(title="Plot Bearish", defval=true)
plotHiddenBear = input(title="Plot Hidden Bearish", defval=false)


bearColor = color.purple
bullColor = color.green
hiddenBullColor = color.new(color.green, 80)
hiddenBearColor = color.new(color.red, 80)
textColor = color.white
noneColor = color.new(color.white, 100)



plot(shortTermRSI, title="RSI", linewidth=2, color=#8D1699)
plot(longTermRSI, title="longTermRSI", linewidth=2, color=color.orange)

hline(50, title="Middle Line", linestyle=hline.style_dotted)
obLevel = hline(70, title="Overbought", linestyle=hline.style_dotted)
osLevel = hline(30, title="Oversold", linestyle=hline.style_dotted)
fill(obLevel, osLevel, title="Background", color=longTermRSI >=50 ? color.green:color.purple, transp=65)  // longTermRSI >=50

plFound = na(pivotlow(shortTermRSI, lbL, lbR)) ? false : true
phFound = na(pivothigh(shortTermRSI, lbL, lbR)) ? false : true

_inRange(cond) =>
    bars = barssince(cond == true)
    rangeLower <= bars and bars <= rangeUpper

//------------------------------------------------------------------------------
// Regular Bullish

// shortTermRSI: Higher Low
oscHL = shortTermRSI[lbR] > valuewhen(plFound, shortTermRSI[lbR], 1) and _inRange(plFound[1])

// Price: Lower Low
priceLL = low[lbR] < valuewhen(plFound, low[lbR], 1)

bullCond = plotBull and priceLL and oscHL and plFound

plot(
	 plFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bullish",
	 linewidth=2,
	 color=(bullCond ? bullColor : noneColor),
	 transp=0
	 )


plotshape(
	 bullCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bullish Label",
	 text=" Bull ",
	 style=shape.labelup,
	 location=location.absolute,
	 color=bullColor,
	 textcolor=textColor,
	 transp=0
	 )

//------------------------------------------------------------------------------
// Hidden Bullish

// shortTermRSI: Lower Low
oscLL = shortTermRSI[lbR] < valuewhen(plFound, shortTermRSI[lbR], 1) and _inRange(plFound[1])

// Price: Higher Low
priceHL = low[lbR] > valuewhen(plFound, low[lbR], 1)

hiddenBullCond = plotHiddenBull and priceHL and oscLL and plFound

plot(
	 plFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bullish",
	 linewidth=2,
	 color=(hiddenBullCond ? hiddenBullColor : noneColor),
	 transp=0
	 )

plotshape(
	 hiddenBullCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bullish Label",
	 text=" H Bull ",
	 style=shape.labelup,
	 location=location.absolute,
	 color=bullColor,
	 textcolor=textColor,
	 transp=0
	 )

longCondition= longTermRSI >=50  and ( (bullCond or hiddenBullCond ) )  or  (strategy.position_size>0 and crossover(shortTermRSI,20) )
//last condition above is to leg in if you are already in the Long trade, 


strategy.entry(id="RSIDivLE", long=true,  when=longCondition)


//------------------------------------------------------------------------------
// Regular Bearish

// shortTermRSI: Lower High
oscLH = shortTermRSI[lbR] < valuewhen(phFound, shortTermRSI[lbR], 1) and _inRange(phFound[1])

// Price: Higher High
priceHH = high[lbR] > valuewhen(phFound, high[lbR], 1)

bearCond = plotBear and priceHH and oscLH and phFound

plot(
	 phFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bearish",
	 linewidth=2,
	 color=(bearCond ? bearColor : noneColor),
	 transp=0
	 )

plotshape(
	 bearCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bearish Label",
	 text=" Bear ",
	 style=shape.labeldown,
	 location=location.absolute,
	 color=bearColor,
	 textcolor=textColor,
	 transp=0
	 )

//------------------------------------------------------------------------------
// Hidden Bearish

// shortTermRSI: Higher High
oscHH = shortTermRSI[lbR] > valuewhen(phFound, shortTermRSI[lbR], 1) and _inRange(phFound[1])

// Price: Lower High
priceLH = high[lbR] < valuewhen(phFound, high[lbR], 1)

hiddenBearCond = plotHiddenBear and priceLH and oscHH and phFound

plot(
	 phFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bearish",
	 linewidth=2,
	 color=(hiddenBearCond ? hiddenBearColor : noneColor),
	 transp=0
	 )

plotshape(
	 hiddenBearCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bearish Label",
	 text=" H Bear ",
	 style=shape.labeldown,
	 location=location.absolute,
	 color=bearColor,
	 textcolor=textColor,
	 transp=0
	 )
	 
	 
//calculate stop Loss
stopLossVal = stopLoss==true ? ( strategy.position_avg_price -  (strategy.position_avg_price*0.08) ) : 0

//partial profit
strategy.close(id="RSIDivLE", comment="TP1", qty=strategy.position_size*3/4, when=strategy.position_size>0 and (longTermRSI>=takeProfitRSILevel or crossover(longTermRSI,90)))
strategy.close(id="RSIDivLE",comment="TP2",   qty=strategy.position_size*3/4 , when=crossover(longTermRSI,70))
strategy.close(id="RSIDivLE",comment="TP3",   qty=strategy.position_size/2, when=crossover(longTermRSI,65))
strategy.close(id="RSIDivLE",comment="TP4",   qty=strategy.position_size/2 , when=crossover(longTermRSI,60))

//close the whole position when stoploss hits or longTermRSI goes below 30
strategy.close(id="RSIDivLE",comment="Exit",    when=crossunder(longTermRSI,30) or close<stopLossVal)

Lebih banyak

2019 FMZ - Semua hak dilindungi