В процессе загрузки ресурсов... загрузка...

Динамическая стратегия поддержки и сопротивления CCI

Автор:Чао Чжан, Дата: 2024-01-22 16:37:46
Тэги:

Обзор

Эта стратегия использует поворотные точки индикатора CCI для расчета динамических уровней поддержки и сопротивления и объединяет суждение о тренде для поиска сигналов покупки и продажи.

Принцип стратегии

Индикатор CCI может показать, слишком слабый или слишком сильный рынок. Две крайности 80 и -80 могут быть использованы для определения того, вступил ли рынок в состояние перекупа или перепродажи. Эта стратегия использует эту характеристику CCI. Вычислив поворотные точки левых и правых 50 баров, получаются верхние и нижние поворотные точки. Затем линии поддержки и сопротивления строятся динамически путем добавления или вычитания буфера на основе поворотных точек.

Сигнал покупки генерируется, когда закрытие выше, чем открытие, и ниже, чем верхний уровень поддержки. Сигнал продажи генерируется, когда закрытие ниже, чем открытие, и выше, чем нижний уровень сопротивления. Чтобы отфильтровать торговые сигналы против основного направления тренда, стратегия также сочетает в себе индикаторы EMA и наклона, чтобы определить текущее направление основного тренда. Длинные входные сделки размещаются только тогда, когда тренд определен как бычий. Краткие входные сделки размещаются только тогда, когда тренд определен как медвежий.

Стоп-лосс и прибыль рассчитываются динамически на основе индикатора ATR, что делает контроль рисков этой стратегии более разумным.

Анализ преимуществ

В частности, поскольку CCI не имеет собственного рынка, он не может быть признан конкурентоспособным.
Сочетание с суждением о тренде позволяет избежать торговли против тренда и уменьшает потери.
Динамические параметры стоп-лосса и прибыли делают контроль рисков более разумным.
Параметры, которые можно настроить, такие как длина CCI, размер буфера и т. д., адаптируются к более широкой рыночной среде.

Анализ рисков

Индикатор CCI имеет тенденцию генерировать ложные сигналы, поэтому ему необходим фильтр от оценки тренда.
Возврат не всегда удается, с определенной вероятностью риска убытков.
Неправильное настройка параметров может привести к чрезмерной торговле или упущенным возможностям.

Методы, такие как оптимизация параметров, регулирование диапазона стоп-лосса и т. д. могут помочь снизить риски. Кроме того, эта стратегия может использоваться в качестве вспомогательного инструмента для других индикаторов, не полагаясь полностью на его сигналы.

Руководство по оптимизации

Оптимизировать размер буфера для адаптации к рынкам с различным уровнем волатильности.
Оптимизировать параметры периода ATR для более точного динамического стоп-лосса и получения прибыли.
Проверьте различные параметры CCI.
Проверьте влияние других типов индикаторов оценки тенденций.

Заключение

Эта стратегия объединяет в себе возможность длинного/короткого скрининга от CCI и подтверждение фильтра от суждения о тренде, обладая определенной практической ценностью. Динамическая стоп-лосс и прибыль также делает риск контролируемым при применении стратегии в фактической торговле. Благодаря оптимизации параметров и улучшениям можно ожидать лучших результатов.

