資源の読み込みに... 荷物...

基本的Pinbar取引戦略

作者: リン・ハーンチャオチャン開催日:2023年11月15日15時25分57秒
タグ:

概要

この戦略は,トレンドの方向にトレードブレイクアウトに平均を移動することによってトレンド決定のピンバーパターンを利用する.価格がピンバーキャンドルストイックによって形成された高/低から突破したとき,トレード信号を生成する.さらに,全体的なトレンド方向を決定するために高速および遅い移動平均を使用し,範囲限定価格アクション中に間違った信号を避ける.

戦略の論理

移動平均を計算する.
カンデスタイクに基づいて,上昇傾向 (閉じる>開く) と下落傾向 (閉じる<開く) のピンバーを特定します.
ピンバーの高低が前のキャンドルの高低を突破するかどうかを確認する.前回の高値を突破するブライッシュピンバーは長信号を与える.前回の低値を突破するベアッシュピンバーは短信号を与える.
また,上昇傾向を決定するために,高速MAが遅いMAよりも高いかどうかを確認し,下落傾向を決定する場合は逆です.
ロング・シグナルは,高速/遅いMAが上昇傾向を示す場合にのみ有効である.短信号は,高速/遅いMAが下落傾向を示す場合にのみ有効である.これは,レンジ・バインド価格アクション中に間違ったシグナルを避ける.
有効なロング・シグナルでは,既定のストップロスとテイクプロフィットでロング・シグナル.有効なショート・シグナルでは,既定のストップロスとテイクプロフィットでショート・シグナル.
急速なMAが遅いMAを下回る場合は,既存のポジションを閉じる.

利点

ピンバーの高低をブレイクアウトレベルとして使って強いモメンタムを表します
価格の動きの範囲内で誤った信号を避けるためにトレンド方向を考慮し,精度を向上させる.
トレンドとブレイクを把握しトレンド市場で良いパフォーマンスを発揮します
パラメータは,異なる製品と時間枠に最適化できます.

リスクと軽減

失敗した突破リスクはより大きな突破レベルとより強い勢力を使って軽減できます
不正確なトレンド識別リスク.MAパラメータを調整するか,他のトレンド指標を追加することによって軽減できます.
ストップロスは太りすぎて早速終了する. 製品と時間枠に基づいてストップロスを動的に調整できます.
利潤を制限しすぎると利益目標とリスク・報酬比を動的に設定できます

増進の機会

全体的に,MA,ブレイクアウト,ストップロスト,テイクプロフィートのパラメータは,製品とタイムフレームに合わせて最適化され,個別戦略が作れます.
EMA,SMAなどの異なるMAsをテストして最適な指標を見つけることができます
モメントのような追加指標は傾向の精度を向上させることができます
マシン学習技術を使用してパラメータを動的に最適化することができます.
統計学的な学習によって脱出の成功率を向上させることができます

概要

この戦略は,理論的にフィルタリングされたシグナルのためのトレンドとモメンタムを組み合わせます.良いパフォーマンスのために製品とタイムフレームの間で強力なパラメータ最適化が鍵です.さらに,補助指標と機械学習技術により戦略をさらに改善することができます.継続的な改善により,これは強力なトレンドブレークアウト取引システムになることができます.

