1. 사각형
2. 전략에 따른 변동성 추세

전략에 따른 변동성 추세

저자:차오장, 날짜: 2024-04-01 11:07:23
태그:

---

---

/*backtest
start: 2024-03-01 00:00:00
end: 2024-03-31 23:59:59
period: 4h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// © Julien_Eche

//@version=5
strategy('Volatility Trend Strategy', overlay=true, default_qty_type=strategy.percent_of_equity, default_qty_value=20)

// Input parameters
Length = input.int(defval=20, title='Length', minval=1) // Length parameter for Bollinger Bands
Dev = input.float(defval=1.0, title='Deviation', minval=0.1, step=0.05) // Deviation parameter for Bollinger Bands
UseFilter = input(defval=true, title='Use Filter') // Option to use filter
ATRLength = input.int(defval=14, title='ATR Length', minval=1) // ATR Length parameter
HideLabels = input(defval=false, title='Hide Labels') // Option to hide labels

// Calculation of Bollinger Bands
UpperBand = ta.sma(close, Length) + ta.stdev(close, Length) * Dev
LowerBand = ta.sma(close, Length) - ta.stdev(close, Length) * Dev

// Initialization of variables
Line = 0.0
Trend = 0.0

// Calculation of Average True Range (ATR)
atrValue = ta.atr(ATRLength)

// Determine signal based on Bollinger Bands
Signal = close > UpperBand ? 1 : close < LowerBand ? -1 : 0

// Determine trend line based on signal and filter option
if Signal == 1
    if UseFilter == true
        Line := low - atrValue
        if Line < Line[1]
            Line := Line[1]
    else
        Line := low
        if Line < Line[1]
            Line := Line[1]
        
if Signal == -1
    if UseFilter == true
        Line := high + atrValue
        if Line > Line[1]
            Line := Line[1]
    else
        Line := high
        if Line > Line[1]
            Line := Line[1]

if Signal == 0
    Line := Line[1]

// Determine trend direction
Trend := Trend[1]
if Line > Line[1]
    Trend := 1
if Line < Line[1]
    Trend := -1

// Determine buy and sell signals
BuySignal = Trend[1] == -1 and Trend == 1 ? true : false
SellSignal = Trend[1] == 1 and Trend == -1 ? true : false

// Plot trend line
plot(Line, color=Trend > 0 ? color.new(color.blue, 100) : color.new(color.red, 100), style=plot.style_line, linewidth=2, title='Trend Line')

// Plot buy and sell signals
plotshape(BuySignal == true and HideLabels == false ? Line - atrValue : na, style=shape.labelup, location=location.absolute, color=color.new(color.blue, 0), textcolor=color.new(color.white, 0), offset=0, size=size.auto)
plotshape(SellSignal == true and HideLabels == false ? Line + atrValue : na, style=shape.labeldown, location=location.absolute, color=color.new(color.red, 0), textcolor=color.new(color.white, 0), offset=0, size=size.auto)

// Entry and exit strategy
if BuySignal
    strategy.entry('Buy', strategy.long)
if SellSignal
    strategy.close('Buy')

---

• 동적 위험 관리 전략에 따른 다중 지표 트렌드
• 루다 모멘텀 트렌드 거래 전략
• 이중 이동 평균 크로스오버 전략
• 수정된 볼링거 밴드 전략
• 동적 임계 가격 변화 파업 전략
• 이중 이동평균 후속 브레이크업 전략
• 이중 이동평균 크로스오버 전략으로 운동 거래
• 다중 지표 BTC 거래 전략
• TD 순차적인 파업 및 리트랙션 구매/판매 전략
• SMA 크로스오버 컴파운딩 전략
• 이중 이동 평균 및 RSI 기반 단기 확장 트렌드 전략
• 듀얼 레인지 필터 모멘텀 거래 전략
• VWAP 이동 평균 크로스오버와 동적 ATR 스톱 로스 및 영업 전략
• 자금 데이터에 기초한 시간 계열 적응적 동적 기준 전략
• 아시아 세션 높은 낮은 브레이크업 전략
• 화살표와 경고 전략으로 마커스의 트렌드 트레이더
• 전략에 따른 EMA의 이중 이동평균 크로스오버 트렌드
• 이동 평균 크로스오버 전략
• 수동 TP와 SL로 RSI 모멘텀 전략
• EMA RSI 트렌드 추적 및 모멘텀 전략