1. বর্গক্ষেত্র
2. রেলিং স্টপ লস সহ RSI ইন্ডিকেটর ভিত্তিক স্কেলপিং কৌশল

রেলিং স্টপ লস সহ RSI ইন্ডিকেটর ভিত্তিক স্কেলপিং কৌশল

লেখক:চাওঝাং, তারিখ: ২০২৩-১২-১২ 15:46:49
ট্যাগঃ

---

---

/*backtest
start: 2023-11-11 00:00:00
end: 2023-12-11 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// Scalping strategy
// © Lukescream and Ninorigo
// (original version by Lukescream - lastest versions by Ninorigo) - v1.3
//

//@version=4
strategy(title="Scalping using RSI 2 indicator", shorttitle="RSI 2 Strategy", overlay=true, pyramiding=0, process_orders_on_close=false)

var bool ConditionEntryL = false
var bool ConditionEntryS = false


//***********
// Costants
//***********
def_start_date = timestamp("01 Jan 2021 07:30 +0000")
def_end_date   = timestamp("01 Dec 2024 07:30 +0000")

def_rsi_length = 2
def_overbought_value = 90
def_oversold_value   = 10

def_slow_ma_length = 200
def_fast_ma_length = 50
def_ma_choice      = "EMA"

def_tick   = 0.5
def_filter = true

def_trailing_stop = 1


//***********
// Change the optional parameters
//***********
start_time  = input(title="Start date", defval=def_start_date, type=input.time)
end_time    = input(title="End date", defval=def_end_date, type=input.time)
// RSI
src         = input(title="Source", defval=close, type=input.source)
rsi_length  = input(title="RSI Length", defval=def_rsi_length, minval=1, type=input.integer)
overbought_threshold = input(title="Overbought threshold", defval=def_overbought_value, type=input.float)
oversold_threshold   = input(title="Oversold threshold", defval=def_oversold_value, type=input.float)
// Moving average
slow_ma_length = input(title="Slow MA length", defval=def_slow_ma_length, type=input.integer)
fast_ma_length = input(title="Fast MA length", defval=def_fast_ma_length, type=input.integer)
ma_choice = input(title="MA choice", defval="EMA", options=["SMA", "EMA"])
// Input ticker
tick   = input(title="Ticker size", defval=def_tick, type=input.float)
filter = input(title="Trend Filter", defval=def_filter, type=input.bool)
// Trailing stop (%)
ts_rate = input(title="Trailing Stop %", defval=def_trailing_stop, type=input.float)


//***********
// RSI
//***********
// Calculate RSI
up   = rma(max(change(src), 0), rsi_length)
down = rma(-min(change(src), 0), rsi_length)
rsi = (down == 0 ? 100 : (up == 0 ? 0 : 100-100/(1+up/down)))


//***********
// Moving averages
//***********
slow_ma = (ma_choice == "SMA" ? sma(close, slow_ma_length) : ema(close, slow_ma_length))
fast_ma = (ma_choice == "SMA" ? sma(close, fast_ma_length) : ema(close, fast_ma_length))
// Show the moving averages
plot(slow_ma, color=color.white,  title="Slow MA")
plot(fast_ma, color=color.yellow, title="Fast MA")


//***********
// Strategy
//***********
if true
    // Determine the entry conditions (only market entry and market exit conditions)
    // Long position
    ConditionEntryL := (filter == true ? (fast_ma > slow_ma and close > slow_ma and rsi < oversold_threshold) : (fast_ma > slow_ma and rsi < oversold_threshold))
    // Short position
    ConditionEntryS := (filter == true ? (fast_ma < slow_ma and close < slow_ma and rsi > overbought_threshold) : (fast_ma < slow_ma and rsi > overbought_threshold))
   
    // Calculate the trailing stop
    ts_calc = close * (1/tick) * ts_rate * 0.01

    // Submit the entry orders and the exit orders
    // Long position
    if ConditionEntryL
        strategy.entry("RSI Long", strategy.long)
    // Exit from a long position
    strategy.exit("Exit Long", "RSI Long", trail_points=0, trail_offset=ts_calc)

    // Short position 
    if ConditionEntryS
        strategy.entry("RSI Short", strategy.short)
    // Exit from a short position
    strategy.exit("Exit Short", "RSI Short", trail_points=0, trail_offset=ts_calc)

// Highlights long conditions
bgcolor (ConditionEntryL ? color.navy : na, transp=60, offset=1, editable=true, title="Long position band")
// Highlights short conditions
bgcolor (ConditionEntryS ? color.olive : na, transp=60, offset=1, editable=true, title="Short position band")

---

• মাধ্যাকর্ষণ কেন্দ্র ব্যাকটেস্টিং ট্রেডিং কৌশল
• পিভট পয়েন্ট ব্রেকআউট কৌশল
• ইম্পোমেন্টাম পলব্যাক কৌশল
• ক্রিপ্টো কৌশল অনুসরণ করে RSI প্রবণতা
• ট্রেন ট্র্যাকিং স্ট্র্যাটেজি ডুয়াল ভর্টেক্স ইন্ডিকেটরের উপর ভিত্তি করে সত্যিকারের শক্তি সূচকের সাথে মিলিত
• ইচিমোকু প্রাথমিক মেঘ প্রবণতা অনুসরণ কৌশল
• মাল্টি-টাইমফ্রেম মুভিং এভারেজ সিস্টেম ট্রেডিং স্ট্র্যাটেজি
• ইভিডব্লিউএমএ কৌশল অনুসরণ করে প্রবণতা
• পরিবর্তনের হার পরিমাণগত কৌশল
• ইএমএ ট্রেন্ড ট্র্যাকিং ওসিলেশন স্ট্র্যাটেজি দমন
• ভলিউম এবং মূল্য পলব্যাকের সাথে উন্নত কৌশল মাল্টিপল টেক লাভ
• দীর্ঘমেয়াদী প্রবণতা ট্র্যাকিং সহজ পলব্যাক কৌশল
• আরএসআই সূচক এবং ২০০ দিনের এসএএমএ ফিল্টারের উপর ভিত্তি করে পরোক্ষ শক্তি সূচক কৌশল
• স্টোকাস্টিক মম্পটাম ইনডেক্স এবং আরএসআই ভিত্তিক কোয়ান্ট ট্রেডিং কৌশল
• ট্রেডিং কৌশল অনুসরণ করে গতির সূচক চালিত প্রবণতা
• প্রাইস এক্সট্রিমামের উপর ভিত্তি করে ট্রেডিং কৌশল
• এমএসিডি কৌশল - দ্বি-মুখী প্রস্থান ট্রেডিং
• ইম্পোমেন্ট ফিল্টারিং চলমান গড় কৌশল
• এসএমএ এবং ইএমএ ভিত্তিক পরিমাণগত ট্রেডিং কৌশল
• উন্নত সুপারট্রেন্ড ট্র্যাকিং কৌশল