O recurso está a ser carregado... Carregamento...
  1. Quadrado
  2. Estratégia de média móvel adaptativa do canal de Gauss

Estratégia de média móvel adaptativa do canal de Gauss

Autora:ChaoZhang, Data: 2024-03-28 18:08:18
Tags:

img

Resumo

A estratégia de média móvel adaptativa do canal de Gauss é uma estratégia de negociação quantitativa que utiliza técnicas de filtragem de Gauss e configurações de parâmetros adaptativos. Baseada na teoria do filtro de Gauss proposta por John Ehlers, esta estratégia gera sinais de negociação suaves e adaptativos aplicando vários cálculos de média móvel exponencial aos dados de preços. O núcleo da estratégia é construir um canal de preços ajustado dinamicamente, com bandas superiores e inferiores obtidas adicionando e subtraindo a faixa verdadeira filtrada do preço filtrado de Gauss. Quando o preço ultrapassa a faixa superior, uma posição longa é inserida, e quando ultrapassa a faixa inferior, uma posição curta é inserida.

Princípios de estratégia

Os princípios da estratégia da média móvel adaptativa do canal de Gauss são os seguintes:

  1. Calcule o valor do filtro gaussiano do preço. Com base no período de amostragem definido pelo usuário e no número de pólos, os parâmetros Beta e Alpha são calculados e, em seguida, os dados de preço são submetidos a filtragem gaussiana de vários níveis para obter uma série de preços suavizada.
  2. Calcule o valor do filtro gaussiano da faixa real. O mesmo processo de filtragem gaussiano é aplicado à faixa real do preço, resultando em uma série de faixa suavizada.
  3. Construir o canal de Gauss. O preço filtrado por Gauss serve como a faixa média, a faixa superior é formada adicionando o produto da faixa verdadeira filtrada e um multiplicador definido pelo usuário à faixa média, e a faixa inferior é formada subtraindo esse valor da faixa média, criando um canal dinâmico.
  4. Gerar sinais de negociação: quando o preço ultrapassa a faixa superior do canal, um sinal de compra é gerado; quando o preço ultrapassa a faixa inferior, um sinal de venda é gerado.
  5. Introduzir parâmetros de período de tempo. Os usuários podem definir os horários de início e fim para a execução da estratégia, e a estratégia só operará com base em sinais de negociação dentro desse período de tempo especificado.

Análise das vantagens

A estratégia da média móvel adaptativa do canal de Gauss tem as seguintes vantagens:

  1. Forte adaptabilidade: a estratégia utiliza parâmetros ajustados dinamicamente que podem adaptar-se às diferentes condições de mercado e instrumentos de negociação sem exigir frequentes ajustes manuais.
  2. Boa capacidade de acompanhamento de tendências: através da construção de canais de preços, a estratégia pode efetivamente capturar e seguir as tendências do mercado, evitando sinais falsos em mercados instáveis.
  3. A técnica de filtragem de Gauss é usada para suavizar os dados de preço várias vezes, eliminando a maioria do ruído do mercado e tornando os sinais de negociação mais confiáveis.
  4. Alta flexibilidade: os utilizadores podem ajustar os parâmetros da estratégia de acordo com as suas necessidades, tais como o período de amostragem, número de postes, multiplicador de intervalo, etc., para otimizar o desempenho da estratégia.
  5. A introdução de parâmetros de período de tempo permite que a estratégia seja executada dentro de um intervalo de tempo especificado, facilitando a aplicação no mundo real e a pesquisa de backtesting.

Análise de riscos

Apesar das suas muitas vantagens, a estratégia da média móvel adaptativa do canal de Gauss ainda traz certos riscos:

  1. Risco de definição de parâmetros: configurações inadequadas de parâmetros podem levar à ineficácia da estratégia ou a um desempenho fraco, exigindo testes e otimização repetidos em aplicações práticas.
  2. Risco de acontecimentos súbitos: face a certos acontecimentos súbitos importantes, a estratégia pode não ser capaz de reagir correctamente e em tempo útil, resultando em perdas.
  3. Se as definições dos parâmetros estiverem demasiado ajustadas aos dados históricos, a estratégia poderá ter um desempenho fraco no futuro, exigindo a consideração do desempenho tanto dentro da amostra como fora da amostra.
  4. Risco de arbitragem: a estratégia é principalmente adequada para mercados em tendência, e a negociação frequente em mercados agitados pode enfrentar riscos significativos de arbitragem.

Orientações de otimização

As direções de otimização para a estratégia de média móvel adaptativa do canal de Gauss incluem:

  1. Optimização de parâmetros dinâmicos: através da introdução de aprendizagem de máquina e outras técnicas, alcançar a otimização automática e o ajuste dinâmico de parâmetros de estratégia para melhorar a adaptabilidade.
  2. Fusão de múltiplos fatores: combinar outros indicadores ou fatores técnicos eficazes com o canal de Gauss para formar sinais comerciais mais robustos.
  3. Optimização da gestão de posições: Incorporar regras razoáveis de gestão de posições e gestão de fundos na estratégia para controlar os saques e os riscos.
  4. Coordenação multi-instrumental: alargar a estratégia a vários instrumentos de negociação diferentes e diversificar os riscos através da alocação de ativos e da análise de correlação.

