Die Ressourcen sind geladen. Beförderung...

Doppelte EMA-Strategie "Golden Cross Long Line"

Schriftsteller:ChaoZhang, Datum: 2024-02-23 12:17:40
Tags:

Übersicht

Die Dual EMA Golden Cross Long Line Strategie ist eine Trend-Tracking-Strategie, die nur Long-Positionen eröffnet. Die Strategie verwendet drei gleitende Durchschnitte, kurzfristige EMA, mittelfristige EMA und langfristige EMA. Die spezifische Einstiegsregel lautet: Long öffnen, wenn der Preis über der langfristigen EMA liegt und die kurzfristige EMA über die mittelfristige EMA kreuzt, um ein goldenes Kreuz zu bilden.

Strategie Logik

Berechnung der kurzfristigen EMA, der mittelfristigen EMA und der langfristigen EMA unter Verwendung von drei konfigurierbaren EMA-Perioden.
Wenn der Preis über der langfristigen EMA liegt, beweist dies, dass er sich derzeit in einem bullischen Trend befindet.
Wenn die kurzfristige EMA von unten über die mittelfristige EMA überschreitet, um ein goldenes Kreuz zu bilden, beweist dies weiter, dass sich der Aufwärtstrend verstärkt.
Wenn beide Bedingungen gleichzeitig erfüllt sind, öffnen Sie lang.

Analyse der Vorteile

Der größte Vorteil dieser Strategie besteht darin, dass sie Trends effektiv identifizieren kann, indem mehrjährige EMAs kombiniert beurteilt werden, um nicht durch kurzfristige Marktgeräusche irregeführt zu werden.

Risikoanalyse

Das Hauptrisiko dieser Strategie ist die Long-Position. Wenn der Markt umkehrt, ist er nicht in der Lage, Positionen rechtzeitig zu schließen, was zu einem Risiko von zunehmenden Verlusten führt. Darüber hinaus kann eine unsachgemäße Periodeneinstellung der EMAs auch zu häufigem Handel und erhöhten Transaktionskosten führen.

Optimierungsrichtung

Verstärkung des Positionsgrößenmanagements, um Positionen zu reduzieren, wenn die Abzüge einen bestimmten Prozentsatz erreichen.
Erhöhen Sie die Stop-Loss-Einstellungen, wenn Sie neue Höchststände brechen.
Optimierung der EMA-Periodenparameter zur Verringerung der Handelshäufigkeit.

Zusammenfassung

Diese Strategie ist insgesamt eine stabile, qualitativ hochwertige langfristige Holdingstrategie. Sie hat eine starke Fähigkeit, Trends mit angemessener Risikokontrolle zu identifizieren. Mit weiterer Optimierung wird erwartet, dass sie bessere stabile Renditen erzielt.

/*backtest
start: 2024-01-01 00:00:00
end: 2024-01-31 23:59:59
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy("Strategia EMA Long con Opzioni di Uscita Avanzate e Periodi EMA Personalizzabili", overlay=true)

// Parametri di input generali
useVolatilityFilter = input.bool(true, title="Usa Filtro di Volatilità")
atrPeriods = input.int(14, title="Periodi ATR", minval=1)
atrMultiplier = input.float(1.5, title="Moltiplicatore ATR", step=0.1)
useTrailingStop = input.bool(true, title="Usa Trailing Stop")
trailingStopPercent = input.float(15.0, title="Percentuale Trailing Stop", minval=0.1, step=0.1) / 100.0
useEMAExit = input.bool(true, title="Usa Uscita EMA Corta incrocia EMA Media al Ribasso")

// Parametri di input per periodi EMA personalizzabili
emaLongTermPeriod = input.int(200, title="Periodo EMA Lungo Termine", minval=1)
emaShortTermPeriod = input.int(5, title="Periodo EMA Breve Termine", minval=1)
emaMidTermPeriod = input.int(10, title="Periodo EMA Medio Termine", minval=1)

// Calcolo delle EMA con periodi personalizzabili
longTermEMA = ta.ema(close, emaLongTermPeriod)
shortTermEMA = ta.ema(close, emaShortTermPeriod)
midTermEMA = ta.ema(close, emaMidTermPeriod)

// Calcolo ATR e soglia di volatilità
atr = ta.atr(atrPeriods)
atrThreshold = ta.sma(atr, atrPeriods) * atrMultiplier

// Condizione di entrata
enterLongCondition = close > longTermEMA and shortTermEMA > midTermEMA
enterLong = useVolatilityFilter ? (enterLongCondition and atr > atrThreshold) : enterLongCondition

if (enterLong)
    strategy.entry("Enter Long", strategy.long)

// Tracking del prezzo di entrata e del massimo prezzo raggiunto per il trailing stop
var float entryPrice = na
var float maxPriceSinceEntry = na
if (strategy.position_size > 0)
    maxPriceSinceEntry := math.max(na(maxPriceSinceEntry) ? high : maxPriceSinceEntry, high)
    entryPrice := na(entryPrice) ? strategy.position_avg_price : entryPrice
else
    maxPriceSinceEntry := na
    entryPrice := na

// Calcolo del valore del trailing stop
trailStopPrice = maxPriceSinceEntry * (1 - trailingStopPercent)

// Implementazione delle condizioni di uscita
exitCrossUnder = close < longTermEMA
emaCross = ta.crossunder(shortTermEMA, midTermEMA)

if (useEMAExit and emaCross)
    strategy.close("Enter Long", comment="EMA Cross Exit")

if (useTrailingStop)
    strategy.exit("Trailing Stop", from_entry="Enter Long", stop=trailStopPrice)

// Visualizzazioni
plot(longTermEMA, color=color.yellow, title="EMA Lungo Termine")
plot(shortTermEMA, color=color.blue, title="EMA Breve Termine")
plot(midTermEMA, color=color.green, title="EMA Medio Termine")
plot(useVolatilityFilter ? atrThreshold : na, color=color.purple, title="ATR Threshold")
plot(strategy.position_size > 0 ? trailStopPrice : na, color=color.orange, title="Trailing Stop Value", style=plot.style_linebr)

Mehr