資源の読み込みに... 荷物...

ガウスチャネル適応移動平均戦略

作者: リン・ハーンチャオチャン, 日付: 2024-03-28 18:08:18
タグ:

概要

ガウスチャネル適応移動平均戦略 (Gaussian Channel Adaptive Moving Average Strategy) は,ガウスチャネルフィルタリング技術と適応パラメータ設定を利用した定量的な取引戦略である.ジョン・エーラーズが提案したガウスチャネルフィルタ理論に基づいて,この戦略は,複数の指数的な移動平均計算を価格データに適用することによって,スムーズかつ適応的な取引信号を生成する.戦略の核は,ガウスチャネルフィルタリング価格からフィルタリングされた真の範囲を足し,減算することによって得られる上下帯で動的に調整された価格チャネルを構築することである.価格が上帯を超えるとロングポジションが入力され,下帯を超えるとショートポジションが入力される.さらに,戦略は,実行開始および終了時間のための柔軟な設定を可能にする時間段パラメーターを導入し,戦略の実用性を向上させる.

戦略の原則

ガウスチャネル適応移動平均戦略の原則は以下のとおりである.

価格のガウスフィルター値を計算する.ユーザーによって定義されたサンプリング期間とポール数に基づいて,ベータとアルファパラメータが計算され,その後価格データは複数のレベルのガウスフィルタリングを受け,平滑した価格シリーズを得ます.
真の範囲のガウスフィルター値を計算する.同じガウスフィルタリングプロセスは価格の真の範囲に適用され,平滑した範囲シリーズが得られる.
ガウスチャネルを構成する.ガウスフィルタ価格は中間帯として機能し,上帯はフィルタリングされた真域の積とユーザー定義倍数を加えて中間帯に形成され,下帯は中間帯からこの値を引いて動的チャネルを作成することによって形成される.
取引シグナルを生成する.価格がチャネルの上部帯を超えると,購入信号が生成され,価格が下部帯を超えると,販売信号が生成される.
期間パラメータを導入します. ユーザーは戦略実行の開始および終了時間を設定することができ,この戦略は,指定された期間内の取引信号に基づいてのみ動作します.

利点分析

ガウスのチャネル適応型移動平均戦略には以下の利点があります.

戦略は動的に調整されたパラメータを使用し,頻繁な手動調整を必要とせずに異なる市場条件と取引手段に適応することができます.
トレンドフォロー能力が良い.価格チャネルを構築することで,戦略は市場のトレンドを効果的に把握し,フォローすることができ,不安定な市場で誤った信号を避ける.
優れたスムーズ化.ガウスフィルタリング技術は,価格データを複数回スムーズ化するために使用され,ほとんどの市場ノイズを取り除き,取引信号をより信頼性のあるものにします.
高い柔軟性. 戦略のパフォーマンスを最適化するために,利用者は,サンプル期間,ポール数,範囲倍数など,戦略のパラメータをニーズに応じて調整できます.
強力な実用性. 期間パラメータの導入により,戦略は指定された時間範囲内で実行され,実用的な応用とバックテスト研究を容易にする.

リスク分析

多くの利点にもかかわらず,ガウスチャネル適応型移動平均戦略には依然としていくつかのリスクがあります.

パラメータ設定リスク:不適切なパラメータ設定は,戦略の非効率性または不良なパフォーマンスにつながり,実用的なアプリケーションで繰り返しテストと最適化が必要になります.
突発的な重大事件に直面すると,戦略は適切なタイミングで反応できず,損失を伴う可能性があります.
過剰調整リスク:パラメータの設定が過去データにあまりにも密接に適合している場合,戦略は将来的に機能が悪くなり,サンプル内およびサンプル外の両方のパフォーマンスを考慮する必要がある可能性があります.
アルビトラージリスク.この戦略は主にトレンド市場に適しており,不安定な市場で頻繁に取引する場合は,重大なアルビトラージリスクに直面する可能性があります.

オプティマイゼーションの方向性

ガウスチャネル適応移動平均戦略の最適化方向は以下の通りである.

ダイナミックパラメータ最適化.機械学習やその他の技術導入により,適応性を向上させるために戦略パラメータの自動最適化とダイナミック調整を達成する.
多因子融合.他の効果的な技術指標や要因をガウスチャネルと組み合わせて,より強力な取引信号を形成します.
ポジション管理の最適化. 引き下げとリスクを制御するための戦略に合理的なポジション管理とマネーマネジメントルールを組み込む.
複数の手段による調整戦略を複数の異なる取引手段に拡大し,資産配分と相関分析を通じてリスクを多様化する.

概要

