1. مربع
2. تجارتی حکمت عملی کے بعد قیمت کا فرق اور رجحان

تجارتی حکمت عملی کے بعد قیمت کا فرق اور رجحان

مصنف:چاؤ ژانگ، تاریخ: 2023-10-25 18:02:11
ٹیگز:

---

---

/*backtest
start: 2022-10-18 00:00:00
end: 2023-10-24 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy(title='BroTheJo Strategy', shorttitle='BTJ', overlay=true)

// Input settings
ccimomCross = input.string('CCI', 'Entry Signal Source', options=['CCI', 'Momentum'])
ccimomLength = input.int(10, minval=1, title='CCI/Momentum Length')
useDivergence = input.bool(false, title='Find Regular Bullish/Bearish Divergence')
rsiOverbought = input.int(65, minval=1, title='RSI Overbought Level')
rsiOversold = input.int(35, minval=1, title='RSI Oversold Level')
rsiLength = input.int(14, minval=1, title='RSI Length')
plotMeanReversion = input.bool(true, 'Plot Mean Reversion Bands on the chart')
emaPeriod = input(200, title='Lookback Period (EMA)')
bandMultiplier = input.float(1.6, title='Outer Bands Multiplier')

// CCI and Momentum calculation
momLength = ccimomCross == 'Momentum' ? ccimomLength : 10
mom = close - close[momLength]
cci = ta.cci(close, ccimomLength)
ccimomCrossUp = ccimomCross == 'Momentum' ? ta.cross(mom, 0) : ta.cross(cci, 0)
ccimomCrossDown = ccimomCross == 'Momentum' ? ta.cross(0, mom) : ta.cross(0, cci)

// RSI calculation
src = close
up = ta.rma(math.max(ta.change(src), 0), rsiLength)
down = ta.rma(-math.min(ta.change(src), 0), rsiLength)
rsi = down == 0 ? 100 : up == 0 ? 0 : 100 - 100 / (1 + up / down)
oversoldAgo = rsi[0] <= rsiOversold or rsi[1] <= rsiOversold or rsi[2] <= rsiOversold or rsi[3] <= rsiOversold
overboughtAgo = rsi[0] >= rsiOverbought or rsi[1] >= rsiOverbought or rsi[2] >= rsiOverbought or rsi[3] >= rsiOverbought

// Regular Divergence Conditions
bullishDivergenceCondition = rsi[0] > rsi[1] and rsi[1] < rsi[2]
bearishDivergenceCondition = rsi[0] < rsi[1] and rsi[1] > rsi[2]

// Mean Reversion Indicator
meanReversion = plotMeanReversion ? ta.ema(close, emaPeriod) : na
stdDev = plotMeanReversion ? ta.stdev(close, emaPeriod) : na
upperBand = plotMeanReversion ? meanReversion + stdDev * bandMultiplier : na
lowerBand = plotMeanReversion ? meanReversion - stdDev * bandMultiplier : na

// Entry Conditions
prevHigh = ta.highest(high, 1)
prevLow = ta.lowest(low, 1)
longEntryCondition = ccimomCrossUp and oversoldAgo and (not useDivergence or bullishDivergenceCondition) and (prevHigh >= meanReversion) and (prevLow >= meanReversion)
shortEntryCondition = ccimomCrossDown and overboughtAgo and (not useDivergence or bearishDivergenceCondition) and (prevHigh <= meanReversion) and (prevLow <= meanReversion)

// Plotting
oldLongEntryCondition = ccimomCrossUp and oversoldAgo and (not useDivergence or bullishDivergenceCondition)
oldShortEntryCondition = ccimomCrossDown and overboughtAgo and (not useDivergence or bearishDivergenceCondition)
plotshape(oldLongEntryCondition, title='BUY', style=shape.triangleup, location=location.belowbar, color=color.new(color.lime, 0), textcolor=color.new(color.white, 0), size=size.tiny)
plotshape(oldShortEntryCondition, title='SELL', style=shape.triangledown, location=location.abovebar, color=color.new(color.red, 0), textcolor=color.new(color.white, 0), size=size.tiny)

// Strategy logic
if (longEntryCondition)
    strategy.entry("Buy", strategy.long)
if (shortEntryCondition)
    strategy.entry("Sell", strategy.short)

// Close all open positions when outside of bands
closeAll = (high >= upperBand) or (low <= lowerBand)

if (closeAll)
    strategy.close_all("Take Profit/Cut Loss")


// Plotting
plot(upperBand, title='Upper Band', color=color.fuchsia, linewidth=1)
plot(meanReversion, title='Mean', color=color.gray, linewidth=1)
plot(lowerBand, title='Lower Band', color=color.blue, linewidth=1)

---

• ڈونچیئن چینل موافقت پذیر رجحان کی حکمت عملی
• ایم اے سی ڈی کنٹرولڈ رسک ٹریڈنگ حکمت عملی
• RSI رجحان کی پیروی کی حکمت عملی
• چلتی اوسط پر مبنی اوسط ریورس ٹریڈنگ کی حکمت عملی
• ای ایم اے کی اوسط ریورس ٹریڈنگ کی حکمت عملی
• کثیر اشارے کے ساتھ تجارت کی حکمت عملی
• کثیر عوامل کی حکمت عملی کا مجموعہ
• ووٹ ڈالنے کی حکمت عملی میں رکاوٹیں
• دو مرحلے کی سٹاپ نقصان کی حکمت عملی
• متعدد اشارے پر مبنی مقداری تجارتی حکمت عملی
• بریک آؤٹ اسکیلپر - تیزی سے رجحان کی تبدیلیوں کو پکڑنا
• ای ایم اے کراس اوور ٹریکنگ کی حکمت عملی
• ٹریلنگ سٹاپ نقصان کے ساتھ ایس ایس ایل چینل بریک آؤٹ کی حکمت عملی
• مومنٹم ٹریکنگ سی سی آئی حکمت عملی
• آہستہ آہستہ جمع ہونے والی بریکآؤٹ ٹریڈنگ کی حکمت عملی
• متحرک موم بتی کی سمت کی حکمت عملی
• RSI متغیر تجارتی حکمت عملی
• کثیر اشارے پر مبنی قلیل مدتی رجحان کی حکمت عملی
• ملٹی ٹائم فریم ایم اے سی ڈی ہیٹ میپ حکمت عملی
• ڈبل حرکت پذیر اوسط کراس اوور حکمت عملی