O recurso está a ser carregado... Carregamento...

Supertrend MACD Estratégia Quantitativa

Autora:ChaoZhang, Data: 2023-12-26 11:13:24
Tags:

Resumo

Esta estratégia combina os potenciais sinais de inversão de tendência do indicador Supertrend e do indicador MACD, juntamente com os sinais de sobrecompra/supervenda do indicador RSI, para formar um sistema relativamente estável e eficiente para sinais de entrada e saída.

Estratégia lógica

A lógica central desta estratégia reside na utilização combinada do indicador Supertrend e do indicador MACD como critérios para os sinais de entrada.

Na parte da Supertrend, a estratégia adota a mudança de direção do indicador Supertrend como o sinal de reversão potencial. Quando a direção da Supertrend gira de cima para baixo, um sinal de compra é gerado. Quando a direção gira de baixo para cima, um sinal de venda é gerado.

Na parte do MACD, a estratégia usa o cruzamento da inclinação e da linha zero do indicador MACD em um período de tempo menor (diário) para identificar oportunidades de reversão potenciais. Quando o valor absoluto da inclinação do MACD é grande (acima do limiar) e a inclinação mantém a tendência ascendente, um sinal é gerado. Se a linha MACD cruza a linha zero, um sinal auxiliar é gerado.

Para os sinais de entrada, a estratégia exige que o sinal Supertrend e o sinal MACD estejam na mesma direção antes de enviar ordens de negociação.

Além disso, para os sinais de saída, a estratégia também adota os sinais de sobrecompra / sobrevenda do indicador RSI. Quando o RSI ultrapassa 80, um sinal de venda é gerado. Quando o RSI cai abaixo de 20, um sinal de compra é gerado. Estes ajudam a determinar o tempo de reversão.

Análise das vantagens

A maior vantagem desta estratégia é a diversidade dos sinais indicadores, que podem complementar-se e tornar o sinal global mais estável e confiável.

Os sinais de reversão de supertendência podem capturar tendências de curto prazo relativamente fortes; a inclinação do MACD pode julgar a força da tendência de médio e longo prazo para evitar ser enganada por falsas reversões; o RSI pode fornecer o melhor momento de entrada e saída no mercado de gama, indicando níveis de sobrecompra / sobrevenda. A empilha de sinais de vários indicadores pode filtrar alguns negócios barulhentos e alcançar uma maior taxa de ganho.

Além disso, o design do prazo também é razoável. Supertrend usa o prazo horário, enquanto MACD usa o prazo diário. Isso garante tanto a frequência de negociação quanto a estabilidade no julgamento da tendência.

Análise de riscos

O principal risco desta estratégia é a alta probabilidade de confundir sinais entre diferentes indicadores. Por exemplo, o Supertrend pode dar uma inversão falsa enquanto o sinal MACD não se sincroniza. Isso pode levar a perdas desnecessárias.

Além disso, o RSI para determinar o momento da saída também pode ser demasiado cedo ou demasiado tarde, impedindo o período máximo de detenção.

Por fim, um limiar de inclinação do MACD demasiado grande pode também perder oportunidades de reversão mais fracas.

Orientações de otimização

Esta estratégia pode ser melhorada a partir dos seguintes aspectos:

Introduzir o mecanismo de stop loss quando a perda exceder uma certa percentagem.
Adicionar um limiar dinâmico para o julgamento da inclinação do MACD.
Adicionar condição de pullback para julgamento de saída do RSI. Exigir um callback significativo após o RSI exceder 80 antes de considerar a posição de fechamento.
Teste o MACD com volume e veja se melhora a confiabilidade do sinal
Tentando ajuste automático de parâmetros para encontrar configurações ideais

Conclusão

A Supertrend MACD Quantitative Strategy combina sinais de vários indicadores para fornecer sinais de entrada e saída. Suas vantagens estão em sinais estáveis e taxa de vitória relativamente alta. Melhorias adicionais podem ser alcançadas através da otimização de parâmetros. Os riscos e as direções de otimização centram-se principalmente em torno de questões de sobreajuste de parâmetros.

