O recurso está a ser carregado... Carregamento...
  1. Quadrado
  2. SuperTrend Estratégia Quantitativa de Negociação para Bitcoin

SuperTrend Estratégia Quantitativa de Negociação para Bitcoin

Autora:ChaoZhang, Data: 2024-02-06 12:09:09
Tags:

img

Resumo

Esta é uma estratégia de negociação quantitativa automatizada para Bitcoin baseada no indicador SuperTrend. Ele usa o indicador SuperTrend para determinar as tendências do mercado e combina o princípio de stop loss ATR para controlar riscos, permitindo negociação longa e curta. A maior vantagem desta estratégia é uma boa relação risco-recompensa e uma estratégia de stop loss confiável, adequada para a detenção de médio a longo prazo.

Princípio da estratégia

Esta estratégia usa o indicador SuperTrend para determinar a direção das tendências do mercado.

Especificamente, esta estratégia primeiro calcula o período ATR como 14 bares e determina a distância de stop loss para cada negociação multiplicando-a por um multiplicador de stop loss ATR (como 1.5x).

Após entrar em um comércio, o stop loss é fixado acima ou abaixo do stop loss ATR. O primeiro nível de lucro é calculado com base em uma relação risco-recompensa, por padrão em 0,75, o que significa que a distância de lucro é 0,75x da distância de stop loss. Quando o preço atinge o primeiro nível de lucro, 50% da posição será fechada e o stop loss é movido para o preço de entrada (break even) para bloquear os lucros. O segundo nível de lucro continua a usar uma relação risco-recompensação de 0,75. Se o preço atingir o stop loss, a posição restante será fechada por stop loss.

Assim, esta estratégia assegura um risco de stop loss controlado e, ao mesmo tempo, fixa os lucros através de lucros parciais, adequados para estratégias de investimento de médio a longo prazo.

Análise das vantagens

A maior vantagem desta estratégia é a boa relação risco/retorno, permitindo a detenção a médio e longo prazo.

  1. Usando o SuperTrend para determinar tendências de mercado, filtrar ruído de mercado e capturar tendências principais.

  2. O rastreamento ATR dinâmico do stop loss, controlando de forma fiável a perda de uma única transação.

  3. A captação parcial de lucros bloqueia o lucro, resultando numa elevada relação risco/recompensa.

  4. Mudar o stop loss para o preço de entrada após atingir o TP1 bloqueia o lucro e aumenta a estabilidade da estratégia.

  5. Lógica extremamente simples, fácil de entender e implementar, com grande espaço de ajuste de parâmetros.

  6. Aplicável às principais bolsas que utilizam dados intradiários ou de alta frequência, com elevada flexibilidade.

Análise de riscos

Esta estratégia comporta também alguns riscos, principalmente nos seguintes domínios:

  1. O risco de falha não desencadear o stop loss, enfrentando grandes perdas.

  2. A SuperTrend não consegue determinar a tendência correta, resultando em sinais comerciais errados.

  3. Tomar o rácio de lucro muito alto, incapaz de montar a tendência. Deve ajustar com base em diferentes mercados.

  4. A frequência de negociação pode ser demasiado elevada ou demasiado baixa.

Orientações de otimização

Ainda há muito espaço para otimizar esta estratégia, principalmente nos seguintes domínios:

  1. Teste diferentes métodos de stop loss ATR, como ATR fixo, stop de momento, stop de Bollinger, etc.

  2. Otimizar os parâmetros da SuperTendência usando algoritmos de avanço ou genéticos para obter os melhores parâmetros.

  3. Adicionando uma segunda camada de stop loss como os canais de Donchian para tornar o stop mais confiável.

  4. Teste diferentes rácios de lucro para obter lucro ideal versus equilíbrio de risco.

  5. Explorar técnicas de aprendizagem de máquina para stop loss dinâmico, ajuste de posição, etc.

Conclusão

Esta é uma estratégia quantitativa baseada em SuperTrend para tendência, parada dinâmica ATR e lucro parcial. Tem uma relação risco-recompensa equilibrada, adequada para negociação de algo. Há amplo espaço para otimizar parâmetros, stop loss, lucro, etc. Vale a pena ajustar e aplicar a longo prazo.

