O recurso está a ser carregado... Carregamento...

Estratégia de ruptura do SR

Autora:ChaoZhang, Data: 2024-05-15 16:30:14
Tags:

Resumo

A estratégia de ruptura de SR é uma estratégia de ruptura de suporte e resistência desenvolvida com base no indicador de detector de ruptura do LonesomeTheBlue. A ideia principal desta estratégia é gerar sinais longos ou curtos julgando se o preço de fechamento quebra o nível de suporte ou resistência. As configurações padrão são baseadas no gráfico de velas de 8 horas, mas há configurações de parâmetros mais ideais no gráfico de velas de 4 horas. Esta estratégia usa as funções pivothigh e pivotlow para determinar os níveis de suporte e resistência e usa os preços mais altos e mais baixos para determinar rupturas. Ao mesmo tempo, esta estratégia também define stop loss e take profit.

Princípio da estratégia

Use as funções pivothigh e pivotlow para calcular os máximos e mínimos durante um determinado período de tempo e armazená-los em matrizes.
Determine se o preço de fechamento atual é superior ao nível de resistência.
Determine se o preço de fechamento atual está abaixo do nível de suporte.
Após a geração de um sinal de negociação, calcular os preços de stop loss e take profit com base nos rácios de stop loss e take profit definidos e definir as ordens de stop loss e take profit correspondentes.
Desenhar o intervalo de ruptura correspondente de acordo com a direção de ruptura.

Vantagens da estratégia

A ruptura de suporte e resistência é uma estratégia de negociação clássica com uma certa base prática.
Usando as funções pivothigh e pivotlow para calcular os níveis de suporte e resistência, as oportunidades de ruptura podem ser capturadas com relativa precisão.
A estrutura de código desta estratégia é clara, e armazenando altos e baixos em matrizes, é conveniente para backtesting e otimização.
São definidos o stop loss e o take profit, o que permite controlar os riscos relativamente bem.

Riscos estratégicos

A estratégia de ruptura de suporte e resistência tem um desempenho fraco em mercados agitados e é propensa a frequentes rupturas falsas.
Os rácios fixos de stop loss e de take profit podem não ser capazes de se adaptar a diferentes condições de mercado, resultando num desequilíbrio de risco e retorno.
Esta estratégia considera apenas os fatores de preço e não considera outros indicadores importantes, como o volume de negociação, que podem perder alguns sinais importantes.

Direcção de otimização da estratégia

Considerar a introdução de mais indicadores técnicos, tais como volume de negociação, MACD, etc., para melhorar a precisão e a confiabilidade dos sinais.
No caso de uma operação de paralisação e de captação de lucros, considerar a utilização de paralisações de trail ou de paralisações dinâmicas e de captação de lucros para melhor adaptar-se às diferentes condições de mercado.
Considerar a introdução de condições de filtragem, tais como filtragem de tendências, filtragem de volatilidade, etc., para reduzir falsas rupturas em mercados instáveis.
Considere a otimização dos níveis de suporte e resistência, como o uso de períodos adaptativos, a introdução de níveis de Fibonacci, etc.

Resumo

A estratégia de ruptura da SR é uma estratégia de negociação baseada na idéia clássica de ruptura de suporte e resistência. Usando as funções pivothigh e pivotlow para calcular os níveis de suporte e resistência, e julgando se o preço de fechamento quebra esses níveis para gerar sinais de negociação. A vantagem desta estratégia é que a idéia é clara e fácil de implementar e otimizar; ao mesmo tempo, também há alguns riscos, como mau desempenho em mercados instáveis, e os riscos que podem ser causados por índices fixos de stop loss e take profit. No futuro, podemos considerar a otimização e melhoria desta estratégia a partir de aspectos como indicadores técnicos, stop loss e take profit, condições de filtragem, otimização de suporte e resistência, etc., para melhorar sua estabilidade e lucratividade.

