En la carga de los recursos... Cargando...

Estrategia de ruptura de impulso

El autor:¿ Qué pasa?, Fecha: 2023-12-13 17:08:53
Las etiquetas:

Resumen general

Esta estrategia combina el promedio móvil, el indicador RSI de Laguerre y el indicador ADX para implementar el comercio de ruptura. Se hace largo cuando el promedio móvil rápido cruza por encima del promedio móvil lento, el RSI de Laguerre es mayor que 80, y el ADX es mayor que 20; se hace corto cuando el promedio móvil rápido cruza por debajo del promedio móvil lento, el RSI de Laguerre es menor que 20 y el ADX es mayor que 20.

Principio

La estrategia utiliza principalmente los siguientes indicadores para determinar las tendencias y el calendario de entrada:

Combinación de medias móviles: EMA de 16 días, EMA de 48 días, SMA de 200 días. Se determina una tendencia alcista cuando el promedio a corto plazo cruza por encima del promedio a largo plazo y una tendencia bajista cuando cruza por debajo.
Indicador RSI de Laguerre para determinar zonas de sobrecompra y sobreventa.
Indicador ADX para determinar el estado de la tendencia.

Las señales de entrada se determinan por la dirección de la combinación de promedios móviles, el tiempo de entrada por el RSI de Laguerre y los mercados que no están en tendencia son filtrados por el ADX. Las señales de salida se generan cuando los promedios móviles se cruzan hacia atrás.

Los puntos fuertes

Las ventajas de esta estrategia incluyen:

Capturar el impulso de la tendencia: La estrategia solo entra en el mercado al comienzo del desarrollo de la tendencia, capturando ganancias exponenciales de las tendencias.
Pérdidas limitadas: las pérdidas de parada establecidas adecuadamente limitan las pérdidas de operaciones individuales.
Indicadores combinados precisos: Los promedios móviles, Laguerre RSI y ADX pueden determinar con relativa precisión la dirección del mercado y el momento de entrada.
Implementación sencilla: la estrategia utiliza sólo 3 indicadores y es fácil de entender e implementar.

Los riesgos

También hay algunos riesgos para la estrategia:

Riesgos de reversión de tendencia: como estrategia de tendencia, pueden producirse grandes pérdidas si no se detectan las reversiones de tendencia a tiempo.
Riesgos de extracción: en los mercados variados, pueden producirse paradas que conducen a extracciones de cuentas.
Riesgos de optimización de parámetros: los parámetros de los indicadores deben ajustarse para diferentes mercados para evitar fallos.

Contramedidas:

Las pérdidas estrictas para limitar los importes de pérdidas de operaciones individuales.
Optimizar los parámetros del indicador y los umbrales de ruptura.
Utilice la cobertura de futuros, etc., para gestionar las reducciones.

Direcciones de optimización

Algunas formas de optimizar la estrategia incluyen:

Optimización de parámetros: prueba de combinaciones de períodos de media móvil, parámetros RSI de Laguerre, parámetros ADX para encontrar ajustes óptimos.
Optimización de la ruptura: Prueba diferentes umbrales de ruptura de la media móvil para equilibrar la frecuencia y la rentabilidad de las operaciones.
Optimización de la entrada: Prueba otros indicadores combinados con el RSI de Laguerre para obtener un tiempo de entrada más preciso.
Optimización de salida: Investigue otras señales de salida en combinación con promedios móviles.
Optimización de la toma de ganancias frente a la optimización de pérdidas de parada: Pruebe diferentes estrategias para optimizar los rendimientos.

Resumen de las actividades

En resumen, esta estrategia captura efectivamente los movimientos de tendencia mediante la combinación de promedios móviles, Laguerre RSI y ADX para determinar entradas y salidas. Al entrar temprano en los desarrollos de tendencia y seguir de cerca las tendencias, se pueden obtener ganancias exponenciales, mientras que las pérdidas de parada ayudan a limitar las pérdidas. La estrategia es adecuada para los inversores cómodos al hacer juicios de mercado, así como para aquellos que realizan operaciones automatizadas después de la optimización de parámetros.

