Les ressources ont été chargées... Je charge...
  1. Carré
  2. Stratégie de modèle d'optimisation de la tendance de fusion ATR

Stratégie de modèle d'optimisation de la tendance de fusion ATR

Auteur:ChaoZhang est là., Date: 2024-11-28 17h06 et 21h
Les étiquettes:ATRSMATPBPRésultatsSL

img

Résumé

Cette stratégie est un système avancé de suivi des tendances basé sur les moyennes pondérées ATR et Fibonacci. Elle combine l'analyse de la volatilité sur plusieurs délais avec la moyenne pondérée Fibonacci pour créer un modèle de trading réactif et adaptatif.

Principe de stratégie

La stratégie utilise une approche d'indicateur technique à plusieurs niveaux: elle calcule d'abord la True Range (TR) et la pression d'achat (BP), puis calcule les ratios de pression basés sur les périodes de la séquence de Fibonacci (8,13,21,34,55). Différents poids (5,4,3,2,1) sont appliqués à différentes périodes pour construire une moyenne pondérée, encore lissée par un SMA à 3 périodes. Les signaux de trading sont déclenchés par des croisements SMA avec des seuils prédéfinis (58,0 et 42,0) et un mécanisme de prise de profit en quatre étapes est conçu en utilisant ATR.

Les avantages de la stratégie

  1. Analyse multidimensionnelle: Combine des données provenant de plusieurs délais pour une perspective globale du marché
  2. Adaptation dynamique: Adaptation à la volatilité du marché par le biais de l'ATR, renforcement de la stabilité de la stratégie
  3. Prise de profit intelligente: mécanisme à quatre étapes qui s'adapte de manière flexible aux différentes conditions du marché
  4. Risque contrôlé: des conditions d'entrée et de sortie claires réduisent les risques de jugement subjectif
  5. Opération systématique: logique stratégique claire, facile à quantifier et backtest

Risques stratégiques

  1. Sensibilité des paramètres: plusieurs seuils et paramètres de poids nécessitent un ajustement minutieux
  2. Risque de décalage: le lissage de la SMA peut entraîner des retards de signal
  3. Dépendance de l'environnement du marché: peut générer de faux signaux sur différents marchés
  4. Adaptation des paramètres: les paramètres doivent être optimisés pour les différentes conditions du marché Solution: recommander une optimisation approfondie des paramètres et un backtesting, avec un ajustement dynamique des paramètres pour les différentes phases du marché.

Directions d'optimisation de la stratégie

  1. Adaptation des paramètres: développer des mécanismes d'adaptation des paramètres
  2. Filtrage du marché: ajout du module de reconnaissance de l'environnement du marché
  3. Optimisation du signal: introduire des indicateurs de confirmation auxiliaires
  4. Amélioration de la maîtrise des risques: ajout d'un stop-loss dynamique et de la gestion des positions
  5. Contrôle des prélèvements: mettre en œuvre des limites maximales de prélèvement

Résumé

Cette stratégie intègre les moyennes pondérées ATR et Fibonacci pour construire un système complet de suivi des tendances. Ses atouts résident dans l'analyse multidimensionnelle et les capacités d'adaptation dynamique, tandis que l'attention doit être portée à l'optimisation des paramètres et au filtrage de l'environnement du marché.

