1. বর্গক্ষেত্র
2. অ্যাডাপ্টিভ ফিবোনাচি বোলিংজার ব্যান্ড কৌশল বিশ্লেষণ

অ্যাডাপ্টিভ ফিবোনাচি বোলিংজার ব্যান্ড কৌশল বিশ্লেষণ

লেখক:চাওঝাং, তারিখঃ ২০২৫-০১-০৬ ১৬ঃ৪১ঃ৪৮
ট্যাগঃএটিআরবি বিএসএমএএফআইবি

---

---

/*backtest
start: 2019-12-23 08:00:00
end: 2025-01-04 08:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
// © sapphire_edge 

// # ========================================================================= #
// #                  
// #        _____                   __    _              ______    __         
// #      / ___/____ _____  ____  / /_  (_)_______     / ____/___/ /___ ____ 
// #      \__ \/ __ `/ __ \/ __ \/ __ \/ / ___/ _ \   / __/ / __  / __ `/ _ \
// #     ___/ / /_/ / /_/ / /_/ / / / / / /  /  __/  / /___/ /_/ / /_/ /  __/
// #    /____/\__,_/ .___/ .___/_/ /_/_/_/   \___/  /_____/\__,_/\__, /\___/ 
// #              /_/   /_/                                     /____/       
// #                                      
// # ========================================================================= #

strategy(shorttitle="⟡Sapphire⟡ FiboBands Strategy", title="[Sapphire] Fibonacci Bollinger Bands Strategy", initial_capital= 50000, currency= currency.USD,default_qty_value = 1,commission_type= strategy.commission.cash_per_contract,overlay= true )

// # ========================================================================= #
// #                       // Settings Menu //
// # ========================================================================= #

// --------------------    Main Settings    -------------------- //
groupFiboBands = "FiboBands"
length = input.int(20, minval = 1, title = 'Length', group=groupFiboBands)
src = input(close, title = 'Source', group=groupFiboBands)
offset = input.int(0, 'Offset', minval = -500, maxval = 500, group=groupFiboBands)

fibo1 = input(defval = 1.618, title = 'Fibonacci Ratio 1', group=groupFiboBands)
fibo2 = input(defval = 2.618, title = 'Fibonacci Ratio 2', group=groupFiboBands)
fibo3 = input(defval = 4.236, title = 'Fibonacci Ratio 3', group=groupFiboBands)

fiboBuy = input.string(options = ['Fibo 1', 'Fibo 2', 'Fibo 3'], defval = 'Fibo 1', title = 'Fibonacci Buy', group=groupFiboBands)
fiboSell = input.string(options = ['Fibo 1', 'Fibo 2', 'Fibo 3'], defval = 'Fibo 1', title = 'Fibonacci Sell', group=groupFiboBands)

showSignals = input.bool(true, title="Show Signals", group=groupFiboBands)
signalOffset = input.int(5, title="Signal Vertical Offset", group=groupFiboBands)

// --------------------    Trade Management Inputs    -------------------- //
groupTradeManagement = "Trade Management"
useProfitPerc    = input.bool(false, title="Enable Profit Target", group=groupTradeManagement)
takeProfitPerc  = input.float(1.0, title="Take Profit (%)", step=0.1, group=groupTradeManagement)
useStopLossPerc    = input.bool(false, title="Enable Stop Loss", group=groupTradeManagement)
stopLossPerc    = input.float(1.0, title="Stop Loss (%)", step=0.1, group=groupTradeManagement)

// --------------------    Time Filter Inputs    -------------------- //
groupTimeOfDayFilter = "Time of Day Filter"
useTimeFilter1  = input.bool(false, title="Enable Time Filter 1", group=groupTimeOfDayFilter)
startHour1      = input.int(0, title="Start Hour (24-hour format)", minval=0, maxval=23, group=groupTimeOfDayFilter)
startMinute1    = input.int(0, title="Start Minute", minval=0, maxval=59, group=groupTimeOfDayFilter)
endHour1        = input.int(23, title="End Hour (24-hour format)", minval=0, maxval=23, group=groupTimeOfDayFilter)
endMinute1      = input.int(45, title="End Minute", minval=0, maxval=59, group=groupTimeOfDayFilter)
closeAtEndTimeWindow = input.bool(false, title="Close Trades at End of Time Window", group=groupTimeOfDayFilter)

// --------------------    Trading Window    -------------------- //
isWithinTradingWindow(startHour, startMinute, endHour, endMinute) =>
    nyTime            = timestamp("America/New_York", year, month, dayofmonth, hour, minute)
    nyHour            = hour(nyTime)
    nyMinute          = minute(nyTime)
    timeInMinutes     = nyHour * 60 + nyMinute
    startInMinutes    = startHour * 60 + startMinute
    endInMinutes      = endHour * 60 + endMinute
    timeInMinutes    >= startInMinutes and timeInMinutes <= endInMinutes

timeCondition =  (useTimeFilter1 ? isWithinTradingWindow(startHour1, startMinute1, endHour1, endMinute1) : true)

// Check if the current bar is the last one within the specified time window
isEndOfTimeWindow() =>
    nyTime            = timestamp("America/New_York", year, month, dayofmonth, hour, minute)
    nyHour            = hour(nyTime)
    nyMinute          = minute(nyTime)
    timeInMinutes     = nyHour * 60 + nyMinute
    endInMinutes      = endHour1 * 60 + endMinute1
    timeInMinutes == endInMinutes

// Logic to close trades if the time window ends
if timeCondition and closeAtEndTimeWindow and isEndOfTimeWindow()
    strategy.close_all(comment="Closing trades at end of time window")

// # ========================================================================= #
// #                       // Calculations //
// # ========================================================================= #

sma = ta.sma(src, length)
atr = ta.atr(length)

ratio1 = atr * fibo1
ratio2 = atr * fibo2
ratio3 = atr * fibo3

upper3 = sma + ratio3
upper2 = sma + ratio2
upper1 = sma + ratio1

lower1 = sma - ratio1
lower2 = sma - ratio2
lower3 = sma - ratio3

// # ========================================================================= #
// #                       // Signal Logic //
// # ========================================================================= #

// --------------------    Entry Logic    -------------------- //
targetBuy = fiboBuy == 'Fibo 1' ? upper1 : fiboBuy == 'Fibo 2' ? upper2 : upper3
buy = low < targetBuy and high > targetBuy

// --------------------    User-Defined Exit Logic    -------------------- //
targetSell = fiboSell == 'Fibo 1' ? lower1 : fiboSell == 'Fibo 2' ? lower2 : lower3
sell = low < targetSell and high > targetSell

// # ========================================================================= #
// #                       // Strategy Management //
// # ========================================================================= #

// --------------------    Trade Execution Flags    -------------------- //
var bool buyExecuted = false
var bool sellExecuted = false

float labelOffset = ta.atr(14) * signalOffset

// --------------------    Buy Logic    -------------------- //
if buy and timeCondition 
    if useProfitPerc or useStopLossPerc
        strategy.entry("Buy", strategy.long, stop=(useStopLossPerc ? close * (1 - stopLossPerc / 100) : na), limit=(useProfitPerc ? close * (1 + takeProfitPerc / 100) : na))
    else
        strategy.entry("Buy", strategy.long)

    if showSignals and not buyExecuted
        buyExecuted := true  
        sellExecuted := false  
        label.new(bar_index, high - labelOffset, "◭", style=label.style_label_up, color = color.rgb(119, 0, 255, 20), textcolor=color.white)

// --------------------    Sell Logic    -------------------- //
if sell and timeCondition
    if useProfitPerc or useStopLossPerc
        strategy.entry("Sell", strategy.short, stop=(useStopLossPerc ? close * (1 + stopLossPerc / 100) : na), limit=(useProfitPerc ? close * (1 - takeProfitPerc / 100) : na))
    else
        strategy.entry("Sell", strategy.short)

    if showSignals and not sellExecuted
        sellExecuted := true 
        buyExecuted := false  
        label.new(bar_index, low + labelOffset, "⧩", style=label.style_label_down, color = color.rgb(255, 85, 0, 20), textcolor=color.white)



// # ========================================================================= #
// #                         // Plots and Charts //
// # ========================================================================= #

plot(sma, style = plot.style_line, title = 'Basis', color = color.new(color.orange, 0), linewidth = 2, offset = offset)

upp3 = plot(upper3, title = 'Upper 3', color = color.new(color.teal, 90), offset = offset)
upp2 = plot(upper2, title = 'Upper 2', color = color.new(color.teal, 60), offset = offset)
upp1 = plot(upper1, title = 'Upper 1', color = color.new(color.teal, 30), offset = offset)

low1 = plot(lower1, title = 'Lower 1', color = color.new(color.teal, 30), offset = offset)
low2 = plot(lower2, title = 'Lower 2', color = color.new(color.teal, 60), offset = offset)
low3 = plot(lower3, title = 'Lower 3', color = color.new(color.teal, 90), offset = offset)

fill(upp3, low3, title = 'Background', color = color.new(color.teal, 95))

---

• বোলিংজার ব্যান্ড ATR ট্রেন্ড অনুসরণকারী কৌশল
• মাল্টি-পিরিয়ড বোলিংজার ব্যান্ডস টচ ট্রেন্ড বিপরীততা পরিমাণগত ট্রেডিং কৌশল
• বোলিংজার ব্যান্ডস মম্পটম অপ্টিমাইজেশান কৌশল
• উচ্চ নির্ভুলতা RSI এবং Bollinger Bands ব্রেকআউট কৌশল সঙ্গে অপ্টিমাইজড ঝুঁকি-প্রতিদান অনুপাত
• স্মার্ট টাইম-ভিত্তিক লং-কোর্ট রোটেশন ব্যালেন্সড ট্রেডিং স্ট্র্যাটেজি
• ডাবল স্ট্যান্ডার্ড ডিভিয়েশন বোলিংজার ব্যান্ডস মিনটেম ব্রেকআউট কৌশল
• বর্ধিত বোলিংজার মিড ইনভার্সন কোয়ান্টামেটিভ স্ট্র্যাটেজি
• ফিক্সড স্টপ-লস অপ্টিমাইজেশান মডেল সহ ডায়নামিক মুভিং এভারেজ এবং বোলিংজার ব্যান্ড ক্রস কৌশল
• ট্রিপল সুপারট্রেন্ড এবং বোলিংজার ব্যান্ডস মাল্টি-ইন্ডিক্টর ট্রেন্ড অনুসরণকারী কৌশল
• মাল্টি-টেকনিক্যাল ইনডিকেটর ডায়নামিক অ্যাডাপ্টিভ ট্রেডিং স্ট্র্যাটেজি (এমটিডিএটি)

---

• মাল্টি-পিরিয়ড সুপারট্রেন্ড ডায়নামিক পিরামিডিং ট্রেডিং কৌশল
• দীর্ঘমেয়াদী ট্রেন্ড এসএমএ ক্রসওভার পরিমাণগত কৌশল
• পরিমাণগত ট্রেডিং কৌশল অনুসরণ করে মাল্টি-টেকনিক্যাল ইন্ডিকেটর ফিউশন ট্রেন্ড
• মল্টি-টেকনিক্যাল ইন্ডিকেটর মোমেন্টম-এমএ ট্রেন্ড অনুসরণকারী কৌশল
• স্মার্ট R2R-ভিত্তিক স্টপ লস ম্যানেজমেন্ট সহ ট্রিপল EMA ক্রসওভার ট্রেডিং সিস্টেম
• ডায়নামিক ভোল্টেবিলিটি-ড্রাইভড হাই ফ্রিকোয়েন্সি ইএমএ ক্রসওভার কোয়ান্টিটেটিভ স্ট্র্যাটেজি
• ঝুঁকি ব্যবস্থাপনা সিস্টেমের সাথে দ্বৈত প্রযুক্তিগত সূচক গতির বিপরীত ট্রেডিং কৌশল
• EMA-Smoothed RSI এবং ATR Dynamic Stop-Loss/Take-Profit-এর উপর ভিত্তি করে মাল্টি-টাইমফ্রেম কোয়ান্টিটেটিভ ট্রেডিং কৌশল
• মাল্টি-টাইমফ্রেম ক্যান্ডেলস্টাইল প্যাটার্ন ট্রেডিং কৌশল
• মাল্টি-টাইমফ্রেম সুপারট্রেন্ড ডায়নামিক ট্রেন্ড ট্রেডিং অ্যালগরিদম
• অ্যাডাপ্টিভ রিস্ক ম্যানেজমেন্ট সহ উন্নত এমএসিডি ক্রসওভার ট্রেডিং কৌশল
• ক্যান্ডেলস্টিক উইক দৈর্ঘ্যের বিশ্লেষণের উপর ভিত্তি করে পরিমাণগত প্রবণতা ক্যাপচার কৌশল
• পরিসংখ্যানগত দ্বৈত স্ট্যান্ডার্ড বিচ্যুতি VWAP ব্রেকআউট ট্রেডিং কৌশল
• ড্রডাউন এবং টার্গেট মুনাফার উপর ভিত্তি করে লং গ্রিড কৌশল
• এটিআর ঝুঁকি ব্যবস্থাপনা সিস্টেমের সাথে কৌশল অনুসরণ করে গতিশীল চলমান গড় ক্রসওভার প্রবণতা
• ডায়নামিক স্টোকাস্টিক প্যাটার্ন ট্রেডিং সিস্টেমের উপর ভিত্তি করে মাল্টি-ইন্ডিক্টর অপ্টিমাইজড কেডিজে ট্রেন্ড ক্রসওভার কৌশল
• ট্রেডিং সিস্টেম অনুসরণ করে মাল্টি-টাইমফ্রেম হেকিন-আশি চলমান গড় প্রবণতা
• এটিআর স্টপ ম্যানেজমেন্ট সহ ডিআই নির্দেশকগুলির উপর ভিত্তি করে কৌশল অনুসরণ করে গতিশীল অস্থিরতা-সংশোধিত প্রবণতা