거래량-가격 관계 기반 다중 지표 변동성 돌파 거래 시스템

/*backtest
start: 2024-03-28 00:00:00
end: 2024-12-31 00:00:00
period: 1h
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"ETH_USDT"}]
*/

//@version=5
strategy("VolSpike ATR RSI Strategy with ATR Bands", overlay=true, initial_capital=10000, default_qty_type=strategy.percent_of_equity, default_qty_value=10, calc_on_every_tick=false)

//────────────────────────────
// ① User Inputs
//────────────────────────────
// VolSpike reference candle count
barsBack = input.int(7, title="VolSpike - Reference Candle Count", minval=1)

// ATR Band related input values
atrPeriod     = input.int(title="ATR Period", defval=14, minval=1)
atrMultiplier = input.float(title="ATR Band Scale Factor", defval=2.5, step=0.1, minval=0.01)

// RSI related input values and thresholds
rsiPeriod = input.int(title="RSI Period", defval=14, minval=1)
rsiUpper  = input.int(title="RSI Upper Threshold", defval=80, minval=50, maxval=100)
rsiLower  = input.int(title="RSI Lower Threshold", defval=20, minval=0,  maxval=50)

// TP multiplier input: default 1 multiplier (TP = entry price + N times ATR band difference)
tpMultiplier = input.float(title="TP Multiplier", defval=1.0, step=0.1, minval=0.1, tooltip="Determines how many times the difference between the entry price and ATR band is used for TP.")

// Candle wick filter: Maximum allowed wick ratio (body to wick)
maxWickRatio = input.float(title="Max Allowed Wick Ratio", defval=2.0, minval=0.1, step=0.1, tooltip="If the wick length is greater than this ratio compared to the body, no entry will be made.")

//────────────────────────────
// ② VolSpike Calculation (Based on candle close)
//────────────────────────────
var float volSum = na
if bar_index > barsBack
    volSum := 0.0
    for i = 1 to barsBack
        volSum += volume[i]
else
    volSum := na
volSpike = not na(volSum) and (volume > volSum)

//────────────────────────────
// ③ RSI Calculation and Filter (Using user-set RSI thresholds)
//────────────────────────────
rsiVal    = ta.rsi(close, rsiPeriod)
rsiFilter = (rsiVal < rsiUpper) and (rsiVal > rsiLower)

//────────────────────────────
// ⑤ ATR Band Calculation
//────────────────────────────
getBandOffsetSource(srcIn, isUpperBand) =>
    ret = close
    switch srcIn
        "close" => ret := close
        "wicks" => ret := isUpperBand ? high : low
        => ret := close
    ret

// Offset reference is fixed to 'close'
atrSourceRef  = "close"
atrValue      = ta.atr(atrPeriod)
scaledATR     = atrValue * atrMultiplier
upperATRBand  = getBandOffsetSource(atrSourceRef, true)  + scaledATR
lowerATRBand  = getBandOffsetSource(atrSourceRef, false) - scaledATR

// Plot ATR bands on the chart
plot(upperATRBand, title="Upper ATR Band", color=color.rgb(0,255,0,50), linewidth=2)
plot(lowerATRBand, title="Lower ATR Band", color=color.rgb(255,0,0,50), linewidth=2)

//────────────────────────────
// ⑥ Rocket Signal (VolSpike) Display
//────────────────────────────
plotshape(volSpike, title="VolSpike Rocket", location=location.belowbar, style=shape.labelup, text="🚀", color=color.blue, size=size.tiny)

//────────────────────────────
// ⑦ Candle Wick Length Filter Calculation (Applied in reverse)
//────────────────────────────
// Body length (absolute value)
bodyLength = math.abs(close - open)
bodyLength := bodyLength == 0 ? 0.0001 : bodyLength  // Prevent doji
// Long position entry upper wick ratio: (high - close) / bodyLength
longWickRatio = (high - close) / bodyLength
// Short position entry lower wick ratio: (close - low) / bodyLength
shortWickRatio = (close - low) / bodyLength

longWickOK = longWickRatio <= maxWickRatio
shortWickOK = shortWickRatio <= maxWickRatio

//────────────────────────────
// ⑧ Position Entry and Exit Setup
//    - Long: Close of the entry candle > Open → SL = lowerATRBand, TP = entry price + tpMultiplier * (upperATRBand - entry price)
//    - Short: Close of the entry candle < Open → SL = upperATRBand, TP = entry price - tpMultiplier * (entry price - lowerATRBand)
//────────────────────────────
if volSpike and rsiFilter
    // Long position entry (bullish candle) && wick condition met (upper wick)
    if close > open and longWickOK
        longTP = close + tpMultiplier * (upperATRBand - close)
        strategy.entry("Long", strategy.long)
        strategy.exit("Exit Long", from_entry="Long", stop=lowerATRBand, limit=longTP)
    // Short position entry (bearish candle) && wick condition met (lower wick)
    else if close < open and shortWickOK
        shortTP = close - tpMultiplier * (close - lowerATRBand)
        strategy.entry("Short", strategy.short)
        strategy.exit("Exit Short", from_entry="Short", stop=upperATRBand, limit=shortTP)