O recurso está a ser carregado... Carregamento...
  1. Quadrado
  2. Esta é uma estratégia de negociação quantitativa experimental.

Esta é uma estratégia de negociação quantitativa experimental.

Autora:ChaoZhang, Data: 22-12-2023 14:13:27
Tags:

img

Resumo

Esta é uma estratégia de negociação quantitativa experimental que combina indicadores de média móvel e algoritmos de aprendizado de máquina kNN para gerar sinais de negociação.

Princípios de estratégia

Os principais indicadores desta estratégia são duas linhas VWMA com parâmetros diferentes, ou seja, linha rápida e linha lenta. Quando a linha rápida cruza acima da linha lenta, um sinal de compra é gerado. Quando a linha rápida cruza abaixo da linha lenta, um sinal de venda é gerado. Além disso, esta estratégia introduz dois indicadores auxiliares, MFI e ADX, para julgar a confiabilidade do sinal atual sob as condições atuais do mercado através do algoritmo de classificação kNN.

A ideia por trás do algoritmo kNN é comparar novos dados com dados históricos para determinar os resultados correspondentes aos dados históricos k mais semelhantes e categorizar com base no voto da maioria desses resultados históricos k. Esta estratégia usa MFI e ADX como dois parâmetros de entrada do algoritmo kNN para determinar o movimento histórico de preços (uptrend ou downtrend) sob esta combinação de indicadores, filtrando assim o sinal atual para melhorar a qualidade do sinal.

Vantagens

  • Utilizar a capacidade de seguir a tendência do VWMA e gerar sinais de negociação através de cruzamento de médias móveis
  • Aplicar indicadores de IFM e ADX para extração de características multidimensionais para ajudar a determinar a direção da tendência
  • Aproveitar o algoritmo de aprendizado de máquina kNN para otimizar e filtrar dinamicamente os sinais de negociação
  • Estratégia experimental com grande margem de melhoria através de mais verificação e otimização de dados

Riscos e atenuações

  • Linhas VWMA tendem a atrasar
  • As IFM e as ADX têm algum atraso, o que pode induzir em erro as condições de mercado
  • Os parâmetros do algoritmo kNN (por exemplo, valor k) podem ter um impacto significativo nos resultados
  • A estratégia experimental pode ter um desempenho inferior na negociação ao vivo

Atenuantes:

  • Ajustar os parâmetros MA para reduzir o atraso
  • Melhorar os indicadores para avaliar com mais precisão as tendências
  • Otimizar os parâmetros kNN para melhorar a aptidão
  • Verificar a estratégia através de backtest e negociação em papel

Orientações de otimização

Há muito espaço para otimizar esta estratégia:

  • Adicionar mais indicadores MA para construir combinações MA
  • Tente diferentes indicadores auxiliares como MACD, KDJ etc.
  • Melhorar o algoritmo kNN, por exemplo, usando diferentes métricas de distância
  • Tente outros algoritmos de aprendizagem de máquina como SVM, Random Forest etc
  • Ajuste de parâmetros para encontrar conjuntos de parâmetros ideais

A introdução de mais indicadores e algoritmos de aprendizagem automática pode melhorar ainda mais a estabilidade e a rentabilidade da estratégia.

Resumo

Esta é uma estratégia de negociação quantitativa experimental baseada em indicadores VWMA e algoritmos de aprendizado de máquina kNN. Tem a vantagem de forte capacidade de seguir tendências enquanto filtra sinais por meio de aprendizado de máquina. A estratégia tem grande espaço para expansão através da introdução de mais recursos e algoritmos de otimização para melhores resultados.

