В процессе загрузки ресурсов... загрузка...

Стратегия торговли RSI и скользящей средней за несколько временных рамок

Автор:Чао Чжан, Дата: 2024-01-22 11:00:20
Тэги:

Обзор

Эта стратегия сочетает в себе индикатор RSI, простую скользящую среднюю (SMA) и взвешенную скользящую среднюю (WMA) для определения торговых сигналов.

Логика стратегии

Стратегия сначала рассчитывает 144-периодическую WMA и 5-периодическую SMA как на 1-часовых, так и на 5-минутных временных рамках. Бычий рынок определяется только тогда, когда 5-минутная SMA выше WMA. Стратегия затем вычисляет осциллятор RSI и соответствующие линии K и D. Сигналы продажи генерируются, когда линия K пересекает линию D ниже из зоны перекупки. Сигналы покупки генерируются, когда линия K пересекает линию D из зоны перепродажи.

Анализ преимуществ

Это очень эффективная стратегия следования тренду. Используя два временных фрейма для определения тренда, он значительно уменьшает ложные сигналы. Кроме того, он сочетает в себе несколько фильтров, включая RSI, SMA и WMA, чтобы сделать сигналы более надежными.

Анализ рисков

Наибольший риск этой стратегии заключается в неправильном суждении о тренде. В переломные моменты краткосрочные и долгосрочные скользящие средние могут перевернуться вверх или вниз вместе, что приводит к неправильным сигналам. Кроме того, RSI может генерировать более шумные сигналы во время колебаний рынков. Однако эти риски могут быть уменьшены путем правильной корректировки периодов параметров SMA, WMA и RSI.

Руководство по оптимизации

Стратегия может быть улучшена в следующих аспектах:

Испытать различные длины SMA, WMA и RSI, чтобы найти оптимальную комбинацию
Включить другие индикаторы, такие как MACD, Bollinger Bands для проверки надежности сигнала
Оптимизируйте механизмы стоп-лосса и прибыли путем тестирования стоп-фиксированного коэффициента, стоп-фиксированного коэффициента и т.д.
Добавление модулей управления капиталом для контроля размеров сделок и общего риска
Внедрение моделей машинного обучения для поиска наилучших параметров производительности с помощью масштабного бэкстестинга

Резюме

Стратегия полностью использует сильные стороны скользящих средних и осцилляторов для установления относительно солидной системы следования тренду. Подтверждая сигналы в нескольких временных рамках и индикаторах, она может плавно улавливать средне- и долгосрочные тенденции. Настройки стоп-лосса и прибыли также позволяют ей в определенной степени выдерживать нормальные колебания рынка. Однако все еще есть возможности для улучшения, такие как тестирование большего количества комбинаций индикаторов, использование машинного обучения для оптимизации параметров. В целом, это очень перспективная торговая стратегия.