/*backtest
start: 2022-12-19 00:00:00
end: 2023-12-25 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5

strategy("SuperTrend.MACD Strategy", overlay=false, default_qty_type=strategy.percent_of_equity, default_qty_value=100, initial_capital=100000, pyramiding=5, process_orders_on_close=true)

// ---------------- Utility Functions ----------------
getArrayValue(float[] arr, int ago) =>
    if ago >= 0
        array.get(arr, ago >= array.size(arr) ? na: array.size(arr) + -1 * ago -1)
    else
        na

filterNA(float[] a, s, int y) =>
    int x = 0
    if not na(s[0])
        array.push(a, s[0])
        if array.size(a) > y
            array.shift(a)
    a

pine_rsi(float[] x, int y) =>
    x0 = getArrayValue(x, 0)
    x1 = getArrayValue(x, 1)

    u = math.max(x0 - x1, 0) // upward ta.change
    d = math.max(x1 - x0, 0) // downward ta.change
    rs = ta.rma(u, y) / ta.rma(d, y)
    res = 100 - 100 / (1 + rs)
    res

turnAround(float[] arr) =>
    int isTurnAround = 0
    
    now = getArrayValue(arr, 0)
    p1 = getArrayValue(arr, 1)
    p2 = getArrayValue(arr, 2)

    if p1 > now and p1 > p2
        isTurnAround := -1
    else if p1 < now and p1 < p2
        isTurnAround := 1

intergerizeSignal(i) =>
    i>0 ? 1 : i<0 ? -1 : 0

linreg(float[] y, int n, int offset=0) => 
    float slope = na
    float intercept = na

    int endcursor = offset + n - 1

    if array.size(y) > endcursor
        float sumX = 0
        float sumX2 = 0
        float sumY = 0
        float sumY2 = 0
        float sumXY = 0

        for i=offset to endcursor
            yv = array.get(y, i)
            sumY += yv
            sumY2 += math.pow(yv, 2)
            sumX += i
            sumX2 += math.pow(i, 2)
            sumXY += i*yv

        // Pearson correlation coefficient
        r = (n * sumXY - sumX * sumY) / math.sqrt((n * sumY2 - math.pow(sumY, 2)) * (n * sumX2 - math.pow(sumX, 2)))

        // Coefficient of determination
        r2 = math.pow(r, 2)

        meanX = sumX / n
        meanY = sumY / n

        slope := (n * sumXY - sumX * sumY) / (n * sumX2 - math.pow(sumX, 2))
        intercept := meanY - slope * meanX

    [slope, intercept]

isStartOfDay() => dayofweek != dayofweek[1]

// ---------------- Variables ----------------

varip float st_signal = 0
varip float macd_signal = 0
varip float macd_close_signal = 0
varip float histo_signal = 0

var int openSignal = 0
var int closeSignal = 0

// -------------------------------- Supertrend Signal (Open) --------------------------------

// ST calculation
atrPeriod = input(10, "Supertrend ATR Length")
factor = input.float(2.0, "Supertrend Factor", step = 0.01)

[_, direction] = ta.supertrend(factor, atrPeriod)

st_direction_change = ta.change(direction)
if st_direction_change < 0
    st_signal := 4
if st_direction_change > 0
    st_signal := -4

// -------------------------------- MACD Signal (Open + Close) --------------------------------

// MACD Calculation
fastLength = input(12, title="MACD Fast Length")
slowLength = input(26, title="MACD Slow Length")
signalLength = input(9, title="MACD Signal Length")
macdSlowTimeframe = input.timeframe("D", "MACD Timeframe")
macdSlopeLookbackOpen = input(7, title="MACD Slope Lookback - Open")
macdSlopeLookbackClose = input(3, title="MACD Slope Lookback - Close")

dailyClose = request.security(syminfo.tickerid, macdSlowTimeframe, close, barmerge.gaps_on)
[macdLine, signalLine, _] = ta.macd(dailyClose, fastLength, slowLength, signalLength)

// MACD Slope calculation

varip macdHistory = array.new<float>(0)
varip macdSlowSlopeArr = array.new<float>(0)
varip float macdSlowSlope = na
varip float macdCloseSlope = na

if not na(macdLine[0])
    array.push(macdHistory, macdLine[0])
    if array.size(macdHistory) > macdSlopeLookbackOpen
        array.shift(macdHistory)
    [s1, _] = linreg(macdHistory, macdSlopeLookbackOpen)
    macdSlowSlope := s1

    array.push(macdSlowSlopeArr, macdSlowSlope)
    if array.size(macdSlowSlopeArr) > macdSlopeLookbackClose
        array.shift(macdSlowSlopeArr)
    [s2, _] = linreg(macdSlowSlopeArr, macdSlopeLookbackClose)
    macdCloseSlope := s2

// MACD Signal Calculation
// > open signal
threshold_macdSlowSlope = input.float(0.75, "MACD Slope Open Threshold", step = 0.05)

macdSlowSlopeOverThreshold = math.abs(macdSlowSlope) >= threshold_macdSlowSlope
macdSlowSlopeTrend = macdSlowSlope - getArrayValue(macdSlowSlopeArr, 1)
macdSlowSlopeTrendConfirm = macdSlowSlope*macdSlowSlopeTrend >0

if (macdSlowSlopeOverThreshold and macdSlowSlopeTrendConfirm)
    macd_signal := 3*macdSlowSlope/math.abs(macdSlowSlope)
else
    macd_signal := 0

// > close signal
int macdCloseSignal = 0
macdCloseSignal := intergerizeSignal(macdCloseSlope)

// Histogram signal Calculation
histSlow = macdLine - signalLine

if (ta.crossover(histSlow, 0))
	histo_signal := 2
if (ta.crossunder(histSlow, 0))
	histo_signal := -2

// -------------------------------- RSI Signal (Close) --------------------------------
int rsiCloseSignal = 0
varip float rsiSlow = na

rsiPeriod = input(14, title="RSI Period")

varip dailyCloseRSIFilter = array.new_float()

// rewrite pine_rsi to remove NaN value from series at calculation
dailyCloseRSIFilter := filterNA(dailyCloseRSIFilter, dailyClose, rsiPeriod)

if not na(dailyClose[0])
    rsiSlow := pine_rsi(dailyCloseRSIFilter, rsiPeriod)

if rsiSlow > 80
    rsiCloseSignal := -1
else if rsiSlow < 20
    rsiCloseSignal := 1
else
    rsiCloseSignal := 0

// -------------------------------- Overall Signal --------------------------------

// Close signal
closeSignals = array.from(macdCloseSignal, rsiCloseSignal)
closeSignal := array.includes(closeSignals, 1) ? 1 : array.includes(closeSignals, -1) ? -1 : 0
closeSignal := closeSignal * 5

// Open signal
if (macd_signal * st_signal > 0) and (macd_signal * macd_close_signal >= 0)
    openSignal := intergerizeSignal(st_signal)
    openSignal := openSignal * 6
else
    openSignal := 0

// -------------------------------- Order --------------------------------
// if strategy.position_size == 0
if openSignal * closeSignal >=0
    if openSignal > 0
        strategy.entry("Long Entry", strategy.long)
    else if openSignal < 0
        strategy.entry("Short Entry", strategy.short)

if strategy.position_size != 0
    if closeSignal < 0
        strategy.close("Long Entry")
    if closeSignal > 0
        strategy.close("Short Entry")


// -------------------------------- Plot --------------------------------

plot(closeSignal, title="Close Signal", color=color.red, linewidth = 1, style=plot.style_area)
plot(openSignal, title="Open Signal", color=color.green, linewidth = 1, style=plot.style_area)
plot(st_signal, title="ST Signal", color=color.black, linewidth = 1, style=plot.style_circles)
plot(macd_signal, title="MACD Signal", color=color.blue, linewidth = 1, style=plot.style_circles)
// plot(macdSlowSlope, title="macd slow slope", color=color.purple, linewidth = 1, style=plot.style_line)
// plot(macdCloseSlope, title="macd slow slope", color=color.lime, linewidth = 1, style=plot.style_line)

hline(0, "Zero Line", color=color.gray)

Mais.