二重指標ハイブリッド量的な取引戦略
作者: リン・ハーンチャオチャン,日付: 2023年12月20日 10:31:06タグ:
概要
この戦略は,トレンド方向を特定し,取引を行うために二重指標を組み合わせます.第一に,短期トレンドを判断するために2つの移動平均 (高速および中間) のクロスオーバーを使用します.第二に,チャネル範囲と長期移動平均を使用して主なトレンド方向を決定します. 2つの判断が一貫している場合にのみ取引信号が生成されます.複数の指標を使用するハイブリッド戦略は,誤った信号を効果的にフィルターし,安定性を向上させることができます.
戦略原則
戦略は判断のための3つの指標を使用します.まず,短期トレンドを決定するために,高速EMA (26期) と中期EMA (50期) の黄金十字と死亡十字;次に,中期トレンドを判断するためにチャネル範囲を計算;最後に,長期SMA (200期) を計算し,主要なトレンド方向を決定するために価格と比較します.すべての3つの判断が一貫している場合にのみ,取引シグナルが生成されます.
具体的には,論理は:
-
短期トレンドを決定するために,高速移動平均と中移動平均のクロスオーバー (上昇傾向の黄金クロス,下落傾向の死亡クロス).
-
中期トレンドを決定するために価格がチャネル範囲を突破するかどうか.チャネル範囲は,長期MAプラス/マイナスATR×係数に基づいています.上限を突破すると上昇信号,下限を突破すると下落信号になります.
-
主要な傾向を決定するために,価格と長期MAを比較する.
最後に,取引シグナルは3つの判断が一貫している場合にのみ生成されます.このハイブリッドメカニズムは誤ったシグナルを効果的にフィルターし,安定性を向上させることができます.
戦略 の 利点
この二重指標のハイブリッド戦略にはいくつかの利点があります.
-
誤った信号を効果的にフィルタリングし,安定性を向上させる. 取引信号は単一のメトリックからのエラーを避けるために複数の指標から検証を必要とするからです.
-
異なる市場のためのパラメータを調整する高度な柔軟性.MAとチャネル範囲のパラメータは,さまざまな環境のために調整できます.
-
トレンドトレードとレンジトレードを組み合わせる.中期および短期指標はトレンドを捉え,長期指標はレンジを決定する.全体的にトレンドと平均逆転戦略の両方のメリットを持っています.
-
高資本利用効率.複数の指標が一致するときにのみ注文を入れ,資本は不必要な取引を避けるために効果的に利用できます.
戦略リスク
リスクもあります:
-
パラメータ設定リスク. MA 期間とチャネル範囲は適切な設定が必要で,不適切な設定はトレンドを検出できず,過剰な偽信号を引き起こす可能性があります.
-
二重指標による機会コストの増加.単一指標戦略と比較して,最適なポイントで入力および終了できないため,いくつかの取引機会が逃れることがあります.
-
ストップ・ロスのメカニズムは慎重さが必要です.ここでのブレイクストップ・ロスは不必要な損失を引き起こす可能性があります.ストップ・ロスの割合は慎重に設定する必要があります.
-
この戦略は,傾向が顕著な市場でよりうまく機能します.
戦略の最適化
戦略は以下の側面から改善できます.
-
最適な設定を見つけるために,過去のデータでバックテストを重ねます.
-
適応型ストップ損失メカニズムを追加します. 動的ストップ損失レベルを調節します.
-
重要な点でのボリューム指標を 支援する.資本効率を向上させるため,ボリュームによるポジションサイズ判断.
-
エントリーロジックを最適化する. 単一のエントリーリスクを減らすためにコスト平均を伴う段階的なエントリーを検討する.
-
機械学習モデルを組み合わせ モデルの強さと適性を判断する 神経ネットワークを導入します
概要
この戦略は,三重タイムフレーム指標と二重検証を活用して誤った信号を抑制し安定性を向上させる.一方,トレンドとレンジ取引の両方のメリットを有し,資本使用効率が高い.パラメータ最適化,ストップ損失調整,ボリューム指標との統合などにより強化することができる.推奨されるハイブリッド定量戦略.
/*backtest
start: 2023-11-19 00:00:00
end: 2023-12-19 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=5
// Indicator to combines:
// Trend Channel[Gu5] (SMA 200) +
// EMA's cross (26, 50 ) +
// Golden Cross (50, 200)
// Author: @gu5tavo71 08/2019
// v2.3.6, 2022.02.18
// Trend Channel [Gu5] // Author: @gu5tavo71 08/2019
//
// This source code is subject to these terms:
// Attribution-NonCommercial 4.0 International (CC BY-NC 4.0)
// https://www.safecreative.org/work/2202190517452-mix1-ema-cross-trend-channel-gu5-
// You are free to:
// Share, copy and redistribute this script
// Adapt, transform and build on this script
// Under the following terms:
// Non-commercial: You cannot sell my indicator. You can't sell my work.
// Attribution: If you post part of my code, you must give me proper credit
//
// I am using part of this code published by @PineCoders and Public Library
// Disclaimer: I am not a financial advisor.
// For purpose educate only. Use at your own risk.
strategy(title = 'Mix1 : Ema Cross + Trend Channel [Gu5] - Backtest', shorttitle = 'Mix01', overlay = true,
initial_capital = 100,
default_qty_value = 100,
default_qty_type = strategy.percent_of_equity,
commission_value = 0.075,
commission_type = strategy.commission.percent,
format = format.price,
precision = 2,
process_orders_on_close = true)
// --------- Inputs "==============================" |
i_maSrc = input.source (close, 'MA Source' , group = 'EMAs')
i_maFast1 = input.int (26, 'EMA Fast' , group = 'EMAs')
i_maFast2 = input.int (50, 'EMA Medium' , group = 'EMAs')
i_maLen = input.int (200, 'MA Trend' , group = 'Trend Channel')
o_maLen1 = 'EMA'
o_maLen2 = 'SMA'
i_maLenSel = input.string (o_maLen2, 'MA Type' , group = 'Trend Channel',
options = [o_maLen1, o_maLen2],
tooltip = "EMA or SMA")
i_htf = input.timeframe ('', 'Select Higher Timeframe' , tooltip = 'Only for MA Trend' , group = 'Trend Channel')
i_rangeLen = input.float (0.618, 'Channel Range Length' , tooltip = 'ATR of the MA Trend', group = 'Trend Channel')
i_slOn = input.bool (false, '■ Stop Loss On/Off' , group = 'Stop Loss')
i_sl = input.float (2.618, 'SL %' , step = 0.1, group = 'Stop Loss')
i_periodSw = input.bool (true, '■ Period On/Off' , group = 'Period')
o_start = timestamp ( '2020-01-01 00:00 GMT-3' )
o_end = timestamp ( '2099-12-31 00:00 GMT-3' )
i_periodStar = input (o_start, 'Start Time' , group = 'Period')
i_periodEnd = input (o_end, 'End Time' , group = 'Period')
o_posSel1 = 'Only Long'
o_posSel2 = 'Only Short'
o_posSel3 = 'Both'
i_posSel = input.string (o_posSel3, 'Position Type' , group = 'Strategy',
options = [o_posSel1, o_posSel2, o_posSel3],
tooltip = "Only Long, Only short or Both")
o_typeS1 = 'Strategy 1'
o_typeS2 = 'Strategy 2'
i_typeS = input.string (o_typeS2, 'Strategy Type' , group = 'Strategy',
options = [o_typeS1, o_typeS2],
tooltip = "Strategy 1:\nLong, when the price (close) crosses the ema.\nStrategy 2:\nLong, only when ema goes up")
i_barColOn = input.bool (true, '■ Bar Color On/Off' , group = 'Display')
i_alertOn = input.bool (false, '■ Alert On/Off' , group = 'Display')
i_channelOn = input.bool (false, '■ Channel Range On/Off' , tooltip = 'If the price (close) is over than the channel, the trend is bullish. If the price is under, bearish. And if the price is in the channel, it is in range', group = 'Display')
i_goldenOn = input.bool (false, '■ Golden Cross On/Off' )
o_alert = '{{strategy.order.comment}}'
i_alert = input.string (o_alert, 'Setting alert' , tooltip = 'For Alerts, just copy {{strategy.order.comment}} and paste in alert window.', group = 'Display')
// --------- Calculations
maFast1 = ta.ema(i_maSrc, i_maFast1)
maFast2 = ta.ema(i_maSrc, i_maFast2)
maDir = maFast1 > maFast2 ? 1 : -1
maTrend = request.security(syminfo.tickerid, i_htf,
i_maLenSel == "SMA" ? ta.sma(close, i_maLen)[1] : ta.ema(close, i_maLen)[1],
lookahead = barmerge.lookahead_on) //No repaint
maTrendDir = i_maSrc >= maTrend ? 1 : -1
rangeAtr = ta.atr(i_maLen) * i_rangeLen
rangeTop = maTrend + rangeAtr
rangeBot = maTrend - rangeAtr
rangeCh = (open <= rangeTop or close <= rangeTop) and
(open >= rangeBot or close >= rangeBot)
trendDir = i_typeS == 'Strategy 1' ?
rangeCh ? 0 :
maTrendDir == 1 and maDir == 1 and maTrend > maFast2 ? 0 :
maTrendDir == -1 and maDir == -1 and maTrend < maFast2 ? 0 :
maTrendDir == 1 and maDir == 1 ? 1 :
maTrendDir == -1 and maDir == -1 ? -1 : 0 :
rangeCh ? 0 :
maTrendDir == 1 and maDir == 1 ? 1 :
maTrendDir == -1 and maDir == -1 ? -1 : 0
GCross = i_goldenOn ? ta.crossover (maFast2, maTrend) : na
DCross = i_goldenOn ? ta.crossunder(maFast2, maTrend) : na
period = true
// Set initial values
condition = 0.0
entryLong = trendDir == 1 and
i_posSel != 'Only Short' and
(i_periodSw ? period : true)
entryShort = trendDir == -1 and
i_posSel != 'Only Long' and
(i_periodSw ? period : true)
exitLong = (trendDir != 1 or maDir == -1) and
condition[1] == 1 and
i_posSel != 'Only Short' and
(i_periodSw ? period : true)
exitShort = (trendDir != -1 or maDir == 1) and
condition[1] == -1 and
i_posSel != 'Only Long' and
(i_periodSw ? period : true)
closeCond = exitLong or exitShort
// Stop Loss (sl)
slEntry = close * i_sl / 100
slTop = close + slEntry
slBot = close - slEntry
slTopBuff = ta.valuewhen(condition[1] != 1 and entryLong, slBot, 0)
slBotBuff = ta.valuewhen(condition[1] != -1 and entryShort, slTop, 0)
slLine = condition[1] == -1 and entryLong ? slTopBuff :
condition[1] == 1 and entryShort ? slBotBuff :
condition[1] == 1 or entryLong ? slTopBuff :
condition[1] == -1 or entryShort ? slBotBuff : na
slTopCross = condition[1] == 1 and ta.crossunder(close, slLine) or high > slLine and low < slLine
slBotCross = condition[1] == -1 and ta.crossover (close, slLine) or high > slLine and low < slLine
slExit = i_slOn ? slTopCross or slBotCross : na
// Conditions
condition := condition[1] != 1 and entryLong ? 1 :
condition[1] != -1 and entryShort ? -1 :
condition[1] != 0 and slExit ? 0 :
condition[1] != 0 and exitLong ? 0 :
condition[1] != 0 and exitShort ? 0 : nz(condition[1])
long = condition[1] != 1 and condition == 1
short = condition[1] != -1 and condition == -1
xl = condition[1] == 1 and exitLong and not slExit
xs = condition[1] == -1 and exitShort and not slExit
sl = condition[1] != 0 and slExit
// --------- Colors
c_green = #006400 //Green
c_greenLight = #388e3c //Green Light
c_red = #8B0000 //Red
c_redLight = #b71c1c //Red Light
c_emas = xl ? color.new(color.orange, 99) :
xs ? color.new(color.orange, 99) :
trendDir == 1 and maDir == 1 ? color.new(c_green, 99) :
trendDir == -1 and maDir == -1 ? color.new(c_red, 99) :
color.new(color.orange, 99)
c_maFill = xl ? color.new(color.orange, 70) :
xs ? color.new(color.orange, 70) :
trendDir == 1 and maDir == 1 ? color.new(c_green, 70) :
trendDir == -1 and maDir == -1 ? color.new(c_red, 70) :
color.new(color.orange, 70)
c_maTrend = trendDir == 0 ? color.new(color.orange, 0) :
trendDir == 1 and maTrend[1] < maTrend ? color.new(c_green, 0) :
trendDir == 1 and maTrend[1] >= maTrend ? color.new(c_greenLight, 0) :
trendDir == -1 and maTrend[1] < maTrend ? color.new(c_redLight, 0) :
trendDir == -1 and maTrend[1] >= maTrend ? color.new(c_red, 0) : na
c_ch = trendDir == 0 ? color.new(color.orange, 50) :
trendDir == 1 ? color.new(c_green, 50) :
trendDir == -1 ? color.new(c_red, 50) : na
c_slLineUp = ta.rising (slLine, 1)
c_slLineDn = ta.falling(slLine, 1)
c_slLine = c_slLineUp ? na :
c_slLineDn ? na : color.red
c_barCol = trendDir == 0 ? color.new(color.orange, 0) :
trendDir == 1 and open <= close ? color.new(c_green, 0) :
trendDir == 1 and open > close ? color.new(c_greenLight, 0) :
trendDir == -1 and open >= close ? color.new(c_red, 0) :
trendDir == -1 and open < close ? color.new(c_redLight, 0) :
color.new(color.orange, 0)
// --------- Plots
p_maFast1 = plot(
maFast1,
title = 'EMA Fast 1',
color = c_emas,
linewidth = 1)
p_maFast2 = plot(
maFast2,
title = 'EMA Fast 2',
color = c_emas,
linewidth = 2)
fill(
p_maFast1, p_maFast2,
title = 'EMAs Fill',
color = c_maFill)
plot(
maTrend,
title = 'SMA Trend',
color = c_maTrend,
linewidth = 3)
p_chTop = plot(
i_channelOn ? rangeTop : na,
title = 'Top Channel',
color = c_maTrend,
linewidth = 1)
p_chBot = plot(
i_channelOn ? rangeBot : na,
title = 'Bottom Channel',
color = c_maTrend,
linewidth = 1)
fill(
p_chTop, p_chBot,
title = 'Channel',
color = c_ch)
plot(
i_slOn and condition != 0 ? slLine : na,
title = 'Stop Loss Line',
color = c_slLine,
linewidth = 1,
style = plot.style_linebr)
// --------- Alerts
barcolor(i_barColOn ? c_barCol : na)
plotshape(
i_alertOn and long ? high : na,
title = 'Long Label',
text = 'Long',
textcolor = color.white,
color = color.new(c_green, 0),
style = shape.labelup,
size = size.normal,
location = location.belowbar)
plotshape(
i_alertOn and short ? low : na,
title = 'Short Label',
text = 'Short',
textcolor = color.white,
color = color.new(c_red, 0),
style = shape.labeldown,
size = size.normal,
location = location.abovebar)
plotshape(
i_alertOn and (xl or xs) ? close : na,
title = 'Close Label',
text = 'Close',
textcolor = color.orange,
color = color.new(color.orange, 0),
style = shape.xcross,
size = size.small,
location = location.absolute)
plotshape(
i_alertOn and sl ? slLine : na,
title = 'Stop Loss',
text = 'Stop\nLoss',
textcolor = color.orange,
color = color.new(color.orange, 0),
style = shape.xcross,
size = size.small,
location = location.absolute)
plotshape(
i_alertOn and i_goldenOn and GCross ? maTrend : na,
title = 'Golden Cross Label',
text = 'Golden\nCross',
textcolor = color.white,
color = color.new(color.orange, 0),
style = shape.labelup,
size = size.normal,
location = location.absolute)
plotshape(
i_alertOn and i_goldenOn and DCross ? maTrend : na,
title = 'Death Cross Label',
text = 'Death\nCross',
textcolor = color.white,
color = color.new(color.orange, 0),
style = shape.labeldown,
size = size.normal,
location = location.absolute)
bgcolor(
i_periodSw and not period ? color.new(color.gray, 90) : na,
title = 'Session')
// --------- Backtest
if long and strategy.position_size == 0 and barstate.isconfirmed
strategy.entry('Long', strategy.long, comment = 'long')
if short and strategy.position_size == 0 and barstate.isconfirmed
strategy.entry('Short', strategy.short, comment = 'short')
strategy.exit(
id = 'XL',
from_entry = 'Long',
stop = i_slOn ? slLine : na)
strategy.exit(
id = 'XS',
from_entry = 'Short',
stop = i_slOn ? slLine : na)
strategy.close(
'Long',
comment = 'Close',
when = xl)
strategy.close(
'Short',
comment = 'Close',
when = xs)
もっと
- 2つの移動平均範囲のブレークアウト戦略
- 移動平均線を持つグリッド戦略
- 二重移動平均知能追跡戦略
- RSI-EMA トレンドブレイク戦略
- ターンポイント予測オシレーター バックテスト戦略
- 移動平均戦略に基づく統合されたイチモク・ケルトナー取引システム
- 二重追跡の亀取引戦略
- イチモク・キンコ・ヒョー ベースBTC取引戦略
- AO指標に基づく傾向 戦略をフォローする
- ユニバーサル・スナイパー戦略
- ボリンジャー・バンドス・モメンタム・ブレイクアウト戦略
- ボリンジャー・バンド 移動平均に基づく短期逆転量的な戦略
- グラデントMACD量子戦略
- 双方向の迅速量的な逆転取引戦略
- ハイキン・アシとカウフマン 適応型移動平均取引戦略
- モメントブレイク・トレード戦略
- イチモク移動平均クロスオーバー戦略
- 動力と取引量戦略
- フラクタル・ブレークアウト戦略
- ビル・ウィリアムズ 素晴らしいオシレーター取引戦略