/*backtest
start: 2023-12-22 00:00:00
end: 2024-01-21 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © AliSignals


//@version=5
strategy("CCI based support and resistance strategy", overlay=true  )


cci_length = input.int(50, "cci length")
right_pivot = input.int(50, "right pivot")
left_pivot = input.int(50, "left pivot")
buffer = input.float(10.0, "buffer")
trend_matter = input.bool(true, "trend matter?")
showmid = input.bool ( false , "show mid?")
trend_type = input.string("cross","trend type" ,options = ["cross","slope"])
slowma_l = input.int(100, "slow ma length")
fastma_l = input.int(50, "fast ma length")
slope_l = input.int(5,  "slope's length for trend detection")
ksl = input.float(1.1)
ktp = input.float(2.2)
restf = input.timeframe(title="Time Frame of Last Period for Calculating max" , defval="D")



// Calculating Upper and Lower CCI
cci = ta.cci(hlc3,cci_length)

uppercci = 0.0
lowercci = 0.0

uppercci := fixnan(ta.pivothigh(cci, left_pivot, right_pivot)) - buffer
lowercci := fixnan(ta.pivotlow (cci, left_pivot, right_pivot)) + buffer
midccci  = math.avg(uppercci,lowercci)


// Support and Resistance based on CCI
res = uppercci*(0.015*ta.dev(hlc3,cci_length))+ ta.sma(hlc3,cci_length)
sup = lowercci*(0.015*ta.dev(hlc3,cci_length))+ ta.sma(hlc3,cci_length)
mid =  midccci*(0.015*ta.dev(hlc3,cci_length))+ ta.sma(hlc3,cci_length)



// Calculating trend
t_cross  = 0
t_cross := ta.ema(close,fastma_l) > ta.ema(close,slowma_l) ? 1 : ta.ema(close,fastma_l) < ta.ema(close,slowma_l) ? -1 : t_cross[1] 

t_slope  = 0
t_slope := ta.ema(close,slowma_l) > ta.ema(close,slowma_l)[slope_l] ? 1 : ta.ema(close,slowma_l) < ta.ema(close,slowma_l)[slope_l]  ? -1 : t_slope[1] 

t  = 0
t := trend_type == "cross" ? t_cross : trend_type == "slope" ? t_slope : na

colort =  trend_matter == false ? color.rgb(201, 251, 0) : t == 1 ? color.rgb(14, 243, 132) :  t == -1 ? color.rgb(255, 34, 34) : na
bull_t = trend_matter == false or t ==  1
bear_t = trend_matter == false or t == -1

plot(res, color = colort)
plot(sup, color = colort)
plot(showmid == true ? mid : na)


// Long and Short enter condition
buy  = bull_t == 1 and ta.lowest (2) < sup and close > open and close > sup
sell = bear_t == 1 and ta.highest(2) > res and close < open and close < res

plotshape( buy , color=color.rgb(6, 255, 23) , location = location.belowbar, style = shape.triangleup  , size = size.normal)
plotshape( sell, color=color.rgb(234, 4, 4) ,  location = location.abovebar, style = shape.triangledown, size = size.normal)





atr = ta.atr(100)



CLOSE=request.security(syminfo.tickerid, restf, close)
max = 0.0
max := CLOSE == CLOSE[1] ? math.max(max[1], atr) : atr
act_atr = 0.0
act_atr := CLOSE == CLOSE[1] ? act_atr[1] : max[1]

atr1 =  math.max(act_atr, atr) 

dis_sl = atr1 * ksl
dis_tp = atr1 * ktp


var float longsl  = open[1] - dis_sl
var float shortsl = open[1] + dis_sl
var float longtp =   open[1] + dis_tp
var float shorttp =  open[1] - dis_tp


longCondition = buy
if (longCondition)
    strategy.entry("My Long Entry Id", strategy.long)

shortCondition = sell
if (shortCondition)
    strategy.entry("My Short Entry Id", strategy.short)


longsl  := strategy.position_size > 0  ? longsl[1]  : close - dis_sl
shortsl := strategy.position_size < 0 ? shortsl[1] : close + dis_sl
longtp  := strategy.position_size > 0  ? longtp[1]  : close + dis_tp
shorttp := strategy.position_size < 0 ? shorttp[1] : close - dis_tp




if strategy.position_size > 0 
    strategy.exit(id="My Long close Id", from_entry ="My Long Entry Id" , stop=longsl, limit=longtp)
if strategy.position_size < 0 
    strategy.exit(id="My Short close Id", from_entry ="My Short Entry Id" , stop=shortsl, limit=shorttp)

Больше