/*backtest
start: 2023-10-15 00:00:00
end: 2023-11-14 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
//Backtested Time Frame: H1
//Default Settings: Are meant to run successfully on all currency pairs to reduce over-fitting.
//Risk Warning: This is a forex trading robot, backtest performance will not equal future performance, USE AT YOUR OWN RISK.
//Code Warning: Although every effort has been made for robustness, this code has not been vetted by independent 3rd parties.
strategy("Pin Bar Strategy v1", overlay=true)

// User Input
usr_risk = input(title="Equity Risk (%)",type=input.integer,minval=1,maxval=100,step=1,defval=3,confirm=false)
atr_mult = input(title="Stop Loss (x*ATR, Float)",type=input.float,minval=0.1,maxval=100,step=0.1,defval=1.9,confirm=false)
trd_rewd = input(title="Risk : Reward (1 : x*SL, Float)",type=input.float,minval=0.1,maxval=100,step=0.1,defval=3.1,confirm=false)
sma_fast = input(title="Fast MA (Period)",type=input.integer,minval=1,maxval=500,step=1,defval=20,confirm=false)
sma_slow = input(title="Slow MA (Period)",type=input.integer,minval=1,maxval=500,step=1,defval=50,confirm=false)
atr_valu = input(title="ATR (Period)",type=input.integer,minval=1,maxval=500,step=1,defval=14,confirm=false)
use_slpe = input(title="Use MA Slope (Boolean)",type=input.bool,defval=true,confirm=false)
slp_long = input(title="Bull Slope Angle (Deg)",type=input.integer,minval=-90,maxval=90,step=1,defval=1,confirm=false)
slp_shrt = input(title="Bear Slope Angle (Deg)",type=input.integer,minval=-90,maxval=90,step=1,defval=-1,confirm=false)
emg_exit = input(title="Exit When MA Re-Cross (Boolean)",type=input.bool,defval=true,confirm=false)
ent_canc = input(title="Cancel Entry After X Bars (Period)",type=input.integer,minval=1,maxval=500,step=1,defval=3,confirm=false)

// Create Indicators
fastSMA = sma(close, sma_fast)
slowSMA = sma(close, sma_slow)
bullishPinBar = ((close > open) and ((open - low) > 0.66 * (high - low))) or ((close < open) and ((close - low) > 0.66 * (high - low)))
bearishPinBar = ((close > open) and ((high - close) > 0.66 * (high - low))) or ((close < open) and ((high - open) > 0.66 * (high - low)))
atr = atr(atr_valu)

// Specify Trend Conditions
smaUpTrend = (fastSMA > slowSMA) and (fastSMA[1] > slowSMA[1]) and (fastSMA[2] > slowSMA[2]) and (fastSMA[3] > slowSMA[3]) and (fastSMA[4] > slowSMA[4])
smaDnTrend = (fastSMA < slowSMA) and (fastSMA[1] < slowSMA[1]) and (fastSMA[2] < slowSMA[2]) and (fastSMA[3] < slowSMA[3]) and (fastSMA[4] < slowSMA[4])
candleUpTrend = (close[5] > fastSMA[5]) and (open[5] > fastSMA[5]) and (close[6] > fastSMA[6]) and (open[6] > fastSMA[6]) and (close[7] > fastSMA[7]) and (open[7] > fastSMA[7]) and (close[8] > fastSMA[8]) and (open[8] > fastSMA[8]) and (close[9] > fastSMA[9]) and (open[9] > fastSMA[9]) and (close[10] > fastSMA[10]) and (open[10] > fastSMA[10])
candleDnTrend = (close[5] < fastSMA[5]) and (open[5] < fastSMA[5]) and (close[6] < fastSMA[6]) and (open[6] < fastSMA[6]) and (close[7] < fastSMA[7]) and (open[7] < fastSMA[7]) and (close[8] < fastSMA[8]) and (open[8] < fastSMA[8]) and (close[9] < fastSMA[9]) and (open[9] < fastSMA[9]) and (close[10] < fastSMA[10]) and (open[10] < fastSMA[10])

// Specify Piercing Conditions
bullPierce = ((low < fastSMA) and (open > fastSMA) and (close > fastSMA)) or ((low < slowSMA) and (open > slowSMA) and (close > slowSMA))
bearPierce = ((high > fastSMA) and (open < fastSMA) and (close < fastSMA)) or ((high > slowSMA) and (open < slowSMA) and (close < slowSMA))

// MA Slope Function
angle(_source) =>
    rad2degree=180/3.14159265359
    ang=rad2degree*atan((_source[0] - _source[1])/atr(atr_valu)) 

// Calculate MA Slope
fastSlope=angle(fastSMA)
slowSlope=angle(slowSMA)
slopingUp = fastSlope > slp_long
slopingDn = fastSlope < slp_shrt
    
// Specify Entry Conditions
longEntry = smaUpTrend and bullishPinBar and bullPierce
shortEntry = smaDnTrend and bearishPinBar and bearPierce
longEntryWithSlope = smaUpTrend and bullishPinBar and bullPierce and slopingUp
shortEntryWithSlope = smaDnTrend and bearishPinBar and bearPierce and slopingDn

// Specify Secondary Exit Conditions
longExit = crossunder(fastSMA, slowSMA)
shortExit = crossover(fastSMA, slowSMA)

// Long Entry Function
enterlong() =>
    risk = usr_risk * 0.01 * strategy.equity
    stopLoss = low[1] - atr[1] * atr_mult
    entryPrice = high[1]
    units = risk / (entryPrice - stopLoss)
    takeProfit = entryPrice + trd_rewd * (entryPrice - stopLoss)
    strategy.entry("long", strategy.long, units, stop=entryPrice)
    strategy.exit("exit long", "long", stop=stopLoss, limit=takeProfit)
    
// Short Entry Function
entershort() =>
    risk = usr_risk * 0.01 * strategy.equity
    stopLoss = high[1] + atr[1] * atr_mult
    entryPrice = low[1]
    units = risk / (stopLoss - entryPrice)
    takeProfit = entryPrice - trd_rewd * (stopLoss - entryPrice)
    strategy.entry("short", strategy.short, units, stop=entryPrice)
    strategy.exit("exit short", "short", stop=stopLoss, limit=takeProfit)
    
// Execute Long Entry w/o Slope
if (longEntry and use_slpe == false)
    enterlong()
    
// Execute Long Entry w/ Slope
if (longEntryWithSlope and use_slpe == true)
    enterlong()

// Exit Long Due to Re-Cross
if(longExit and strategy.position_size > 0 and emg_exit)    
    strategy.order("exit long, re-cross", strategy.short, abs(strategy.position_size))

// Cancel the Long Entry
strategy.cancel("long", barssince(longEntry) > ent_canc)

// Execute Short Entry w/o Slope
if (shortEntry and use_slpe == false)
    entershort() 
    
// Execute Short Entry w/ Slope
if (shortEntryWithSlope and use_slpe == true)
    entershort() 

// Exit Short Due to Re-Cross
if(shortExit and strategy.position_size < 0 and emg_exit)    
    strategy.order("exit short, re-cross", strategy.long, abs(strategy.position_size))

// Cancel the Short Entry
strategy.cancel("short", barssince(shortEntry) > ent_canc)

// Plot Moving Averages to Chart
plot(fastSMA, color=color.red)
plot(slowSMA, color=color.blue)

// Plot Pin Bars to Chart
plotshape(bullishPinBar, style=shape.arrowup, location=location.abovebar, color=#FF0000, text='')
plotshape(bearishPinBar, style=shape.arrowdown, location=location.belowbar, color=#0000FF, text='')

もっと

2019 FMZ - すべての権利は保護されています.

基本的Pinbar取引戦略

概要

戦略の論理

利点

リスク と 軽減

増進 の 機会

概要

リスクと軽減

増進の機会