/*backtest
start: 2023-12-05 00:00:00
end: 2023-12-12 00:00:00
period: 1m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © PtGambler

//@version=5
strategy("3MA + Laguerre RSI + ADX [Pt]", shorttitle = "3MA+LaRSI+ADX[Pt]", overlay=true, initial_capital = 10000, default_qty_type = strategy.percent_of_equity, default_qty_value = 100, calc_on_order_fills = false, max_bars_back = 500)


// ********************************** Trade Period / Strategy Setting **************************************
startY = input(title='Start Year', defval=2011, group = "Backtesting window")
startM = input.int(title='Start Month', defval=1, minval=1, maxval=12, group = "Backtesting window")
startD = input.int(title='Start Day', defval=1, minval=1, maxval=31, group = "Backtesting window")
finishY = input(title='Finish Year', defval=2050, group = "Backtesting window")
finishM = input.int(title='Finish Month', defval=12, minval=1, maxval=12, group = "Backtesting window")
finishD = input.int(title='Finish Day', defval=31, minval=1, maxval=31, group = "Backtesting window")
timestart = timestamp(startY, startM, startD, 00, 00)
timefinish = timestamp(finishY, finishM, finishD, 23, 59)
use_entry_sess = input.bool(false, 'Use Entry Session Window', group = "Trading Session")
t1_session = input("0930-1555:23456", "Entry Session", group="Trading Session", tooltip = "Entry Signal only generated within this period.") 
t1 = time(timeframe.period, t1_session)
window = true

margin_req = input.float(1, title="Margin Requirement / Leverage", step=0.1, group = "Trading Options")
qty_per_trade = input.float(100, title = "% of initial capital per trade", group = "Trading Options")
reinvest = input.bool(defval=false,title="Reinvest profit", group = "Trading Options")
reinvest_percent = input.float(defval=100, title = "Reinvest percentage", group="Trading Options")

close_eod = input.bool(false, "All trades will close at the close of trading window", group = "Trading Options")
close_b4_open = input.bool(false, "Position must hit either SL/PT before entering new trade", group = "Trading Options")

profit = strategy.netprofit 
strategy.initial_capital = 50000
float trade_amount = math.floor(strategy.initial_capital*margin_req / close) 

if strategy.netprofit > 0 and reinvest
    trade_amount := math.floor((strategy.initial_capital* (qty_per_trade/100)+(profit*reinvest_percent*0.01))*margin_req/ close) 
else
    trade_amount := math.floor(strategy.initial_capital* (qty_per_trade/100)*margin_req / close)  

// ******************************************************************************************

group_ma = "Moving Average Ribbon"
group_larsi = "Laguerre RSI"
group_adx = "ADX"
group_SL = "Stop Loss / Profit Target"

// ----------------------------------------- MA Ribbon -------------------------------------

ema1_len = input.int(16, "Fast EMA Length", group = group_ma)
ema2_len = input.int(48, "Slow EMA Length ", group = group_ma)
sma1_len = input.int(200, "Slow SMA Length", group = group_ma)

ema1 = ta.ema(close, ema1_len)
ema2 = ta.ema(close, ema2_len)
sma1 = ta.sma(close, sma1_len)

plot(ema1, "EMA 1", color.white, linewidth = 2)
plot(ema2, "EMA 2", color.yellow, linewidth = 2)
plot(sma1, "SMA 1", color.purple, linewidth = 2)

ma_bull = ema1 > ema2 and ema2 > sma1   
ma_bear = ema1 < ema2 and ema2 < sma1

// ------------------------------------------ Laguerre RSI ---------------------------------------

alpha = input.float(0.2, title='Alpha', minval=0, maxval=1, step=0.1, group = group_larsi)

gamma = 1 - alpha
L0 = 0.0
L0 := (1 - gamma) * close + gamma * nz(L0[1])
L1 = 0.0
L1 := -gamma * L0 + nz(L0[1]) + gamma * nz(L1[1])

L2 = 0.0
L2 := -gamma * L1 + nz(L1[1]) + gamma * nz(L2[1])

L3 = 0.0
L3 := -gamma * L2 + nz(L2[1]) + gamma * nz(L3[1])

cu = (L0 > L1 ? L0 - L1 : 0) + (L1 > L2 ? L1 - L2 : 0) + (L2 > L3 ? L2 - L3 : 0)

cd = (L0 < L1 ? L1 - L0 : 0) + (L1 < L2 ? L2 - L1 : 0) + (L2 < L3 ? L3 - L2 : 0)

temp = cu + cd == 0 ? -1 : cu + cd
LaRSI = temp == -1 ? 0 : cu / temp
LaRSI := LaRSI * 100

bull_LaRSI = LaRSI > 80
bear_LaRSI = LaRSI < 20

// --------------------------------------- ADX  ------------------------

adxlen = input(14, title="ADX Smoothing", group = group_adx)
dilen = input(14, title="DI Length", group = group_adx)
dirmov(len) =>
	up = ta.change(high)
	down = -ta.change(low)
	plusDM = na(up) ? na : (up > down and up > 0 ? up : 0)
	minusDM = na(down) ? na : (down > up and down > 0 ? down : 0)
	truerange = ta.rma(ta.tr, len)
	plus = fixnan(100 * ta.rma(plusDM, len) / truerange)
	minus = fixnan(100 * ta.rma(minusDM, len) / truerange)
	[plus, minus]
adx(dilen, adxlen) =>
	[plus, minus] = dirmov(dilen)
	sum = plus + minus
	adx = 100 * ta.rma(math.abs(plus - minus) / (sum == 0 ? 1 : sum), adxlen)
sig = adx(dilen, adxlen)

active_adx = sig > 20 //and sig > sig[1]

// ******************************* Profit Target / Stop Loss *********************************************

use_SLPT = input.bool(false, 'Use Fixed SL / PT', group = group_SL)
SL = input.float(50, 'Stop loss in ticks', step = 1, group = group_SL) * syminfo.mintick
PT = input.float(100, "Profit target in ticks", step = 1, group = group_SL) * syminfo.mintick

var L_PT = 0.0
var S_PT = 0.0
var L_SL = 0.0
var S_SL = 0.0

if strategy.position_size > 0
    L_SL := L_SL[1]
    L_PT := L_PT[1]
else if strategy.position_size < 0
    S_SL := S_SL[1]
    S_PT := S_PT[1]
else
    L_SL := close - SL
    L_PT := close + PT
    S_SL := close + SL
    S_PT := close - PT

entry_line = plot(use_SLPT and strategy.position_size != 0 ? strategy.opentrades.entry_price(0) : na, "Entry Price", color.white, linewidth = 1, style = plot.style_linebr)

L_PT_line = plot(use_SLPT and strategy.position_size > 0 ? L_PT : na, "L PT", color.green, linewidth = 2, style = plot.style_linebr)
S_PT_line = plot(use_SLPT and strategy.position_size < 0 ? S_PT : na, "S PT", color.green, linewidth = 2, style = plot.style_linebr)

L_SL_line = plot(use_SLPT and strategy.position_size > 0 ? L_SL : na, "L SL", color.red, linewidth = 2, style = plot.style_linebr)
S_SL_line = plot(use_SLPT and strategy.position_size < 0 ? S_SL : na, "S SL", color.red, linewidth = 2, style = plot.style_linebr)

fill(L_PT_line, entry_line, color = color.new(color.green,90))
fill(S_PT_line, entry_line, color = color.new(color.green,90))
fill(L_SL_line, entry_line, color = color.new(color.red,90))
fill(S_SL_line, entry_line, color = color.new(color.red,90))


// ---------------------------------- Strategy setup ------------------------------------------------------

L_entry1 = ma_bull and bull_LaRSI and active_adx
S_entry1 = ma_bear and bear_LaRSI and active_adx

L_exit1 = ta.crossunder(ema1, ema2)
S_exit1 = ta.crossover(ema1, ema2)

// Trigger zones
bgcolor(ma_bull ? color.new(color.green ,90) : na)
bgcolor(ma_bear ? color.new(color.red,90) : na)

if L_entry1 and (use_entry_sess ? window : true) and (close_b4_open ? strategy.position_size == 0 : true)
    strategy.entry("Long", strategy.long, trade_amount)

if S_entry1 and (use_entry_sess ? window : true) and (close_b4_open ? strategy.position_size == 0 : true)
    strategy.entry("Short", strategy.short, trade_amount)

if use_SLPT
    strategy.exit("Exit Long", "Long", limit = L_PT, stop = L_SL, comment_profit = "Exit Long, PT hit", comment_loss = "Exit Long, SL hit")
    strategy.exit("Exit Short", "Short", limit = S_PT, stop = S_SL, comment_profit = "Exit Short, PT hit", comment_loss = "Exit Short, SL hit")
else
    if L_exit1
        strategy.close("Long", comment = "Exit Long")

    if S_exit1
        strategy.close("Short", comment = "Exit Short")

if use_entry_sess and not window and close_eod
    strategy.close_all(comment = "EOD close")

Más.