1. 策略广场
2. 多指标趋势跟踪与成交量确认策略

多指标趋势跟踪与成交量确认策略

Author: ChaoZhang, Date: 2024-07-31 11:43:53
Tags: ADXTTIVPCIVWMASMAMACD

---

---

/*backtest
start: 2023-07-25 00:00:00
end: 2024-07-30 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © PineCodersTASC

//  TASC Issue: August 2024 - Vol. 42
//     Article: Volume Confirmation For A Trend System.
//              The Trend Thrust Indicator And
//              Volume Price Confirmation Indicator.
//  Article By: Buff Pelz Dormeier
//    Language: TradingView's Pine Script™ v5
// Provided By: PineCoders, for tradingview.com


//@version=5
string title = "TASC 2024.08 Volume Confirmation For A Trend System"
string stitle = "VCTS"
strategy(title, stitle, false)


// Input
lenADX  = input.int(14, "ADX Length", 1)
smt     = input.int(14, "ADX Smoothing", 1, 50)
fastTTI = input.int(13, "TTI Fast Average", 1)
slowTTI = input.int(26, "TTI Slow Average", 1)
smtTTI  = input.int(9,  "TTI Signal Length", 1)
shortVP = input.int(5,  "VPCI Short-Term Average", 1)
longVP  = input.int(25, "VPCI Long-Term Average", 1)


// Functions
// ADX
adx(lenADX, smt) =>
    upDM   =  ta.change(high)
    dwDM   = -ta.change(low)
    pDM    = na(upDM) ? na : upDM > dwDM and upDM > 0 ? upDM : 0
    mDM    = na(dwDM) ? na : dwDM > upDM and dwDM > 0 ? dwDM : 0
    ATR    = ta.atr(lenADX)
    pDI    = fixnan(100 * ta.rma(pDM, lenADX) / ATR)
    mDI    = fixnan(100 * ta.rma(mDM, lenADX) / ATR)
    ADX    = 100*ta.rma(math.abs((pDI - mDI)  / (pDI + mDI)), smt)
    ADX

// TTI
// See also: https://www.tradingview.com/script/B6a7HzVn/
tti(price, fast, slow) =>
    fastMA = ta.vwma(price, fast)  
    slowMA = ta.vwma(price, slow)  
    VWMACD = fastMA - slowMA 
    vMult  = math.pow((fastMA / slowMA), 2) 
    VEFA   = fastMA * vMult 
    VESA   = slowMA / vMult
    TTI    = VEFA - VESA
    signal = ta.sma(TTI, smtTTI)
    [TTI, signal]

// VPCI
// See also: https://www.tradingview.com/script/lmTqKOsa-Indicator-Volume-Price-Confirmation-Indicator-VPCI/
vpci(long, short) =>
    VPC    = ta.vwma(close, long)  - ta.sma(close, long)
    VPR    = ta.vwma(close, short) / ta.sma(close, short)
    VM     = ta.sma(volume, short) / ta.sma(volume, long)
    VPCI   = VPC * VPR * VM
    VPCI


// Calculations
float ADX     = adx(lenADX, smt)
[TTI, signal] = tti(close, fastTTI, slowTTI) 
float VPCI    = vpci(longVP, shortVP)


// Plot
col1  = #4daf4a50
col2  = #e41a1c20
col0  = #ffffff00
adxL1 = plot(ADX,    "ADX", #984ea3)
adxL0 = plot(30,     "ADX Threshold", #984ea350)
ttiL1 = plot(TTI,    "TTI", #ff7f00)
ttiL0 = plot(signal, "TTI Signal", #ff7f0050)
vpcL1 = plot(VPCI*10,"VPCI", #377eb8)
vpcL0 = plot(0,      "VPCI Zero", #377eb850)
fill(adxL1, adxL0, ADX > 30 ? col1 : col0)
fill(ttiL1, ttiL0, TTI > signal ? col1 : col0)
fill(vpcL1, vpcL0, VPCI > 0 ? col1 : col2)


// Strategy entry/exit rules 
if ADX > 30
    if TTI > signal
        if VPCI > 0
            strategy.entry("entry", strategy.long)
if VPCI < 0
    strategy.close_all("exit")

---

• 多指标交叉动态动量策略
• 动态头寸规模短线外汇交易策略
• 改进型双重 EMA 回撤突破交易策略
• 多重指标趋势跟踪与止盈优化策略
• 多指标动态止损动量趋势交易策略
• 多指标协同趋势反转量化交易策略
• Momentum-based ZigZag
• VWMA-ADX 基于动量与趋势的比特币多头策略
• 基于RSI、MACD和成交量的多指标组合自适应交易策略
• 多指标协同布林带-斐波那契-MACD-RSI智能交易策略

---

• 早晨蜡烛突破与反转策略
• 基于斐波那契回撤的自适应趋势跟踪策略
• 高级马尔可夫模型技术指标融合交易策略
• 多层波动带交易策略
• 多周期均线交叉与波动率过滤动态策略
• 多重指标综合动量交易策略
• 三重指数移动平均线与支撑阻力动态交易策略
• 双重RSI策略:结合背离与交叉的高级趋势捕捉系统
• 基于洛伦兹分类法的多时间框架交易策略
• 双均线趋势捕捉策略结合动态止损和过滤器
• 双均线交叉带止盈止损的自适应量化交易策略
• 基于艾略特波浪与汤姆·德马克顺势交易策略
• 基于量化动量和收敛发散的多时间框架统一策略
• RSI超卖定期投资策略与冷却期优化
• HMA优化多周期量化交易策略与动态止损结合
• 布林带交叉与滑点价格影响组合策略
• 趋势结构突破与订单块公平价值缺口策略
• SMA交叉与成交量过滤的自适应动态止盈止损策略
• 双重MACD趋势确认交易系统
• 高低突破策略结合Alpha趋势和移动平均线过滤