En la carga de los recursos... Cargando...
  1. Cuadrado
  2. Estrategia de aprendizaje automático KNN: Sistema de negociación de predicción de tendencias basado en el algoritmo de vecinos más cercanos K

Estrategia de aprendizaje automático KNN: Sistema de negociación de predicción de tendencias basado en el algoritmo de vecinos más cercanos K

El autor:¿ Qué pasa?, Fecha: 2024-05-15 17:09:34
Las etiquetas:N.N.C.N.- ¿Qué es?El ATR

img

Resumen general

Esta estrategia emplea el algoritmo de aprendizaje automático K-Nearest Neighbors (KNN) para predecir las tendencias de precios. Seleccionando diferentes métodos de cálculo de precios (como HL2, VWAP, SMA, etc.) como valores de entrada y varios valores objetivo (como acción de precios, VWAP, volatilidad, etc.) para la evaluación, el algoritmo KNN identifica los puntos de datos históricos K más cercanos al estado actual del mercado. La estrategia luego hace predicciones de tendencia largas o cortas basadas en la dirección de la tendencia de estos puntos de datos K. Además, la estrategia aplica un promedio móvil para suavizar los resultados de la predicción y mejorar la estabilidad.

Principios de estrategia

  1. Seleccionar un método de cálculo de precios (por ejemplo, HL2, VWAP, SMA) como valor de entrada para el algoritmo KNN.
  2. Elegir un objetivo de evaluación (por ejemplo, acción de precios, VWAP, volatilidad) como valor objetivo para el algoritmo KNN.
  3. Establecer el número de vecinos más cercanos (K) y el período de suavización para ajustar la sensibilidad del algoritmo KNN y la suavidad de los resultados de predicción.
  4. Para cada nuevo punto de datos de precios, utilizar el algoritmo KNN para encontrar los K puntos de datos históricos más cercanos al estado actual del mercado.
  5. Basándose en la dirección de la tendencia ( alcista o bajista) de estos puntos de datos K, vote para obtener la predicción de la tendencia actual del mercado.
  6. Limpiar los resultados de la predicción utilizando una media móvil para mejorar la estabilidad.
  7. Generar señales comerciales (largas o cortas) basadas en los resultados de la predicción suavizada y demostrar visualmente la predicción de la tendencia actual del mercado mediante cambios en el color de fondo.

Ventajas

  1. Al utilizar un algoritmo de aprendizaje automático, la estrategia puede aprender de datos históricos y predecir las tendencias de precios, proporcionando adaptabilidad y flexibilidad.
  2. El rendimiento de la estrategia puede optimizarse para adaptarse a las diferentes condiciones del mercado ajustando parámetros como los valores de entrada, los valores objetivo, el número de vecinos más cercanos y el período de suavización.
  3. La combinación de los resultados de las predicciones con una media móvil mejora la estabilidad y fiabilidad de las predicciones.
  4. La predicción de la tendencia actual del mercado se demuestra visualmente a través de cambios en el color de fondo, lo que permite a los operadores evaluar rápidamente las condiciones del mercado y tomar decisiones.

Los riesgos

  1. El rendimiento predictivo del algoritmo KNN se basa en la calidad y la representatividad de los datos históricos.
  2. El rendimiento de la estrategia puede verse influenciado por la configuración de parámetros, y las combinaciones inadecuadas de parámetros pueden dar lugar a un rendimiento deficiente o a un sobreajuste.
  3. Cuando la tendencia del mercado experimenta cambios rápidos o ocurren eventos de cisne negro, las predicciones basadas en datos históricos pueden volverse ineficaces, lo que hace que la estrategia genere señales comerciales incorrectas.

Direcciones de optimización

  1. Incorporar más indicadores técnicos o datos sobre el sentimiento del mercado como datos de entrada para el algoritmo KNN para mejorar la precisión y robustez de las predicciones.
  2. Implementar un mecanismo adaptativo para ajustar dinámicamente los parámetros de la estrategia en función de las diferentes condiciones del mercado y los niveles de volatilidad.
  3. Combinar otros métodos de análisis técnico o medidas de gestión del riesgo para reducir la exposición al riesgo de la estrategia y mejorar la estabilidad de los rendimientos.

Resumen de las actividades

Al aplicar el algoritmo de aprendizaje automático KNN a la predicción de tendencias de precios, esta estrategia demuestra cómo capturar tendencias de mercado y generar señales comerciales utilizando datos históricos y métodos estadísticos. Las fortalezas de la estrategia se encuentran en su adaptabilidad y flexibilidad, ya que se puede optimizar a través de ajustes de parámetros para adaptarse a diferentes condiciones del mercado. Sin embargo, los riesgos de la estrategia se derivan principalmente de la calidad y la representatividad de los datos históricos, así como de la razonabilidad de la configuración de parámetros. Las mejoras futuras podrían incluir la incorporación de más indicadores, mecanismos adaptativos y medidas de gestión de riesgos para mejorar aún más la robustez y rentabilidad de la estrategia.