/*backtest
start: 2024-01-06 00:00:00
end: 2024-02-05 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// Developed by © StrategiesForEveryone
//@version=5

strategy("SuperTrend Strategy for BTCUSD 4H", overlay=true, process_orders_on_close = true, initial_capital = 100, default_qty_type = strategy.cash, precision = 2, slippage = 50, commission_value = 0.03, backtest_fill_limits_assumption = 50)

// ------ Date filter (obtained from ZenAndTheArtOfTrading) ---------

initial_date = input(title="Initial date", defval=timestamp("10 Feb 2014 13:30 +0000"), group="Time filter", tooltip="Enter the start date and time of the strategy")
final_date   = input(title="Final date", defval=timestamp("01 Jan 2030 19:30 +0000"), group="Time filter", tooltip="Enter the end date and time of the strategy")
dateFilter(int st, int et) => time >= st and time <= et
colorDate = input.bool(defval=false, title="Date background", tooltip = "Add color to the period of time of the strategy tester")
bgcolor(colorDate and dateFilter(initial_date, final_date) ? color.new(color.blue, transp=90) : na)

// ------------ Super Trend ----------

atrPeriod = input(9, "ATR Length SuperTrend")
factor = input.float(2.5, "Factor SuperTrend", step = 0.05)
[supertrend, direction] = ta.supertrend(factor, atrPeriod)
show_supertrend = input.bool(defval = false, title="Show supertrend ?", group = "Appearance")
bodyMiddle = plot(show_supertrend ? ((open + close) / 2) : na, display=display.none)
upTrend = plot(show_supertrend and direction < 0 ? supertrend : na, "Up Trend", color = color.green, style=plot.style_linebr)
downTrend = plot(show_supertrend and direction > 0 ? supertrend : na, "Down Trend", color = color.red, style=plot.style_linebr)
fill(bodyMiddle, upTrend, color.new(color.green, 90), fillgaps=false)
fill(bodyMiddle, downTrend, color.new(color.red, 90), fillgaps=false)

// ---------- Atr stop loss (obtained from garethyeo)

source_atr = input(close, title='Source', group = "Atr stop loss", inline = "A")
length_atr = input.int(14, minval=1, title='Period', group = "Atr stop loss" , inline = "A")
multiplier = input.float(1.5, minval=0.1, step=0.1, title='Atr multiplier', group = "Atr stop loss", inline = "A", tooltip = "Defines the stop loss distance based on the Atr stop loss indicator")
shortStopLoss = source_atr + ta.atr(length_atr) * multiplier
longStopLoss = source_atr - ta.atr(length_atr) * multiplier
show_atr_stoploss = input.bool(defval=false, title="Show Atr stop loss ?", group = "Appearance")
plot(show_atr_stoploss ? longStopLoss : na, color=color.white, style = plot.style_circles)
plot(show_atr_stoploss ? shortStopLoss : na, color=color.white, style = plot.style_circles)

// ------------- Money management --------------

strategy_contracts = strategy.equity / close
distance_sl_atr_long = -1 * (longStopLoss - close) / close
distance_sl_atr_short = (shortStopLoss - close) / close
risk = input.float(2.5, '% Account risk per trade', step=1, group = "Risk management for trades", tooltip = "Percentage of total account to risk per trade")
long_amount = strategy_contracts * (risk / 100) / distance_sl_atr_long
short_amount = strategy_contracts * (risk / 100) / distance_sl_atr_short

// ---------- Risk management ---------------

risk_reward_breakeven_long= input.float(title="Risk/reward for breakeven long", defval=0.75, step=0.05, group = "Risk management for trades")
risk_reward_take_profit_long= input.float(title="Risk/reward for take profit long", defval=0.75, step=0.05, group = "Risk management for trades")
risk_reward_breakeven_short= input.float(title="Risk/reward for break even short", defval=0.75, step=0.05, group = "Risk management for trades")
risk_reward_take_profit_short= input.float(title="Risk/reward for take profit short", defval=0.75, step=0.05, group = "Risk management for trades")
tp_percent=input.float(title="% of trade for first take profit", defval=50, step=5, group = "Risk management for trades", tooltip = "Closing percentage of the current position when the first take profit is reached.")

// ------------ Trade conditions ---------------

bought = strategy.position_size > 0
sold = strategy.position_size < 0
long_supertrend=ta.crossover(close, supertrend)
short_supertrend=ta.crossunder(close, supertrend)
var float sl_long = na
var float sl_short = na 
var float be_long = na
var float be_short = na
var float tp_long = na
var float tp_short = na
if not bought
    sl_long:=na
if not sold
    sl_short:=na

// ---------- Strategy -----------

// Long position 

if not bought and long_supertrend
    sl_long:=longStopLoss           
    long_stoploss_distance = close - longStopLoss
    be_long := close + long_stoploss_distance * risk_reward_breakeven_long
    tp_long:=close+(long_stoploss_distance*risk_reward_take_profit_long)
    strategy.entry('L', strategy.long, long_amount, alert_message = "Long")
    strategy.exit("Tp", "L", stop=sl_long, limit=tp_long, qty_percent=tp_percent)
    strategy.exit('Exit', 'L', stop=sl_long)
if high > be_long
    sl_long := strategy.position_avg_price
    strategy.exit("Tp", "L", stop=sl_long, limit=tp_long, qty_percent=tp_percent)
    strategy.exit('Exit', 'L', stop=sl_long)
if bought and short_supertrend
    strategy.close("L", comment="CL")

// Short position

if not sold and short_supertrend
    sl_short:=shortStopLoss
    short_stoploss_distance=shortStopLoss - close  
    be_short:=((short_stoploss_distance*risk_reward_breakeven_short)-close)*-1
    tp_short:=((short_stoploss_distance*risk_reward_take_profit_short)-close)*-1
    strategy.entry("S", strategy.short, short_amount, alert_message = "Short")
    strategy.exit("Tp", "S", stop=sl_short, limit=tp_short, qty_percent=tp_percent)
    strategy.exit("Exit", "S", stop=sl_short)
if low < be_short
    sl_short:=strategy.position_avg_price
    strategy.exit("Tp", "S", stop=sl_short, limit=tp_short, qty_percent=tp_percent)
    strategy.exit("Exit", "S", stop=sl_short)    
if sold and long_supertrend
    strategy.close("S", comment="CS") 

// ---------- Draw position on chart -------------

if high>tp_long
    tp_long:=na
if low<tp_short
    tp_short:=na
if high>be_long
    be_long:=na
if low<be_short
    be_short:=na

show_position_on_chart = input.bool(defval=true, title="Draw position on chart ?", group = "Appearance", tooltip = "Activate to graphically display profit, stop loss and break even")
position_price = plot(show_position_on_chart? strategy.position_avg_price : na, style=plot.style_linebr, color = color.new(#ffffff, 10), linewidth = 1)

sl_long_price = plot(show_position_on_chart and bought ? sl_long : na, style = plot.style_linebr, color = color.new(color.red, 10), linewidth = 1)
sl_short_price = plot(show_position_on_chart and sold ? sl_short : na, style = plot.style_linebr, color = color.new(color.red, 10), linewidth = 1)

tp_long_price = plot(strategy.position_size>0 and show_position_on_chart? tp_long : na, style = plot.style_linebr, color = color.new(#11eb47, 10), linewidth = 1)
tp_short_price = plot(strategy.position_size<0 and show_position_on_chart? tp_short : na, style = plot.style_linebr, color = color.new(#11eb47, 10), linewidth = 1)

breakeven_long = plot(strategy.position_size>0 and high<be_long and show_position_on_chart ? be_long : na , style = plot.style_linebr, color = color.new(#00ff40, 60), linewidth = 1)
breakeven_short = plot(strategy.position_size<0 and low>be_short and show_position_on_chart ? be_short : na , style = plot.style_linebr, color = color.new(#00ff40, 60), linewidth = 1)

position_profit_long = plot(bought and show_position_on_chart and strategy.openprofit>0 ? close : na, style = plot.style_linebr, color = color.new(#4cd350, 10), linewidth = 1)
position_profit_short = plot(sold and show_position_on_chart and strategy.openprofit>0 ? close : na, style = plot.style_linebr, color = color.new(#4cd350, 10), linewidth = 1)

fill(plot1 = position_price, plot2 = position_profit_long, color = color.new(color.green,90))
fill(plot1 = position_price, plot2 = position_profit_short, color = color.new(color.green,90))

fill(plot1 = position_price, plot2 = sl_long_price, color = color.new(color.red,90))
fill(plot1 = position_price, plot2 = sl_short_price, color = color.new(color.red,90))

fill(plot1 = position_price, plot2 = tp_long_price, color = color.new(color.green,90))
fill(plot1 = position_price, plot2 = tp_short_price, color = color.new(color.green,90))
Mais.

2019 FMZ - Todos os direitos reservados