संसाधन लोड हो रहा है... लोड करना...

LazyBear संकेतक पर आधारित Squeeze Momentum ट्रेडिंग रणनीति

लेखक:चाओझांग, दिनांकः 2024-02-05 14:48:01
टैगः

अवलोकन

यह रणनीति LazyBear के Squeeze Momentum Indicator पर आधारित है, जिसमें अतिरिक्त गति फ़िल्टर, परिवर्तित डेटा स्रोत, और बेहतर जोखिम प्रबंधन प्रणाली और अनुकूलन योग्य बैकटेस्टिंग समय सीमा है, जिसका उद्देश्य अस्थिरता के निचोड़ के बाद मूल्य प्रकोप को पकड़ना है।

रणनीति तर्क

यह रणनीति मूल्य चैनलों की गणना करने के लिए बोलिंगर बैंड और केल्टनर चैनलों का उपयोग करती है। ब्रेकआउट बढ़ी हुई अस्थिरता का संकेत देते हैं। इसमें लेज़ीबीयर का स्क्वीज़ मोमेंटम इंडिकेटर शामिल है जो मूल्य गति की दिशा निर्धारित करने के लिए रैखिक प्रतिगमन का उपयोग करता है।

रणनीति गति फ़िल्टर जोड़ती है, केवल तभी व्यापार करती है जब पूर्ण गति एक सीमा से अधिक हो जाती है। गति फ़िल्टर पारित होने के साथ अस्थिरता निचोड़ (चैनल सख्त) पर, यह लंबी / छोटी के लिए प्रवृत्ति की दिशा का न्याय करता है। यह जोखिमों को नियंत्रित करने के लिए स्टॉप लॉस, ले लाभ और ट्रेलिंग स्टॉप भी सेट करता है।

लाभ विश्लेषण

रणनीति व्यापक निर्णय के लिए कई संकेतकों को एकीकृत करती है। यह जोखिम प्रबंधन तंत्र के साथ प्रति व्यापार हानि को सीमित करती है। यह समय पर निचोड़ के बाद मूल्य रुझानों का न्याय कर सकती है। अनुकूलन योग्य मापदंड इसे अनुकूलन योग्य बनाते हैं।

जोखिम विश्लेषण

मुख्य जोखिमों में शामिल हैंः गलत निर्णयों का कारण बनने वाले झूठे ब्रेकआउट; गलत पैरामीटर सेटिंग्स के साथ समय पर उलटने में विफलता; नुकसान को बढ़ाने वाले स्टॉप लॉस उल्लंघन। इन्हें मापदंडों को अनुकूलित करके, जोखिम प्रबंधन सेटिंग्स को समायोजित करके, उपयुक्त उत्पादों का चयन करके और ट्रेडिंग सत्रों को कम किया जा सकता है।

अनुकूलन दिशाएँ

वॉल्यूम जैसे अन्य संकेतक फिल्टरों को जोड़ने पर विचार करें; उच्च परिशुद्धता के लिए गति सीमा को ठीक करें; सख्त जोखिम नियंत्रण के लिए ड्रॉडाउन स्टॉप लॉस जोड़ें; अधिक उत्पादों में परीक्षण प्रभावशीलता। ये अनुकूलन रणनीति को अधिक मजबूत और सामान्य बना सकते हैं।

सारांश

यह रणनीति उच्च स्तर के एकीकरण और जोखिम नियंत्रण उपायों में सुधार के साथ मूल्य रुझानों और अस्थिरता का अपेक्षाकृत व्यापक रूप से आकलन करती है। इसे निचोड़ के बाद मूल्य प्रकोपों को पकड़ने में मजबूत अनुकूलन क्षमता के लिए अनुकूलन दिशाओं के माध्यम से और बढ़ाया जा सकता है।

/*backtest
start: 2024-01-05 00:00:00
end: 2024-02-04 00:00:00
period: 2h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// @version=4
// Strategy based on LazyBear Squeeze Momentum Indicator
// © Bitduke
// All scripts: https://www.tradingview.com/u/Bitduke/#published-scripts

strategy(shorttitle="SMS", title="Squeeze Momentum Strategy", overlay=false )

length = input(12, title="BB Length")
mult = input(2.0, title="BB MultFactor")
lengthKC = input(16, title="KC Length")
mult_kc = input(1.5, title="KC MultFactor")


//FILTERS
useMomAverage = input(false, title="Filter for Momenutum value", type=input.bool)
MomentumMin = input(20, title="Min for momentum")

// Calculate BB
src = ohlc4

ma_1 = sma(src, length)
ma_2 = sma(src, lengthKC)
range_ma = sma(high - low, lengthKC)

dev = mult * stdev(src, length)

upper_bb = ma_1 + dev
lower_bb = ma_1 - dev

upper_kc = ma_2 + range_ma * mult_kc
lower_kc = ma_2 - range_ma * mult_kc

sqz_on = lower_bb > lower_kc and upper_bb < upper_kc
sqz_off = lower_bb < lower_kc and upper_bb > upper_kc
no_sqz = sqz_on == false and sqz_off == false

val = linreg(src - avg(avg(highest(hl2, lengthKC), lowest(low, lengthKC)), sma(hl2, lengthKC)), lengthKC, 0)

bcolor = iff(val > 0, iff(val > nz(val[1]), color.lime, color.green), iff(val < nz(val[1]), color.red, color.maroon))
scolor = no_sqz ? color.blue : sqz_on ? color.black : color.aqua
plot(val, color=bcolor, style=plot.style_histogram, linewidth=4)
plot(0, color=scolor, style=plot.style_cross, linewidth=2)

//LOGIC
//momentum filter
filterMom = useMomAverage ? abs(val) > MomentumMin / 100000 ? true : false : true

//standard condition
longCondition = scolor[1] != color.aqua and scolor == color.aqua and bcolor == color.lime and filterMom
exitLongCondition = bcolor == color.green
shortCondition = scolor[1] != color.aqua and scolor == color.aqua and bcolor == color.red and filterMom
exitShortCondition = bcolor == color.maroon

// Risk Management Sysyem
stop_loss = input(defval = 600, title="Stop Loss", minval = 0)
take_profit = input(defval = 1000, title="Take Profit", minval = 0)
trailing_stop = input(defval = 20, title="Trailing Stop", minval = 0)
// If the zero value is set for stop loss, take profit or trailing stop, then the function is disabled
s_loss = stop_loss >= 1 ? stop_loss : na
tk_profit = take_profit >= 1 ? take_profit : na
tr_stop = trailing_stop >= 1 ? trailing_stop : na


//STRATEGY
strategy.entry("SQ_Long", strategy.long, when=longCondition)
strategy.exit("Exit Long", from_entry = "SQ_Long", profit = take_profit, trail_points = trailing_stop, loss = s_loss)
strategy.close("SQ_Long", exitLongCondition)

strategy.entry("SQ_Short", strategy.short, when=shortCondition)
strategy.exit("Exit Short", from_entry = "SQ_Short", profit = take_profit, trail_points = trailing_stop, loss = s_loss )
strategy.close("SQ_Short", when=exitShortCondition)

अधिक

2019 FMZ - सभी अधिकार सुरक्षित