/*backtest
start: 2023-11-21 00:00:00
end: 2023-12-21 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © lastguru

//@version=4
strategy(title="VWMA with kNN Machine Learning: MFI/ADX", shorttitle="VWMA + kNN: MFI/ADX", overlay=true, default_qty_type=strategy.percent_of_equity, default_qty_value=100)

/////////
// kNN //
/////////

// Define storage arrays for: parameter 1, parameter 2, price, result (up = 1; down = -1)
var knn1 = array.new_float(1, 0)
var knn2 = array.new_float(1, 0)
var knnp = array.new_float(1, 0)
var knnr = array.new_float(1, 0)

// Store the previous trade; buffer the current one until results are in
_knnStore (p1, p2, src) =>
    var prevp1 = 0.0
    var prevp2 = 0.0
    var prevsrc = 0.0
    
    array.push(knn1, prevp1)
    array.push(knn2, prevp2)
    array.push(knnp, prevsrc)
    array.push(knnr, src >= prevsrc ? 1 : -1)
    
    prevp1 := p1
    prevp2 := p2
    prevsrc := src

// Sort two arrays (MUST be of the same size) based on the first.
// In other words, when an element in the first is moved, the element in the second moves as well.
_knnGet(arr1, arr2, k) =>
    sarr = array.copy(arr1)
    array.sort(sarr)
    ss = array.slice(sarr, 0, min(k, array.size(sarr)))
    m = array.max(ss)
    out = array.new_float(0)
    for i = 0 to array.size(arr1) - 1
        if (array.get(arr1, i) <= m)
            array.push(out, array.get(arr2, i))
    out

// Create a distance array from the two given parameters
_knnDistance(p1, p2) =>
    dist = array.new_float(0)
    n = array.size(knn1) - 1
    for i = 0 to n
        d = sqrt( pow(p1 - array.get(knn1, i), 2) + pow(p2 - array.get(knn2, i), 2) )
        array.push(dist, d)
    dist

// Make a prediction, finding k nearest neighbours
_knn(p1, p2, k) =>
    slice = _knnGet(_knnDistance(p1, p2), array.copy(knnr), k)
    knn = array.sum(slice)

////////////
// Inputs //
////////////

SRC = input(title="Source", type=input.source, defval=open)
FAST = input(title="Fast Length", type=input.integer, defval=13)
SLOW = input(title="Slow Length", type=input.integer, defval=19)
FILTER = input(title="Filter Length", type=input.integer, defval=13)
SMOOTH = input(title="Filter Smoothing", type=input.integer, defval=6)
KNN = input(title="kNN nearest neighbors (k)", type=input.integer, defval=23)
BACKGROUND = input(false,title = "Draw background")

////////
// MA //
////////
fastMA = vwma(SRC, FAST)
slowMA = vwma(SRC, SLOW)

/////////
// DMI //
/////////

// Wilder's Smoothing (Running Moving Average)
_rma(src, length) =>
    out = 0.0
    out := ((length - 1) * nz(out[1]) + src) / length

// DMI (Directional Movement Index)
_dmi (len, smooth) =>
    up = change(high)
    down = -change(low)
    plusDM = na(up) ? na : (up > down and up > 0 ? up : 0)
    minusDM = na(down) ? na : (down > up and down > 0 ? down : 0)
    trur = _rma(tr, len)
    plus = fixnan(100 * _rma(plusDM, len) / trur)
    minus = fixnan(100 * _rma(minusDM, len) / trur)
    sum = plus + minus
    adx = 100 * _rma(abs(plus - minus) / (sum == 0 ? 1 : sum), smooth)
    [plus, minus, adx]

[diplus, diminus, adx] = _dmi(FILTER, SMOOTH)

/////////
// MFI //
/////////

// common RSI function
_rsi(upper, lower) =>
    if lower == 0
        100
    if upper == 0
        0
	100.0 - (100.0 / (1.0 + upper / lower))

mfiUp = sum(volume * (change(ohlc4) <= 0 ? 0 : ohlc4), FILTER)
mfiDown = sum(volume * (change(ohlc4) >= 0 ? 0 : ohlc4), FILTER)
mfi = _rsi(mfiUp, mfiDown)

////////////
// Filter //
////////////

longCondition = crossover(fastMA, slowMA)
shortCondition = crossunder(fastMA, slowMA)

if (longCondition or shortCondition)
    _knnStore(adx, mfi, SRC)
filter = _knn(adx, mfi, KNN)

/////////////
// Actions //
/////////////

bgcolor(BACKGROUND ? filter >= 0 ? color.green : color.red : na)
plot(fastMA, color=color.red)
plot(slowMA, color=color.green)

if (longCondition and filter >= 0)
    strategy.entry("Long", strategy.long)
if (shortCondition and filter < 0)
    strategy.entry("Short", strategy.short)
Mais.

2019 FMZ - Todos os direitos reservados