/*backtest
start: 2019-12-23 08:00:00
end: 2024-11-27 00:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © PresentTrading

// The Fibonacci ATR Fusion Strategy is an advanced trading methodology that uniquely integrates Fibonacci-based weighted averages with the Average True Range (ATR) to 
// identify and exploit significant market trends. Unlike traditional strategies that rely on single indicators or fixed parameters, this approach leverages multiple timeframes and 
// dynamic volatility measurements to enhance accuracy and adaptability. 

//@version=5
strategy("Fibonacci ATR Fusion - Strategy [presentTrading]", overlay=false, precision=3, commission_value= 0.1, commission_type=strategy.commission.percent, slippage= 1, currency=currency.USD, default_qty_type = strategy.percent_of_equity, default_qty_value = 10, initial_capital=10000)

// Calculate True High and True Low
tradingDirection = input.string(title="Trading Direction", defval="Both", options=["Long", "Short", "Both"])

// Trading Condition Thresholds
long_entry_threshold = input.float(58.0, title="Long Entry Threshold")
short_entry_threshold = input.float(42.0, title="Short Entry Threshold")
long_exit_threshold = input.float(42.0, title="Long Exit Threshold")
short_exit_threshold = input.float(58.0, title="Short Exit Threshold")

// Enable or Disable 4-Step Take Profit
useTakeProfit = input.bool(false, title="Enable 4-Step Take Profit")

// Take Profit Levels (as multiples of ATR)
tp1ATR = input.float(3.0, title="Take Profit Level 1 ATR Multiplier")
tp2ATR = input.float(8.0, title="Take Profit Level 2 ATR Multiplier")
tp3ATR = input.float(14.0, title="Take Profit Level 3 ATR Multiplier")

// Take Profit Percentages
tp1_percent = input.float(12.0, title="TP Level 1 Percentage", minval=0.0, maxval=100.0)
tp2_percent = input.float(12.0, title="TP Level 2 Percentage", minval=0.0, maxval=100.0)
tp3_percent = input.float(12.0, title="TP Level 3 Percentage", minval=0.0, maxval=100.0)

true_low = math.min(low, close[1])
true_high = math.max(high, close[1])

// Calculate True Range
true_range = true_high - true_low

// Calculate BP (Buying Pressure)
bp = close - true_low

// Calculate ratios for different periods
calc_ratio(len) =>
    sum_bp = math.sum(bp, len)
    sum_tr = math.sum(true_range, len)
    100 * sum_bp / sum_tr

// Calculate weighted average of different timeframes
weighted_avg = (5 * calc_ratio(8) + 4 * calc_ratio(13) + 3 * calc_ratio(21) + 2 * calc_ratio(34) + calc_ratio(55)) / (5 + 4 + 3 + 2 + 1)
weighted_avg_sma = ta.sma(weighted_avg,3)

// Plot the indicator
plot(weighted_avg, "Fibonacci ATR", color=color.blue, linewidth=2)
plot(weighted_avg_sma, "SMA Fibonacci ATR", color=color.yellow, linewidth=2)

// Define trading conditions
longCondition = ta.crossover(weighted_avg_sma, long_entry_threshold)  // Enter long when weighted average crosses above threshold
shortCondition = ta.crossunder(weighted_avg_sma, short_entry_threshold) // Enter short when weighted average crosses below threshold
longExit = ta.crossunder(weighted_avg_sma, long_exit_threshold)
shortExit = ta.crossover(weighted_avg_sma, short_exit_threshold)


atrPeriod = 14
atrValue = ta.atr(atrPeriod)

if (tradingDirection == "Long" or tradingDirection == "Both")
    if (longCondition)
        strategy.entry("Long", strategy.long)
        // Set Take Profit levels for Long positions
        if useTakeProfit
            tpPrice1 = strategy.position_avg_price + tp1ATR * atrValue
            tpPrice2 = strategy.position_avg_price + tp2ATR * atrValue
            tpPrice3 = strategy.position_avg_price + tp3ATR * atrValue
            // Close partial positions at each Take Profit level
            strategy.exit("TP1 Long", from_entry="Long", qty_percent=tp1_percent, limit=tpPrice1)
            strategy.exit("TP2 Long", from_entry="Long", qty_percent=tp2_percent, limit=tpPrice2)
            strategy.exit("TP3 Long", from_entry="Long", qty_percent=tp3_percent, limit=tpPrice3)
    if (longExit)
        strategy.close("Long")

if (tradingDirection == "Short" or tradingDirection == "Both")
    if (shortCondition)
        strategy.entry("Short", strategy.short)
        // Set Take Profit levels for Short positions
        if useTakeProfit
            tpPrice1 = strategy.position_avg_price - tp1ATR * atrValue
            tpPrice2 = strategy.position_avg_price - tp2ATR * atrValue
            tpPrice3 = strategy.position_avg_price - tp3ATR * atrValue
            // Close partial positions at each Take Profit level
            strategy.exit("TP1 Short", from_entry="Short", qty_percent=tp1_percent, limit=tpPrice1)
            strategy.exit("TP2 Short", from_entry="Short", qty_percent=tp2_percent, limit=tpPrice2)
            strategy.exit("TP3 Short", from_entry="Short", qty_percent=tp3_percent, limit=tpPrice3)
    if (shortExit)
        strategy.close("Short")
Relationnée
Plus de

2019 FMZ - Tous les droits réservés