রিসোর্স লোড হচ্ছে... লোডিং...

BB-RSI-ADX এন্ট্রি পয়েন্ট

লেখক:চাওঝাং, তারিখ: ২০২২-০৫-১১ ১২ঃ৩৮ঃ২২
ট্যাগঃstdevএসএমএ

এই সূচকটি সম্ভাব্য বিপরীতমুখী অবস্থার জন্য অত্যধিক বিক্রয় এবং অত্যধিক ক্রয়ের প্রবেশের পয়েন্টগুলি খুঁজে বের করতে ব্যবহৃত সূচকগুলির সমন্বয়।

ENTER LONG পজিশনের জন্য সব শর্ত পূরণ হলে একটি সবুজ তীর প্রদর্শিত হবে। ENTER SHORT পজিশনের জন্য সমস্ত শর্ত পূরণ হলে একটি লাল সারি প্রদর্শিত হবে।

আপনি ইন্ডিকেটরের সেটিং থেকে এই শর্তের সমস্ত প্যারামিটার পরিবর্তন করতে পারেন।

সূচকটি কিভাবে কাজ করে সিগন্যালগুলো বোলিংজার ব্যান্ড, বিবি %বি, আরএসআই এবং এডিএক্স ইন্ডিকেটর ব্যবহার করে রিভার্স পয়েন্ট খুঁজে বের করার চেষ্টা করছে।

দীর্ঘ শর্ত লিখুন বর্তমান মোমবাতি নিম্ন বিবি নীচের ব্যান্ডের নিচে। বিবি %বি ০ এর বেশি। আরএসআই > ৩০ এডিএক্স > ২৫

সংক্ষিপ্ত শর্ত প্রবেশ করান বর্তমান মোমবাতি উচ্চতা বিবি উপরের ব্যান্ডের উপরে। বিবি %বি ১ এর চেয়ে কম। RSI < ৭০ এডিএক্স > ২৫

এগুলো ডিফল্ট সেটিংস যা আমার জন্য কাজ করে কিন্তু আপনি ইন্ডিকেটর সেটিংস থেকে এগুলো কাস্টমাইজ করতে পারেন। আমি মনে করি এই কৌশলটি ৩ মিনিটের সময়সীমার মধ্যে সবচেয়ে ভালো কাজ করে।

দ্রষ্টব্যঃ bb %B stDev - 1 এর জন্য গণনা করা হয়। এটি আপনাকে একটি পরিবর্তন দ্রুত ঘটতে দেখতে সাহায্য করবে।

ব্যাকটেস্ট

/*backtest
start: 2022-04-10 00:00:00
end: 2022-05-09 23:59:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
indicator(shorttitle="BB-RSI-ADX", title="BB-RSI-ADX Entry Points", overlay=true, timeframe="", timeframe_gaps=true)

// Bollinger Bands Setup
bbLength = input.int(9, minval=1, title="BB Length", group="BB Settings")
src = input(close, title="Source", group="BB Settings")
stDev = input.float(2.0, minval=0.001, maxval=50, title="StdDev", group="BB Settings")
basis = ta.sma(src, bbLength)
dev = stDev * ta.stdev(src, bbLength)
devMinOne = (stDev > 1 ? stDev - 1 : 1) * ta.stdev(src, bbLength)
upper = basis + dev
lower = basis - dev
upperMinOne = basis + devMinOne
lowerMinOne = basis - devMinOne

plot(basis, "Basis", color=#FF6D00)
p1 = plot(upper, "BB  Upper", color=#2962FF)
p2 = plot(lower, "BB Lower", color=#2962FF)
fill(p1, p2, title = "BB Background", color=color.rgb(33, 150, 243, 95))

// BB width %B
bbr = (src - lowerMinOne)/(upperMinOne - lowerMinOne)

// RSI
rsiLengthInput = input.int(14, minval=1, title="RSI Length", group="RSI Settings")
rsiSourceInput = input.source(close, "Source", group="RSI Settings")
rsiUp = ta.rma(math.max(ta.change(rsiSourceInput), 0), rsiLengthInput)
rsiDown = ta.rma(-math.min(ta.change(rsiSourceInput), 0), rsiLengthInput)
rsi = rsiDown == 0 ? 100 : rsiUp == 0 ? 0 : 100 - (100 / (1 + rsiUp / rsiDown))

// ADX
adxlen = input(14, title="ADX Smoothing", group="ADX Settings")
dilen = input(14, title="ADX DI Length", group="ADX Settings")
dirmov(len) =>
	up = ta.change(high)
	down = -ta.change(low)
	plusDM = na(up) ? na : (up > down and up > 0 ? up : 0)
	minusDM = na(down) ? na : (down > up and down > 0 ? down : 0)
	truerange = ta.rma(ta.tr, len)
	plus = fixnan(100 * ta.rma(plusDM, len) / truerange)
	minus = fixnan(100 * ta.rma(minusDM, len) / truerange)
	[plus, minus]
adx(dilen, adxlen) =>
	[plus, minus] = dirmov(dilen)
	sum = plus + minus
	adx = 100 * ta.rma(math.abs(plus - minus) / (sum == 0 ? 1 : sum), adxlen)
adxStr = adx(dilen, adxlen)

// Entry condition inputs
c_enter_long_bbr = input(0, title="Minimum BB %B", group="Enter LONG Conditions", tooltip="The Minimum required BB %B required to enter a LONG position. RECOMMENDED: 0")
c_enter_long_rsi_min = input(30, title="MIN RSI", group="Enter LONG Conditions", tooltip="The Minimum RSI value to enter a LONG position. RECOMMENDED: 30", inline="rsi_long")
c_enter_long_rsi_max = input(50, title="MAX RSI", group="Enter LONG Conditions", tooltip="The Maximum RSI value to enter a LONG position. RECOMMENDED: 50", inline="rsi_long")
c_adx_min_str = input(25, title="ADX Min Strength", group="ADX Settings")

c_enter_short_bbr = input(1, title="Highest BB %B", group="Enter SHORT Conditions", tooltip="The Highest required BB %B required to enter a SHORT position. RECOMMENDED: 1")
c_enter_short_rsi_min = input(50, title="MIN RSI", group="Enter SHORT Conditions", tooltip="The Minimum RSI value to enter a SHORT position. RECOMMENDED: 50", inline="rsi_short")
c_enter_short_rsi_max = input(70, title="MAX RSI", group="Enter SHORT Conditions", tooltip="The Maximum RSI value to enter a SHORT position. RECOMMENDED: 70", inline="rsi_short")

// Enter Long Conditions
enter_long = (low < lower) and (bbr > c_enter_long_bbr) and (rsi > c_enter_long_rsi_min) and (rsi < c_enter_long_rsi_max) and (adxStr > c_adx_min_str)  ? 1 : 0
// Enter Short Conditions
enter_short = (high > upper) and (bbr < c_enter_short_bbr) and (rsi > c_enter_short_rsi_min) and (rsi < c_enter_short_rsi_max) and (adxStr > c_adx_min_str)  ? -1 : 0


//plotarrow(enter_long, maxheight=10)    

//plotarrow(enter_short, maxheight=10)    




if enter_long
    strategy.entry("Enter Long", strategy.long)
else if enter_short
    strategy.entry("Enter Short", strategy.short)

সম্পর্কিত

আরো

2019 FMZ - সমস্ত অধিকার সংরক্ষিত