1. مربع
2. ریورس میڈین بریکنگ اسٹریٹیجی

ریورس میڈین بریکنگ اسٹریٹیجی

مصنف:چاؤ ژانگ، تاریخ: 2023-12-20 14:48:57
ٹیگز:

---

---

/*backtest
start: 2023-12-12 00:00:00
end: 2023-12-19 00:00:00
period: 3m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy(title='BroTheJo Strategy', shorttitle='BTJ INV', overlay=true)

// Input settings
stopLossInPips = input.int(10, minval=0, title='Stop Loss (in Pips)')
ccimomCross = input.string('CCI', 'Entry Signal Source', options=['CCI', 'Momentum'])
ccimomLength = input.int(10, minval=1, title='CCI/Momentum Length')
useDivergence = input.bool(false, title='Find Regular Bullish/Bearish Divergence')
rsiOverbought = input.int(65, minval=1, title='RSI Overbought Level')
rsiOversold = input.int(35, minval=1, title='RSI Oversold Level')
rsiLength = input.int(14, minval=1, title='RSI Length')
plotMeanReversion = input.bool(true, 'Plot Mean Reversion Bands on the chart')
emaPeriod = input(200, title='Lookback Period (EMA)')
bandMultiplier = input.float(1.6, title='Outer Bands Multiplier')

// CCI and Momentum calculation
momLength = ccimomCross == 'Momentum' ? ccimomLength : 10
mom = close - close[momLength]
cci = ta.cci(close, ccimomLength)
ccimomCrossUp = ccimomCross == 'Momentum' ? ta.cross(mom, 0) : ta.cross(cci, 0)
ccimomCrossDown = ccimomCross == 'Momentum' ? ta.cross(0, mom) : ta.cross(0, cci)

// RSI calculation
src = close
up = ta.rma(math.max(ta.change(src), 0), rsiLength)
down = ta.rma(-math.min(ta.change(src), 0), rsiLength)
rsi = down == 0 ? 100 : up == 0 ? 0 : 100 - 100 / (1 + up / down)
oversoldAgo = rsi[0] <= rsiOversold or rsi[1] <= rsiOversold or rsi[2] <= rsiOversold or rsi[3] <= rsiOversold
overboughtAgo = rsi[0] >= rsiOverbought or rsi[1] >= rsiOverbought or rsi[2] >= rsiOverbought or rsi[3] >= rsiOverbought

// Regular Divergence Conditions
bullishDivergenceCondition = rsi[0] > rsi[1] and rsi[1] < rsi[2]
bearishDivergenceCondition = rsi[0] < rsi[1] and rsi[1] > rsi[2]

// Mean Reversion Indicator
meanReversion = plotMeanReversion ? ta.ema(close, emaPeriod) : na
stdDev = plotMeanReversion ? ta.stdev(close, emaPeriod) : na
upperBand = plotMeanReversion ? meanReversion + stdDev * bandMultiplier : na
lowerBand = plotMeanReversion ? meanReversion - stdDev * bandMultiplier : na

// Entry Conditions
prevHigh = ta.highest(high, 1)
prevLow = ta.lowest(low, 1)
shortEntryCondition = ccimomCrossUp and oversoldAgo and (not useDivergence or bullishDivergenceCondition) and (prevHigh >= meanReversion) and (prevLow >= meanReversion)
longEntryCondition = ccimomCrossDown and overboughtAgo and (not useDivergence or bearishDivergenceCondition) and (prevHigh <= meanReversion) and (prevLow <= meanReversion)

// Plotting
oldShortEntryCondition = ccimomCrossUp and oversoldAgo and (not useDivergence or bullishDivergenceCondition)
oldLongEntryCondition = ccimomCrossDown and overboughtAgo and (not useDivergence or bearishDivergenceCondition)
plotshape(oldLongEntryCondition, title='BUY', style=shape.triangleup, text='B', location=location.belowbar, color=color.new(color.lime, 0), textcolor=color.new(color.white, 0), size=size.tiny)
plotshape(oldShortEntryCondition, title='SELL', style=shape.triangledown, text='S', location=location.abovebar, color=color.new(color.red, 0), textcolor=color.new(color.white, 0), size=size.tiny)

// Strategy logic
if (longEntryCondition)
    stopLoss = close - stopLossInPips
    strategy.entry("Buy", strategy.long)
    strategy.exit("exit", "Buy", stop=stopLoss)
if (shortEntryCondition)
    stopLoss = close + stopLossInPips
    strategy.entry("Sell", strategy.short)
    strategy.exit("exit", "Sell", stop=stopLoss)

// Close all open positions when outside of bands
closeAll = (high >= upperBand) or (low <= lowerBand)

if (closeAll)
    strategy.close_all("Take Profit/Cut Loss")

// Plotting
plot(upperBand, title='Upper Band', color=color.fuchsia, linewidth=1)
plot(meanReversion, title='Mean', color=color.gray, linewidth=1)
plot(lowerBand, title='Lower Band', color=color.blue, linewidth=1)

---

• بولنگر بینڈ اور ایم اے سی ڈی پر مبنی تجارتی حکمت عملی
• میکڈ بلیو ریڈ لیوریج حکمت عملی
• رفتار کی گرفتاری چینل کی حکمت عملی
• ہیجنگ اوسیلیشن ریورسنگ حکمت عملی
• بولنگر بینڈ اور آر ایس آئی پر مبنی مقداری تجارتی حکمت عملی
• نسبتا حجم اشارے کی حکمت عملی
• اوکٹاگون کلاؤڈ ٹریکنگ حکمت عملی
• امکان سے بہتر آر ایس آئی حکمت عملی
• ٹرپل ای ایم اے رجحان کی پیروی کی حکمت عملی
• سٹین دی مین - ایک اعلی درجے کی اسٹاک ٹریڈنگ کی حکمت عملی دوہری چلتی اوسط اور اتار چڑھاؤ پر مبنی ہے
• دوہری حرکت پذیر اوسط کی تبدیلی کی حکمت عملی
• لاگارتھمک قیمت کی پیشن گوئی کی حکمت عملی
• سادہ حرکت پذیر اوسط کراس اوور حکمت عملی
• بولنگر بینڈ اور آر ایس آئی رجحان کی پیروی کرنے والی حکمت عملی
• ای ایم اے کی کراس اوور حکمت عملی
• چلتی اوسط پر مبنی حکمت عملی کے بعد رجحان
• RSI ٹریڈنگ حکمت عملی
• Turtle ٹرینڈ ٹریڈنگ سسٹم
• کثیر حرکت پذیر اوسطوں کی کراس ٹریڈنگ کی حکمت عملی
• سٹاپ نقصان/فائدہ لینے کے ساتھ لچکدار ایم اے/وی ڈبلیو اے پی کراس اوور حکمت عملی