O recurso está a ser carregado... Carregamento...

Estratégia de acompanhamento da oscilação da banda de isolamento

Autora:ChaoZhang, Data: 2024-02-04 10:28:24
Tags:

Resumo

A ideia principal desta estratégia é calcular as linhas de stop-loss longas e curtas com base no indicador ATR. Ele gera sinais de negociação quando o preço atravessa essas linhas de stop-loss. Ele tem capacidades de rastreamento de tendências e captura de oscilação.

Princípio da estratégia

A estratégia utiliza o ATR do período N multiplicado por um coeficiente para calcular as linhas de stop-loss longas e curtas.

Long Stop = Highest Price - ATR * Coefficient 
Short Stop = Lowest Price + ATR * Coefficient

Ele vai longo quando o preço sobe e quebra a linha longa de stop-loss, e vai curto quando o preço cai e quebra a linha curta de stop-loss.

Usando a faixa ATR como o nível de stop-loss, este método pode capturar completamente a tendência do preço, garantindo o risco de stop-loss.

Análise das vantagens

A maior vantagem desta estratégia é que pode ajustar automaticamente o nível de stop-loss para capturar as tendências de preços, controlando os riscos.

O stop-loss flutuante baseado no indicador ATR pode ajustar o intervalo de stop-loss de acordo com a volatilidade do mercado para controlar eficazmente a perda única.
Adotar um método inovador para gerar sinais pode filtrar algum ruído e evitar perseguir picos e baixos.
O ajustamento em tempo real das linhas de stop-loss para acompanhar as flutuações de preços impede que o stop-loss seja muito frouxo e bloqueie mais lucros.

Análise de riscos

A estratégia apresenta também alguns riscos, concentrados principalmente na definição do nível de stop-loss e na geração de sinais.

O ciclo e os coeficientes ATR incorretos podem conduzir a uma stop-loss excessivamente larga ou estreita.
O método de sinal de avanço pode perder oportunidades de tendência iniciais.
Pode haver algum atraso no rastreamento de stop-loss durante o término da tendência, incapaz de sair perfeitamente.

As contra-medidas consistem principalmente em ajustar os parâmetros para tornar o stop-loss mais razoável ou ajudar com outros indicadores a determinar a tendência e os sinais.

Orientações de otimização

A estratégia pode ser ainda melhorada nos seguintes aspectos:

Configurar um stop-loss de segunda camada para controlar os riscos.
Combinar outros indicadores para determinar a tendência e melhorar a qualidade do sinal.
Adicione estratégias de parada de lucro para aumentar o lucro quando a tendência continuar.
Otimizar o ciclo ATR e os parâmetros do coeficiente para aproximar o stop-loss das flutuações reais dos preços.

Resumo

Em geral, esta estratégia é muito prática. Ela pode controlar efetivamente os riscos ajustando automaticamente o nível de stop-loss, obtendo bons lucros através do rastreamento de tendências. Podemos otimizar e melhorar ainda mais a estratégia combinando outros métodos analíticos na base existente para torná-la mais estável e inteligente.