ガウスチャンネルの適応型移動平均戦略は,ガウスフィルタリングと適応性パラメータに基づいた定量的な取引戦略で,動的に価格チャネルを構築することによってスムーズかつ信頼性の高い取引信号を生成する.この戦略は,強い適応性,良いトレンドフォロー能力,高いスムーズ性,大きな柔軟性,そして強力な実用性などの利点があります.しかし,パラメータ設定,突然の出来事,オーバーフィット,そして仲介などのリスクにも直面しています.将来,戦略は動的パラメータ最適化,マルチファクター融合,ポジション管理最適化,マルチインスタント調整を通じてさらに精製され強化することができます.

/*backtest
start: 2023-03-22 00:00:00
end: 2024-03-27 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
strategy(title="Gaussian Channel Strategy v1.0", overlay=true, calc_on_every_tick=false, initial_capital=10000, default_qty_type=strategy.percent_of_equity, default_qty_value=100, commission_type=strategy.commission.percent, commission_value=0.1)

// Date condition inputs
startDate = input(title="Date Start", type=input.time, defval=timestamp("1 Jan 2018 00:00 +0000"), group="Dates")
endDate = input(title="Date End", type=input.time, defval=timestamp("31 Dec 2060 23:59 +0000"), group="Dates")
timeCondition = true

// This study is an experiment utilizing the Ehlers Gaussian Filter technique combined with lag reduction techniques and true range to analyze trend activity.
// Gaussian filters, as Ehlers explains it, are simply exponential moving averages applied multiple times.
// First, beta and alpha are calculated based on the sampling period and number of poles specified. The maximum number of poles available in this script is 9.
// Next, the data being analyzed is given a truncation option for reduced lag, which can be enabled with "Reduced Lag Mode".
// Then the alpha and source values are used to calculate the filter and filtered true range of the dataset.
// Filtered true range with a specified multiplier is then added to and subtracted from the filter, generating a channel.
// Lastly, a one pole filter with a N pole alpha is averaged with the filter to generate a faster filter, which can be enabled with "Fast Response Mode". 

//Custom bar colors are included.

//Note: Both the sampling period and number of poles directly affect how much lag the indicator has, and how smooth the output is.
//      Larger inputs will result in smoother outputs with increased lag, and smaller inputs will have noisier outputs with reduced lag.
//      For the best results, I recommend not setting the sampling period any lower than the number of poles + 1. Going lower truncates the equation.

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Updates:
// Huge shoutout to @e2e4mfck for taking the time to improve the calculation method!
// -> migrated to v4
// -> pi is now calculated using trig identities rather than being explicitly defined.
// -> The filter calculations are now organized into functions rather than being individually defined.
// -> Revamped color scheme.

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Functions - courtesy of @e2e4mfck
//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
 
//Filter function 
f_filt9x (_a, _s, _i) => 
    int _m2 = 0, int _m3 = 0, int _m4 = 0, int _m5 = 0, int _m6 = 0, 
    int _m7 = 0, int _m8 = 0, int _m9 = 0, float _f = .0, _x = (1 - _a)
    // Weights. 
    // Initial weight _m1 is a pole number and equal to _i
    _m2 := _i == 9 ? 36  : _i == 8 ? 28 : _i == 7 ? 21 : _i == 6 ? 15 : _i == 5 ? 10 : _i == 4 ? 6 : _i == 3 ? 3 : _i == 2 ? 1 : 0
    _m3 := _i == 9 ? 84  : _i == 8 ? 56 : _i == 7 ? 35 : _i == 6 ? 20 : _i == 5 ? 10 : _i == 4 ? 4 : _i == 3 ? 1 : 0
    _m4 := _i == 9 ? 126 : _i == 8 ? 70 : _i == 7 ? 35 : _i == 6 ? 15 : _i == 5 ? 5  : _i == 4 ? 1 : 0
    _m5 := _i == 9 ? 126 : _i == 8 ? 56 : _i == 7 ? 21 : _i == 6 ? 6  : _i == 5 ? 1  : 0 
    _m6 := _i == 9 ? 84  : _i == 8 ? 28 : _i == 7 ? 7  : _i == 6 ? 1  : 0 
    _m7 := _i == 9 ? 36  : _i == 8 ? 8  : _i == 7 ? 1  : 0 
    _m8 := _i == 9 ? 9   : _i == 8 ? 1  : 0 
    _m9 := _i == 9 ? 1   : 0
    // filter
    _f :=   pow(_a, _i) * nz(_s) + 
      _i  *     _x      * nz(_f[1])      - (_i >= 2 ? 
      _m2 * pow(_x, 2)  * nz(_f[2]) : 0) + (_i >= 3 ? 
      _m3 * pow(_x, 3)  * nz(_f[3]) : 0) - (_i >= 4 ? 
      _m4 * pow(_x, 4)  * nz(_f[4]) : 0) + (_i >= 5 ? 
      _m5 * pow(_x, 5)  * nz(_f[5]) : 0) - (_i >= 6 ? 
      _m6 * pow(_x, 6)  * nz(_f[6]) : 0) + (_i >= 7 ? 
      _m7 * pow(_x, 7)  * nz(_f[7]) : 0) - (_i >= 8 ? 
      _m8 * pow(_x, 8)  * nz(_f[8]) : 0) + (_i == 9 ? 
      _m9 * pow(_x, 9)  * nz(_f[9]) : 0)

//9 var declaration fun
f_pole (_a, _s, _i) =>
    _f1 =            f_filt9x(_a, _s, 1),      _f2 = (_i >= 2 ? f_filt9x(_a, _s, 2) : 0), _f3 = (_i >= 3 ? f_filt9x(_a, _s, 3) : 0)
    _f4 = (_i >= 4 ? f_filt9x(_a, _s, 4) : 0), _f5 = (_i >= 5 ? f_filt9x(_a, _s, 5) : 0), _f6 = (_i >= 6 ? f_filt9x(_a, _s, 6) : 0)
    _f7 = (_i >= 2 ? f_filt9x(_a, _s, 7) : 0), _f8 = (_i >= 8 ? f_filt9x(_a, _s, 8) : 0), _f9 = (_i == 9 ? f_filt9x(_a, _s, 9) : 0)
    _fn = _i == 1 ? _f1 : _i == 2 ? _f2 : _i == 3 ? _f3 :
      _i == 4     ? _f4 : _i == 5 ? _f5 : _i == 6 ? _f6 :
      _i == 7     ? _f7 : _i == 8 ? _f8 : _i == 9 ? _f9 : na
    [_fn, _f1]

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Inputs
//-----------------------------------------------------------------------------------------------------------------------------------------------------------------

//Source
src = input(defval=hlc3, title="Source")

//Poles
int N = input(defval=4, title="Poles", minval=1, maxval=9)

//Period
int per = input(defval=144, title="Sampling Period", minval=2)

//True Range Multiplier
float mult = input(defval=1.414, title="Filtered True Range Multiplier", minval=0)

//Lag Reduction
bool modeLag  = input(defval=false, title="Reduced Lag Mode")
bool modeFast = input(defval=false, title="Fast Response Mode")

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Definitions
//-----------------------------------------------------------------------------------------------------------------------------------------------------------------

//Beta and Alpha Components
beta  = (1 - cos(4*asin(1)/per)) / (pow(1.414, 2/N) - 1)
alpha = - beta + sqrt(pow(beta, 2) + 2*beta)

//Lag
lag = (per - 1)/(2*N)

//Data
srcdata = modeLag ? src + (src - src[lag]) : src
trdata  = modeLag ? tr(true) + (tr(true) - tr(true)[lag]) : tr(true)

//Filtered Values
[filtn, filt1]     = f_pole(alpha, srcdata, N)
[filtntr, filt1tr] = f_pole(alpha, trdata,  N)

//Lag Reduction
filt   = modeFast ? (filtn + filt1)/2 : filtn
filttr = modeFast ? (filtntr + filt1tr)/2 : filtntr

//Bands
hband = filt + filttr*mult
lband = filt - filttr*mult

// Colors
color1   = #0aff68
color2   = #00752d
color3   = #ff0a5a
color4   = #990032
fcolor   = filt > filt[1] ? #0aff68 : filt < filt[1] ? #ff0a5a : #cccccc
barcolor = (src > src[1]) and (src > filt) and (src < hband) ? #0aff68 : (src > src[1]) and (src >= hband) ? #0aff1b : (src <= src[1]) and (src > filt) ? #00752d : 
           (src < src[1]) and (src < filt) and (src > lband) ? #ff0a5a : (src < src[1]) and (src <= lband) ? #ff0a11 : (src >= src[1]) and (src < filt) ? #990032 : #cccccc

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Outputs
//-----------------------------------------------------------------------------------------------------------------------------------------------------------------

//Filter Plot
filtplot = plot(filt, title="Filter", color=fcolor, linewidth=3)

//Band Plots
hbandplot = plot(hband, title="Filtered True Range High Band", color=fcolor)
lbandplot = plot(lband, title="Filtered True Range Low Band", color=fcolor)

//Channel Fill
fill(hbandplot, lbandplot, title="Channel Fill", color=fcolor, transp=80)

//Bar Color
barcolor(barcolor)


longCondition = crossover(close, hband) and timeCondition
closeAllCondition = crossunder(close, hband) and timeCondition

if longCondition
    strategy.entry("long", strategy.long)

if closeAllCondition
    strategy.close("long")

もっと

2019 FMZ - すべての権利は保護されています.