/*backtest
start: 2023-12-22 00:00:00
end: 2024-01-21 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © bufirolas

// Works well with a wide stop with 20 bars lookback
// for the SL level and a 2:1 reward ratio Take Profit .
// These parameters can be modified in the Inputs section of the strategy panel.

// "an entry signal it's a cross down or up on
// the stochastics. if you're in a downtrend
// on the hourly time frame you
// must also be in a downtrend on the five
// minute so the five period has to be below the 144
// as long as the five period is still trading below
// the 144 period on both the hourly and the five minutes
// we are looking for these short signals crosses down
// in the overbought region of the stochastic. Viceversa for longs"

//@version=4
strategy("Stoch + WMA + SMA strat", overlay=true)

//SL & TP Inputs
i_SL=input(true, title="Use Swing Lo/Hi Stop Loss & Take Profit")
i_SwingLookback=input(20, title="Swing Lo/Hi Lookback")
i_SLExpander=input(defval=10, step=1, title="SL Expander")
i_TPExpander=input(defval=30, step=1, title="TP Expander")
i_reverse=input(false, title="Reverse Trades")
i_TStop =input(false, title="Use Trailing Stop")

//Strategy Inputs
src4 = input(close, title="RSI Source")
stochOS=input(defval=20, step=5, title="Stochastics Oversold Level")
stochOB=input(defval=80, step=5, title="Stochastics Overbought Level")

//Stoch rsi Calculations
smoothK = input(3, minval=1)
smoothD = input(3, minval=1)
lengthRSI = input(14, minval=1)
lengthStoch = input(14, minval=1)
rsi1 = rsi(src4, lengthRSI)
k = sma(stoch(rsi1, rsi1, rsi1, lengthStoch), smoothK)
d = sma(k, smoothD)
h0 = hline(80, linestyle=hline.style_dotted)
h1 = hline(20, linestyle=hline.style_dotted)

//MA
wmalen=input(defval=144, title="WMA Length")
WMA = security(syminfo.tickerid, "60", wma(close, wmalen))
SMA = security(syminfo.tickerid, "60", sma(close, 5))
minWMA = wma(close, wmalen)
minSMA = sma(close, 5)

//Entry Logic
stobuy = crossover(k, d) and k < stochOS
stosell = crossunder(k, d) and k > stochOB
mabuy = minSMA > minWMA
daymabuy = SMA > WMA

//SL & TP Calculations
SwingLow=lowest(i_SwingLookback)
SwingHigh=highest(i_SwingLookback)
bought=strategy.position_size != strategy.position_size[1]
LSL=valuewhen(bought, SwingLow, 0)-((valuewhen(bought, atr(14), 0)/5)*i_SLExpander)
SSL=valuewhen(bought, SwingHigh, 0)+((valuewhen(bought, atr(14), 0)/5)*i_SLExpander)
lTP=(strategy.position_avg_price + (strategy.position_avg_price-(valuewhen(bought, SwingLow, 0)))+((valuewhen(bought, atr(14), 0)/5)*i_TPExpander))
sTP=(strategy.position_avg_price - (valuewhen(bought, SwingHigh, 0) - strategy.position_avg_price))-((valuewhen(bought, atr(14), 0)/5)*i_TPExpander)
islong=strategy.position_size > 0
isshort=strategy.position_size < 0

//TrailingStop
dif=(valuewhen(strategy.position_size>0 and strategy.position_size[1]<=0, high,0))
 -strategy.position_avg_price
trailOffset     = strategy.position_avg_price - LSL
var tstop = float(na)
if strategy.position_size > 0
    tstop := high- trailOffset - dif
    if tstop<tstop[1]
        tstop:=tstop[1]
else
    tstop := na
StrailOffset     = SSL - strategy.position_avg_price
var Ststop = float(na)
Sdif=strategy.position_avg_price-(valuewhen(strategy.position_size<0 
 and strategy.position_size[1]>=0, low,0))
if strategy.position_size < 0
    Ststop := low+ StrailOffset + Sdif
    if Ststop>Ststop[1]
        Ststop:=Ststop[1]
else
    Ststop := na
    
//Stop Selector
SL= islong ? LSL : isshort ? SSL : na
if i_TStop 
    SL:= islong ? tstop : isshort ? Ststop : na
TP= islong ? lTP : isshort ? sTP : na


//Entries
if stobuy and mabuy and daymabuy
    strategy.entry("long", long=not i_reverse?true:false)
if stosell and not mabuy and not daymabuy
    strategy.entry("short", long=not i_reverse?false:true)


//Exit
if i_SL
    strategy.exit("longexit", "long", stop=SL, limit=TP)
    strategy.exit("shortexit", "short", stop=SL, limit=TP)

//Plots
plot(i_SL ? SL : na, color=color.red, style=plot.style_cross)
plot(i_SL ? TP : na, color=color.green, style=plot.style_cross)
plot(minWMA)
plot(minSMA, color=color.green)

Больше