/*backtest
start: 2024-01-04 00:00:00
end: 2024-02-03 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © melihtuna
//@version=4
strategy("Chandelier Exit - Strategy",shorttitle="CE-STG" , overlay=true, default_qty_type=strategy.cash, default_qty_value=10000, initial_capital=10000, currency=currency.USD, commission_value=0.03, commission_type=strategy.commission.percent)

length = input(title="ATR Period", type=input.integer, defval=22)
mult = input(title="ATR Multiplier", type=input.float, step=0.1, defval=3.0)
showLabels = input(title="Show Buy/Sell Labels ?", type=input.bool, defval=false)
useClose = input(title="Use Close Price for Extremums ?", type=input.bool, defval=true)
highlightState = input(title="Highlight State ?", type=input.bool, defval=true)

atr = mult * atr(length)

longStop = (useClose ? highest(close, length) : highest(length)) - atr
longStopPrev = nz(longStop[1], longStop) 
longStop := close[1] > longStopPrev ? max(longStop, longStopPrev) : longStop

shortStop = (useClose ? lowest(close, length) : lowest(length)) + atr
shortStopPrev = nz(shortStop[1], shortStop)
shortStop := close[1] < shortStopPrev ? min(shortStop, shortStopPrev) : shortStop

var int dir = 1
dir := close > shortStopPrev ? 1 : close < longStopPrev ? -1 : dir

var color longColor = color.green
var color shortColor = color.red

longStopPlot = plot(dir == 1 ? longStop : na, title="Long Stop", style=plot.style_linebr, linewidth=2, color=longColor)
buySignal = dir == 1 and dir[1] == -1
plotshape(buySignal ? longStop : na, title="Long Stop Start", location=location.absolute, style=shape.circle, size=size.tiny, color=longColor, transp=0)
plotshape(buySignal and showLabels ? longStop : na, title="Buy Label", text="Buy", location=location.absolute, style=shape.labelup, size=size.tiny, color=longColor, textcolor=color.white, transp=0)

shortStopPlot = plot(dir == 1 ? na : shortStop, title="Short Stop", style=plot.style_linebr, linewidth=2, color=shortColor)
sellSignal = dir == -1 and dir[1] == 1
plotshape(sellSignal ? shortStop : na, title="Short Stop Start", location=location.absolute, style=shape.circle, size=size.tiny, color=shortColor, transp=0)
plotshape(sellSignal and showLabels ? shortStop : na, title="Sell Label", text="Sell", location=location.absolute, style=shape.labeldown, size=size.tiny, color=shortColor, textcolor=color.white, transp=0)

midPricePlot = plot(ohlc4, title="", style=plot.style_circles, linewidth=0, display=display.none, editable=false)

longFillColor = highlightState ? (dir == 1 ? longColor : na) : na
shortFillColor = highlightState ? (dir == -1 ? shortColor : na) : na
fill(midPricePlot, longStopPlot, title="Long State Filling", color=longFillColor)
fill(midPricePlot, shortStopPlot, title="Short State Filling", color=shortFillColor)


long_short = input(true, "Long-Short",type=input.bool, group="Strategy Settings")

start     = input(timestamp("2019-01-01"), "Date", type=input.time, group="Strategy Settings")
finish    = input(timestamp("2025-01-01"), "Date", type=input.time, group="Strategy Settings")   
window()  => true

slRatio=input(5, "Manuel Stop Loss Ratio", type=input.float, minval=0, group="Strategy Settings")
tpRatio=input(20, "Take Profit Ratio", type=input.float, minval=0, group="Strategy Settings")
tsStartRatio=input(10, "Trailing Stop Start Ratio", type=input.float, minval=0, group="Strategy Settings")
tsRatio=input(5, "Trailing Stop Ratio", type=input.float, minval=1, group="Strategy Settings")

lastBuyPrice = strategy.position_avg_price

diffHiPriceRatio = (high-lastBuyPrice)/lastBuyPrice*100
diffLoPriceRatio = (close-lastBuyPrice)/lastBuyPrice*100
posHiRatio=0.0
posHiRatio:= strategy.position_size > 0 ? diffHiPriceRatio > posHiRatio[1] ? diffHiPriceRatio : posHiRatio[1] : 0

s_diffHiPriceRatio = (low-lastBuyPrice)/lastBuyPrice*100
s_diffLoPriceRatio = (close-lastBuyPrice)/lastBuyPrice*100
s_posHiRatio=0.0
s_posHiRatio:= strategy.position_size < 0 ? s_diffLoPriceRatio < s_posHiRatio[1] ? s_diffLoPriceRatio : s_posHiRatio[1] : 0

strategy.entry("LONG", strategy.long, when = window() and buySignal)
strategy.close("LONG", when = window() and sellSignal)
strategy.close("LONG", when = diffLoPriceRatio<(slRatio*(-1)), comment="STOP-LONG")
strategy.close("LONG", when = diffHiPriceRatio>tpRatio, comment="TAKE-PROFIT-LONG")
strategy.close("LONG", when = ((posHiRatio[1]>tsStartRatio) and (posHiRatio[1]-diffHiPriceRatio)>tsRatio), comment="TRAILING-STOP-LONG")

if long_short
    strategy.entry("SHORT", strategy.short, when = window() and sellSignal)
    strategy.close("SHORT", when = window() and buySignal)
    strategy.close("SHORT", when = s_diffLoPriceRatio>(slRatio), comment="STOP-SHORT")
    strategy.close("SHORT", when = s_diffHiPriceRatio<(tpRatio*(-1)), comment="TAKE-PROFIT-SHORT")
    strategy.close("SHORT", when = ((s_posHiRatio[1]*(-1)>tsStartRatio) and ((s_posHiRatio[1]-s_diffLoPriceRatio))*(-1)>tsRatio), comment="TRAILING-STOP-SHORT")

Mais.