/*backtest
start: 2024-05-07 00:00:00
end: 2024-05-14 00:00:00
period: 10m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © LonesomeTheBlue © chanu_lev10k

//@version=5
strategy('SR Breakout Strategy', overlay=true, max_bars_back=500, max_lines_count=400)
prd = input.int(defval=5, title='Period', minval=2)
bo_len = input.int(defval=71, title='Max Breakout Length', minval=30, maxval=300)
cwidthu = input.float(defval=3., title='Threshold Rate %', minval=1., maxval=10) / 100
mintest = input.int(defval=2, title='Minimum Number of Tests', minval=1)
bocolorup = input.color(defval=color.blue, title='Breakout Colors', inline='bocol')
bocolordown = input.color(defval=color.red, title='', inline='bocol')
// lstyle = input.string(defval=line.style_solid, title='Line Style')
issl = input.bool(title='SL', inline='linesl1', group='Stop Loss / Take Profit:', defval=false)
slpercent = input.float(title=', %', inline='linesl1', group='Stop Loss / Take Profit:', defval=18.0, minval=0.0, step=0.1)
istp = input.bool(title='TP', inline='linetp1', group='Stop Loss / Take Profit:', defval=false)
tppercent = input.float(title=', %', inline='linetp1', group='Stop Loss / Take Profit:', defval=18.0, minval=0.0, step=0.1)

//width
lll = math.max(math.min(bar_index, 300), 1)
float h_ = ta.highest(lll)
float l_ = ta.lowest(lll)
float chwidth = (h_ - l_) * cwidthu

// check if PH/PL
ph = ta.pivothigh(prd, prd)
pl = ta.pivotlow(prd, prd)

//keep Pivot Points and their locations in the arrays
var phval = array.new_float(0)
var phloc = array.new_int(0)
var plval = array.new_float(0)
var plloc = array.new_int(0)

// keep PH/PL levels and locations
if bool(ph)
    array.unshift(phval, ph)
    array.unshift(phloc, bar_index - prd)
    if array.size(phval) > 1  // cleanup old ones
        for x = array.size(phloc) - 1 to 1 by 1
            if bar_index - array.get(phloc, x) > bo_len
                array.pop(phloc)
                array.pop(phval)

if bool(pl)
    array.unshift(plval, pl)
    array.unshift(plloc, bar_index - prd)
    if array.size(plval) > 1  // cleanup old ones
        for x = array.size(plloc) - 1 to 1 by 1
            if bar_index - array.get(plloc, x) > bo_len
                array.pop(plloc)
                array.pop(plval)

// check bullish cup
float bomax = na
int bostart = bar_index
num = 0
hgst = ta.highest(prd)[1]
if array.size(phval) >= mintest and close > open and close > hgst
    bomax := array.get(phval, 0)
    xx = 0
    for x = 0 to array.size(phval) - 1 by 1
        if array.get(phval, x) >= close
            break
        xx := x
        bomax := math.max(bomax, array.get(phval, x))
        bomax
    if xx >= mintest and open <= bomax
        for x = 0 to xx by 1
            if array.get(phval, x) <= bomax and array.get(phval, x) >= bomax - chwidth
                num += 1
                bostart := array.get(phloc, x)
                bostart
        if num < mintest or hgst >= bomax
            bomax := na
            bomax

// if not na(bomax) and num >= mintest
//     line.new(x1=bar_index, y1=bomax, x2=bostart, y2=bomax, color=bocolorup)
//     line.new(x1=bar_index, y1=bomax - chwidth, x2=bostart, y2=bomax - chwidth, color=bocolorup)
//     line.new(x1=bostart, y1=bomax - chwidth, x2=bostart, y2=bomax, color=bocolorup)
//     line.new(x1=bar_index, y1=bomax - chwidth, x2=bar_index, y2=bomax, color=bocolorup)

plotshape(not na(bomax) and num >= mintest, location=location.belowbar, style=shape.triangleup, color=bocolorup, size=size.small)
//alertcondition(not na(bomax) and num >= mintest, title='Breakout', message='Breakout')

// check bearish cup
float bomin = na
bostart := bar_index
num1 = 0
lwst = ta.lowest(prd)[1]
if array.size(plval) >= mintest and close < open and close < lwst
    bomin := array.get(plval, 0)
    xx = 0
    for x = 0 to array.size(plval) - 1 by 1
        if array.get(plval, x) <= close
            break
        xx := x
        bomin := math.min(bomin, array.get(plval, x))
        bomin
    if xx >= mintest and open >= bomin
        for x = 0 to xx by 1
            if array.get(plval, x) >= bomin and array.get(plval, x) <= bomin + chwidth
                num1 += 1
                bostart := array.get(plloc, x)
                bostart
        if num1 < mintest or lwst <= bomin
            bomin := na
            bomin

// if not na(bomin) and num1 >= mintest
//     line.new(x1=bar_index, y1=bomin, x2=bostart, y2=bomin, color=bocolordown)
//     line.new(x1=bar_index, y1=bomin + chwidth, x2=bostart, y2=bomin + chwidth, color=bocolordown)
//     line.new(x1=bostart, y1=bomin + chwidth, x2=bostart, y2=bomin, color=bocolordown)
//     line.new(x1=bar_index, y1=bomin + chwidth, x2=bar_index, y2=bomin, color=bocolordown)

plotshape(not na(bomin) and num1 >= mintest, location=location.abovebar, style=shape.triangledown, color=bocolordown, size=size.small)

//alertcondition(not na(bomin) and num1 >= mintest, title='Breakdown', message='Breakdown')
//alertcondition(not na(bomax) and num >= mintest or not na(bomin) and num1 >= mintest, title='Breakout or Breakdown', message='Breakout or Breakdown')

// Long Short conditions
longCondition = not na(bomax) and num >= mintest
if longCondition
    strategy.entry('Long', strategy.long)
shortCondition = not na(bomin) and num1 >= mintest
if shortCondition
    strategy.entry('Short', strategy.short)

// Entry price / Take Profit / Stop Loss
//entryprice = strategy.position_avg_price
entryprice = ta.valuewhen(condition=longCondition or shortCondition, source=close, occurrence=0)
pm = longCondition ? 1 : shortCondition ? -1 : 1 / math.sign(strategy.position_size)
takeprofit = entryprice * (1 + pm * tppercent * 0.01)
stoploss = entryprice * (1 - pm * slpercent * 0.01)
strategy.exit(id='Exit Long', from_entry='Long', stop=issl ? stoploss : na, limit=istp ? takeprofit : na, alert_message='Exit Long')
strategy.exit(id='Exit Short', from_entry='Short', stop=issl ? stoploss : na, limit=istp ? takeprofit : na, alert_message='Exit Short')

Mais.