O recurso está a ser carregado... Carregamento...
  1. Quadrado
  2. Estratégia de arbitragem estatística adaptativa de acompanhamento do momento

Estratégia de arbitragem estatística adaptativa de acompanhamento do momento

Autora:ChaoZhang, Data: 2023-12-11 16:41:27
Tags:

img

Resumo

Esta estratégia constrói um envelope de volatilidade dinâmica baseado no método de regressão do núcleo de Nadaraya-Watson para gerar sinais de negociação de compra baixa e venda alta rastreando as situações de cruzamento entre o preço e as faixas de envelope.

Estratégia lógica

O núcleo da estratégia é calcular o envelope dinâmico do preço. Em primeiro lugar, usando uma janela de retrospectiva personalizada, ele constrói as curvas de regressão do núcleo de Nadaraya-Watson do preço (certo, alto, baixo) para obter uma estimativa de preço suavizada. Em seguida, ele calcula o ATR com base em um comprimento ATR personalizado e forma as bandas de envelope superior e inferior com fatores próximos e distantes. Quando o preço entra no envelope de baixo, um sinal de compra é gerado. Quando o preço sai do envelope de cima, um sinal de venda é ativado. Ao rastrear a relação dinâmica entre o preço e as propriedades estatísticas relacionadas à volatilidade, a estratégia ajusta suas decisões de negociação de forma adaptativa.

Vantagens

  1. Com base em modelos matemáticos com parâmetros controláveis, menor probabilidade de sobreajuste.
  2. Adaptação às alterações do mercado, aproveitando a relação dinâmica entre preços e volatilidade para captar oportunidades de negociação.
  3. A escala de log funciona bem com diferentes prazos e instrumentos com diferentes magnitudes de volatilidade.
  4. Parâmetros personalizáveis para ajustar a sensibilidade da estratégia.

Riscos

  1. A natureza teórica dos modelos matemáticos, pode ter um desempenho inferior na negociação ao vivo.
  2. Os parâmetros-chave exigem especialização, configurações inadequadas podem prejudicar a rentabilidade.
  3. O atraso na emissão pode causar a perda de algumas oportunidades comerciais.
  4. Vulnerável a falhas em mercados altamente voláteis.

A otimização adequada, um backtest suficiente, a compreensão dos fatores-chave e uma avaliação prudente das posições na negociação ao vivo poderiam ajudar a mitigar estes riscos.

Orientações para melhorias

  1. Optimize os parâmetros para encontrar a melhor combinação.
  2. Aplicar métodos de aprendizagem de máquina para selecionar automaticamente parâmetros ideais.
  3. Adicionar filtros para ativar a estratégia em certos ambientes de mercado.
  4. Incorporar outros indicadores para filtrar sinais enganosos.
  5. Tente diferentes algoritmos de modelos matemáticos.

Conclusão

A estratégia incorpora análise estatística e análise de indicadores técnicos para gerar sinais de negociação rastreando dinamicamente a relação entre preço e volatilidade. Os parâmetros podem ser ajustados com base nas condições do mercado e necessidades pessoais.