Resumo

A estratégia de média móvel adaptativa do canal de Gauss é uma estratégia quantitativa de negociação baseada na filtragem e nos parâmetros adaptativos de Gauss, que gera sinais de negociação suaves e confiáveis através da construção dinâmica de canais de preços. A estratégia tem vantagens como forte adaptabilidade, boa capacidade de seguir tendências, alta suavidade, grande flexibilidade e forte praticidade. No entanto, também enfrenta riscos como configuração de parâmetros, eventos repentinos, sobreajuste e arbitragem.

/*backtest
start: 2023-03-22 00:00:00
end: 2024-03-27 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
strategy(title="Gaussian Channel Strategy v1.0", overlay=true, calc_on_every_tick=false, initial_capital=10000, default_qty_type=strategy.percent_of_equity, default_qty_value=100, commission_type=strategy.commission.percent, commission_value=0.1)

// Date condition inputs
startDate = input(title="Date Start", type=input.time, defval=timestamp("1 Jan 2018 00:00 +0000"), group="Dates")
endDate = input(title="Date End", type=input.time, defval=timestamp("31 Dec 2060 23:59 +0000"), group="Dates")
timeCondition = true

// This study is an experiment utilizing the Ehlers Gaussian Filter technique combined with lag reduction techniques and true range to analyze trend activity.
// Gaussian filters, as Ehlers explains it, are simply exponential moving averages applied multiple times.
// First, beta and alpha are calculated based on the sampling period and number of poles specified. The maximum number of poles available in this script is 9.
// Next, the data being analyzed is given a truncation option for reduced lag, which can be enabled with "Reduced Lag Mode".
// Then the alpha and source values are used to calculate the filter and filtered true range of the dataset.
// Filtered true range with a specified multiplier is then added to and subtracted from the filter, generating a channel.
// Lastly, a one pole filter with a N pole alpha is averaged with the filter to generate a faster filter, which can be enabled with "Fast Response Mode". 

//Custom bar colors are included.

//Note: Both the sampling period and number of poles directly affect how much lag the indicator has, and how smooth the output is.
//      Larger inputs will result in smoother outputs with increased lag, and smaller inputs will have noisier outputs with reduced lag.
//      For the best results, I recommend not setting the sampling period any lower than the number of poles + 1. Going lower truncates the equation.

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Updates:
// Huge shoutout to @e2e4mfck for taking the time to improve the calculation method!
// -> migrated to v4
// -> pi is now calculated using trig identities rather than being explicitly defined.
// -> The filter calculations are now organized into functions rather than being individually defined.
// -> Revamped color scheme.

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Functions - courtesy of @e2e4mfck
//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
 
//Filter function 
f_filt9x (_a, _s, _i) => 
    int _m2 = 0, int _m3 = 0, int _m4 = 0, int _m5 = 0, int _m6 = 0, 
    int _m7 = 0, int _m8 = 0, int _m9 = 0, float _f = .0, _x = (1 - _a)
    // Weights. 
    // Initial weight _m1 is a pole number and equal to _i
    _m2 := _i == 9 ? 36  : _i == 8 ? 28 : _i == 7 ? 21 : _i == 6 ? 15 : _i == 5 ? 10 : _i == 4 ? 6 : _i == 3 ? 3 : _i == 2 ? 1 : 0
    _m3 := _i == 9 ? 84  : _i == 8 ? 56 : _i == 7 ? 35 : _i == 6 ? 20 : _i == 5 ? 10 : _i == 4 ? 4 : _i == 3 ? 1 : 0
    _m4 := _i == 9 ? 126 : _i == 8 ? 70 : _i == 7 ? 35 : _i == 6 ? 15 : _i == 5 ? 5  : _i == 4 ? 1 : 0
    _m5 := _i == 9 ? 126 : _i == 8 ? 56 : _i == 7 ? 21 : _i == 6 ? 6  : _i == 5 ? 1  : 0 
    _m6 := _i == 9 ? 84  : _i == 8 ? 28 : _i == 7 ? 7  : _i == 6 ? 1  : 0 
    _m7 := _i == 9 ? 36  : _i == 8 ? 8  : _i == 7 ? 1  : 0 
    _m8 := _i == 9 ? 9   : _i == 8 ? 1  : 0 
    _m9 := _i == 9 ? 1   : 0
    // filter
    _f :=   pow(_a, _i) * nz(_s) + 
      _i  *     _x      * nz(_f[1])      - (_i >= 2 ? 
      _m2 * pow(_x, 2)  * nz(_f[2]) : 0) + (_i >= 3 ? 
      _m3 * pow(_x, 3)  * nz(_f[3]) : 0) - (_i >= 4 ? 
      _m4 * pow(_x, 4)  * nz(_f[4]) : 0) + (_i >= 5 ? 
      _m5 * pow(_x, 5)  * nz(_f[5]) : 0) - (_i >= 6 ? 
      _m6 * pow(_x, 6)  * nz(_f[6]) : 0) + (_i >= 7 ? 
      _m7 * pow(_x, 7)  * nz(_f[7]) : 0) - (_i >= 8 ? 
      _m8 * pow(_x, 8)  * nz(_f[8]) : 0) + (_i == 9 ? 
      _m9 * pow(_x, 9)  * nz(_f[9]) : 0)

//9 var declaration fun
f_pole (_a, _s, _i) =>
    _f1 =            f_filt9x(_a, _s, 1),      _f2 = (_i >= 2 ? f_filt9x(_a, _s, 2) : 0), _f3 = (_i >= 3 ? f_filt9x(_a, _s, 3) : 0)
    _f4 = (_i >= 4 ? f_filt9x(_a, _s, 4) : 0), _f5 = (_i >= 5 ? f_filt9x(_a, _s, 5) : 0), _f6 = (_i >= 6 ? f_filt9x(_a, _s, 6) : 0)
    _f7 = (_i >= 2 ? f_filt9x(_a, _s, 7) : 0), _f8 = (_i >= 8 ? f_filt9x(_a, _s, 8) : 0), _f9 = (_i == 9 ? f_filt9x(_a, _s, 9) : 0)
    _fn = _i == 1 ? _f1 : _i == 2 ? _f2 : _i == 3 ? _f3 :
      _i == 4     ? _f4 : _i == 5 ? _f5 : _i == 6 ? _f6 :
      _i == 7     ? _f7 : _i == 8 ? _f8 : _i == 9 ? _f9 : na
    [_fn, _f1]

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Inputs
//-----------------------------------------------------------------------------------------------------------------------------------------------------------------

//Source
src = input(defval=hlc3, title="Source")

//Poles
int N = input(defval=4, title="Poles", minval=1, maxval=9)

//Period
int per = input(defval=144, title="Sampling Period", minval=2)

//True Range Multiplier
float mult = input(defval=1.414, title="Filtered True Range Multiplier", minval=0)

//Lag Reduction
bool modeLag  = input(defval=false, title="Reduced Lag Mode")
bool modeFast = input(defval=false, title="Fast Response Mode")

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Definitions
//-----------------------------------------------------------------------------------------------------------------------------------------------------------------

//Beta and Alpha Components
beta  = (1 - cos(4*asin(1)/per)) / (pow(1.414, 2/N) - 1)
alpha = - beta + sqrt(pow(beta, 2) + 2*beta)

//Lag
lag = (per - 1)/(2*N)

//Data
srcdata = modeLag ? src + (src - src[lag]) : src
trdata  = modeLag ? tr(true) + (tr(true) - tr(true)[lag]) : tr(true)

//Filtered Values
[filtn, filt1]     = f_pole(alpha, srcdata, N)
[filtntr, filt1tr] = f_pole(alpha, trdata,  N)

//Lag Reduction
filt   = modeFast ? (filtn + filt1)/2 : filtn
filttr = modeFast ? (filtntr + filt1tr)/2 : filtntr

//Bands
hband = filt + filttr*mult
lband = filt - filttr*mult

// Colors
color1   = #0aff68
color2   = #00752d
color3   = #ff0a5a
color4   = #990032
fcolor   = filt > filt[1] ? #0aff68 : filt < filt[1] ? #ff0a5a : #cccccc
barcolor = (src > src[1]) and (src > filt) and (src < hband) ? #0aff68 : (src > src[1]) and (src >= hband) ? #0aff1b : (src <= src[1]) and (src > filt) ? #00752d : 
           (src < src[1]) and (src < filt) and (src > lband) ? #ff0a5a : (src < src[1]) and (src <= lband) ? #ff0a11 : (src >= src[1]) and (src < filt) ? #990032 : #cccccc

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Outputs
//-----------------------------------------------------------------------------------------------------------------------------------------------------------------

//Filter Plot
filtplot = plot(filt, title="Filter", color=fcolor, linewidth=3)

//Band Plots
hbandplot = plot(hband, title="Filtered True Range High Band", color=fcolor)
lbandplot = plot(lband, title="Filtered True Range Low Band", color=fcolor)

//Channel Fill
fill(hbandplot, lbandplot, title="Channel Fill", color=fcolor, transp=80)

//Bar Color
barcolor(barcolor)


longCondition = crossover(close, hband) and timeCondition
closeAllCondition = crossunder(close, hband) and timeCondition

if longCondition
    strategy.entry("long", strategy.long)

if closeAllCondition
    strategy.close("long")
Mais.

2019 FMZ - Todos os direitos reservados