/*backtest
start: 2023-05-09 00:00:00
end: 2024-05-14 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/


// This work is licensed under a Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0) https://creativecommons.org/licenses/by-nc-sa/4.0/
// © Blake_22 {

//@version=5
strategy('money printer part 1', overlay=true)

// ~~ Tooltips {
t1 ="PriceValue selects the method of price computation. \n\nSets the smoothing period for the PriceValue. \n\nAdjusting these settings will change the input values for the K-Nearest Neighbors algorithm, influencing how the trend is calculated."
t2 = "TargetValue specifies the target to evaluate. \n\nSets the smoothing period for the TargetValue."
t3 ="numberOfClosestValues sets the number of closest values that are considered when calculating the KNN Moving Average. Adjusting this number will affect the sensitivity of the trend line, with a higher value leading to a smoother line and a lower value resulting in a line that is more responsive to recent price changes."
t4 ="smoothingPeriod sets the period for the moving average applied to the KNN classifier. Adjusting the smoothing period will affect how rapidly the trend line responds to price changes, with a larger smoothing period leading to a smoother line that may lag recent price movements, and a smaller smoothing period resulting in a line that more closely tracks recent changes."
t5 ="This option controls the background color for the trend prediction. Enabling it will change the background color based on the prediction, providing visual cues on the direction of the trend. A green color indicates a positive prediction, while red indicates a negative prediction."
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

// ~~ Inputs {
PriceValue   = input.string("hl2", options = ["hl2","VWAP", "sma", "wma", "ema", "hma"], group="", inline="Value")
maLen        = input.int(5, minval=2, maxval=200, title="", group="", inline="Value", tooltip=t1)
TargetValue  = input.string("Price Action", options = ["Price Action","VWAP", "Volatility", "sma", "wma", "ema", "hma"], group="", inline="Target")
maLen_       = input.int(5, minval=2, maxval=200, title="", group="", inline="Target", tooltip=t2)
// Input parameters for the KNN Moving Average
numberOfClosestValues = input.int(3, "Number of Closest Values", 2, 200, tooltip=t3) 
smoothingPeriod       = input.int(50, "Smoothing Period", 2, 500, tooltip=t4) 
windowSize            = math.max(numberOfClosestValues, 30) 

// knn Color
Upknn_col   = input.color(color.lime, title="", group="KNN Color", inline="knn col")
Dnknn_col   = input.color(color.red, title="", group="KNN Color", inline="knn col")
Neuknn_col  = input.color(color.orange, title="", group="KNN Color", inline="knn col")
// MA knn Color
Maknn_col   = input.color(color.teal, title="", group="MA KNN Color", inline="MA knn col")
// BG Color
bgcolor = input.bool(false, title="Trend Prediction Color", group="BG Color", inline="bg", tooltip=t5)
Up_col  = input.color(color.lime, title="", group="BG Color", inline="bg")
Dn_col  = input.color(color.red, title="", group="BG Color", inline="bg")
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

// ~~ kNN Classifier {
value_in = switch PriceValue
    "hl2"  => ta.sma(hl2,maLen)
    "VWAP" => ta.vwap(close[maLen])
    "sma" => ta.sma(close,maLen)
    "wma" => ta.wma(close,maLen)
    "ema" => ta.ema(close,maLen)
    "hma" => ta.hma(close,maLen)

meanOfKClosest(value_,target_) => 
    closestDistances = array.new_float(numberOfClosestValues, 1e10) 
    closestValues    = array.new_float(numberOfClosestValues, 0.0) 
    for i = 1 to windowSize 
        value = value_[i] 
        distance = math.abs(target_ - value) 
        maxDistIndex = 0 
        maxDistValue = closestDistances.get(0) 
        for j = 1 to numberOfClosestValues - 1 
            if closestDistances.get(j) > maxDistValue
                maxDistIndex := j
                maxDistValue := closestDistances.get(j)
        if distance < maxDistValue 
            closestDistances.set(maxDistIndex, distance)
            closestValues.set(maxDistIndex, value)
    closestValues.sum() / numberOfClosestValues 

// Choose the target input based on user selection
target_in = switch TargetValue
    "Price Action"  => ta.rma(close,maLen_) 
    "VWAP"          => ta.vwap(close[maLen_])
    "Volatility"    => ta.atr(14)
    "sma" => ta.sma(close,maLen_)
    "wma" => ta.wma(close,maLen_)
    "ema" => ta.ema(close,maLen_)
    "hma" => ta.hma(close,maLen_)

knnMA = meanOfKClosest(value_in,target_in)
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

// ~~ kNN Prediction {
// Function to calculate KNN Classifier
price = math.avg(knnMA, close)
c     = ta.rma(knnMA[1], smoothingPeriod) 
o     = ta.rma(knnMA, smoothingPeriod)

// Defines KNN function to perform classification
knn(price) => 
    Pos_count = 0 
    Neg_count = 0 
    min_distance = 10e10 
    nearest_index = 0 
    for j = 1 to 10 
        distance = math.sqrt(math.pow(price[j] - price, 2)) 
        if distance < min_distance 
            min_distance := distance
            nearest_index := j
            Neg = c[nearest_index] > o[nearest_index] 
            Pos = c[nearest_index] < o[nearest_index] 
            if Pos 
                Pos_count += 1
            if Neg 
                Neg_count += 1
    output = Pos_count>Neg_count?1:-1 

// Calls KNN function and smooths the prediction
knn_prediction_raw = knn(price) 
knn_prediction     = ta.wma(knn_prediction_raw, 3)
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

// ~~ Plots {
// Plots for display on the chart
knnMA_          = ta.wma(knnMA,5)
knnMA_col       = knnMA_>knnMA_[1]?Upknn_col:knnMA_<knnMA_[1]?Dnknn_col:Neuknn_col
Classifier_Line = plot(knnMA_,"Knn Classifier Line", knnMA_col)
MAknn_          = ta.rma(knnMA, smoothingPeriod)
plot(MAknn_,"Average Knn Classifier Line" ,Maknn_col) 
green = knn_prediction < 0.5
red   = knn_prediction > -0.5 
bgcolor( green and bgcolor? color.new(Dn_col,80) : 
 red and bgcolor ? color.new(Up_col,80) : na) 
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

// ~~ Alerts {
knnMA_cross_Over_Ma      = ta.crossover(knnMA_,MAknn_)
knnMA_cross_Under_Ma     = ta.crossunder(knnMA_,MAknn_)
knnMA_cross_Over_Close   = ta.crossover(knnMA_,close)
knnMA_cross_Under_Close  = ta.crossunder(knnMA_,close)
knnMA_Switch_Up          = knnMA_[1]<knnMA_ and knnMA_[1]<=knnMA_[2]
knnMA_Switch_Dn          = knnMA_[1]>knnMA_ and knnMA_[1]>=knnMA_[2]
knnMA_Neutral            = knnMA_col==Neuknn_col and knnMA_col[1]!=Neuknn_col
greenBG                  = green and not green[1]
redBG                    = red and not red[1]

alertcondition(knnMA_cross_Over_Ma,  title = "Knn Crossover Average Knn",  message = "Knn Crossover Average Knn")
alertcondition(knnMA_cross_Under_Ma, title = "Knn Crossunder Average Knn", message = "Knn Crossunder Average Knn")
alertcondition(knnMA_cross_Over_Close,  title = "Knn Crossover Close",  message = "Knn Crossover Close")
alertcondition(knnMA_cross_Under_Close, title = "Knn Crossunder Close", message = "Knn Crossunder Close")
alertcondition(knnMA_Switch_Up,  title = "Knn Switch Up",  message = "Knn Switch Up")
alertcondition(knnMA_Switch_Dn, title = "Knn Switch Dn", message = "Knn Switch Dn")
alertcondition(knnMA_Neutral, title = "Knn is Neutral", message = "Knn is Neutral")
alertcondition(greenBG, title = "Positive Prediction", message = "Positive Prediction")
alertcondition(redBG, title = "Negative Prediction", message = "Negative Prediction")
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

//~~Trenddilo {



//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}



//~~ strategy { 1

LongCondtion = knnMA_[1]<knnMA_ and knnMA_[1]<=knnMA_[2]
ShortCondtion = knnMA_[1]>knnMA_ and knnMA_[1]>=knnMA_[2]


//SecondaryLongCondtion = col == color.lime
//SecondaryShortCondtion = col == color.red

strategy.entry("Long", strategy.long, when = LongCondtion)
strategy.close("Long", when =ShortCondtion)

strategy.entry("Short", strategy.short, when =ShortCondtion)
strategy.close("short", when =LongCondtion)


plot(strategy.equity, title="equity", color=color.red, linewidth=2, style=plot.style_areabr)
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}
Relacionados
Más.

2019 FMZ - Todos los derechos reservados