/*backtest
start: 2022-12-04 00:00:00
end: 2023-12-10 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// © Julien_Eche
//@version=5

strategy("Nadaraya-Watson Envelope Strategy", overlay=true, pyramiding=1, default_qty_type=strategy.percent_of_equity, default_qty_value=20)

// Helper Functions
getEnvelopeBounds(_atr, _nearFactor, _farFactor, _envelope) => 
    _upperFar = _envelope + _farFactor*_atr
    _upperNear = _envelope + _nearFactor*_atr
    _lowerNear = _envelope - _nearFactor*_atr
    _lowerFar = _envelope - _farFactor*_atr
    _upperAvg = (_upperFar + _upperNear) / 2
    _lowerAvg = (_lowerFar + _lowerNear) / 2 
    [_upperNear, _upperFar, _upperAvg, _lowerNear, _lowerFar, _lowerAvg]

customATR(length, _high, _low, _close) =>
    trueRange = na(_high[1])? math.log(_high)-math.log(_low) : math.max(math.max(math.log(_high) - math.log(_low), math.abs(math.log(_high) - math.log(_close[1]))), math.abs(math.log(_low) - math.log(_close[1])))
    ta.rma(trueRange, length)

customKernel(x, h, alpha, x_0) =>
    sumWeights = 0.0
    sumXWeights = 0.0
    for i = 0 to h
        weight = math.pow(1 + (math.pow((x_0 - i), 2) / (2 * alpha * h * h)), -alpha)
        sumWeights := sumWeights + weight
        sumXWeights := sumXWeights + weight * x[i]
    sumXWeights / sumWeights

// Custom Settings
customLookbackWindow = input.int(8, 'Lookback Window (Custom)', group='Custom Settings')
customRelativeWeighting = input.float(8., 'Relative Weighting (Custom)', step=0.25, group='Custom Settings')
customStartRegressionBar = input.int(25, "Start Regression at Bar (Custom)", group='Custom Settings')

// Envelope Calculations
customEnvelopeClose = math.exp(customKernel(math.log(close), customLookbackWindow, customRelativeWeighting, customStartRegressionBar))
customEnvelopeHigh = math.exp(customKernel(math.log(high), customLookbackWindow, customRelativeWeighting, customStartRegressionBar))
customEnvelopeLow = math.exp(customKernel(math.log(low), customLookbackWindow, customRelativeWeighting, customStartRegressionBar))
customEnvelope = customEnvelopeClose
customATRLength = input.int(60, 'ATR Length (Custom)', minval=1, group='Custom Settings')
customATR = customATR(customATRLength, customEnvelopeHigh, customEnvelopeLow, customEnvelopeClose)
customNearATRFactor = input.float(1.5, 'Near ATR Factor (Custom)', minval=0.5, step=0.25, group='Custom Settings')
customFarATRFactor = input.float(2.0, 'Far ATR Factor (Custom)', minval=1.0, step=0.25, group='Custom Settings')
[customUpperNear, customUpperFar, customUpperAvg, customLowerNear, customLowerFar, customLowerAvg] = getEnvelopeBounds(customATR, customNearATRFactor, customFarATRFactor, math.log(customEnvelopeClose))

// Colors
customUpperBoundaryColorFar = color.new(color.red, 60)
customUpperBoundaryColorNear = color.new(color.red, 80)
customBullishEstimatorColor = color.new(color.teal, 50)
customBearishEstimatorColor = color.new(color.red, 50)
customLowerBoundaryColorNear = color.new(color.teal, 80)
customLowerBoundaryColorFar = color.new(color.teal, 60)

// Plots
customUpperBoundaryFar = plot(math.exp(customUpperFar), color=customUpperBoundaryColorFar, title='Upper Boundary: Far (Custom)')
customUpperBoundaryAvg = plot(math.exp(customUpperAvg), color=customUpperBoundaryColorNear, title='Upper Boundary: Average (Custom)')
customUpperBoundaryNear = plot(math.exp(customUpperNear), color=customUpperBoundaryColorNear, title='Upper Boundary: Near (Custom)') 
customEstimationPlot = plot(customEnvelopeClose, color=customEnvelope > customEnvelope[1] ? customBullishEstimatorColor : customBearishEstimatorColor, linewidth=2, title='Custom Estimation')
customLowerBoundaryNear = plot(math.exp(customLowerNear), color=customLowerBoundaryColorNear, title='Lower Boundary: Near (Custom)')
customLowerBoundaryAvg = plot(math.exp(customLowerAvg), color=customLowerBoundaryColorNear, title='Lower Boundary: Average (Custom)') 
customLowerBoundaryFar = plot(math.exp(customLowerFar), color=customLowerBoundaryColorFar, title='Lower Boundary: Far (Custom)')

// Fills
fill(customUpperBoundaryFar, customUpperBoundaryAvg, color=customUpperBoundaryColorFar, title='Upper Boundary: Farmost Region (Custom)')
fill(customUpperBoundaryNear, customUpperBoundaryAvg, color=customUpperBoundaryColorNear, title='Upper Boundary: Nearmost Region (Custom)')
fill(customLowerBoundaryNear, customLowerBoundaryAvg, color=customLowerBoundaryColorNear, title='Lower Boundary: Nearmost Region (Custom)')
fill(customLowerBoundaryFar, customLowerBoundaryAvg, color=customLowerBoundaryColorFar, title='Lower Boundary: Farmost Region (Custom)')


longCondition = ta.crossover(close, customEnvelopeLow)
if (longCondition)
    strategy.entry("Buy", strategy.long)

exitLongCondition = ta.crossover(customEnvelopeHigh, close)
if (exitLongCondition)
    strategy.close("Buy")
Mais.

2019 FMZ - Todos os direitos reservados