1. 사각형
2. MACD-ATR-EMA 다중 지표 동적 추세 전략

MACD-ATR-EMA 다중 지표 동적 추세 전략

저자:차오장, 날짜: 2024-09-26 14:43:19
태그:MACDATREMASMA

---

---

/*backtest
start: 2024-08-26 00:00:00
end: 2024-09-25 00:00:00
period: 1h
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy("[ROOT] MACD, ATR, & EMA Strategy", overlay = true)

// Input parameters
macd_fast_length = input.int(12, title="MACD Fast Length")
macd_slow_length = input.int(26, title="MACD Slow Length")
macd_length = input.int(9, title="MACD Signal Length")
atr_length = input.int(14, title="ATR Length")
slow_ema_length = input.int(200, title="Slow EMA Length")
fast_ema_length = input.int(50, title="Fast EMA Length")
risk_per_trade = input.float(100, title="Risk % of Total Balance per Trade", minval=0.1, maxval=100, step=0.1)
swing_lookback = input.int(10, title="Swing High/Low Lookback Period", minval=1, maxval=50, step=1)
stop_loss_type = input.string("Swing Low/High", title="Stop Loss Type", options=["Swing Low/High", "ATR-Based"])
stop_loss_buffer = input.float(0.5, title="ATR Multiplier for Stop Loss", minval=0.1, step=0.1)
min_atr_threshold = input.float(0.1, title="Minimum ATR Threshold", minval=0.01, step=0.01)

// Calculate MACD
MACD = ta.ema(close, macd_fast_length) - ta.ema(close, macd_slow_length)
signal = ta.ema(MACD, macd_length)
macd_histogram = MACD - signal

// Calculate EMAs
slow_ema = ta.ema(close, slow_ema_length)
fast_ema = ta.ema(close, fast_ema_length)

// Plot EMAs
plot(slow_ema, color=color.white, linewidth=3, title="200 EMA")
plot(fast_ema, color=color.gray, linewidth=2, title="50 EMA")

// Calculate ATR for dynamic stop-loss
atr_value = ta.atr(atr_length)

// Determine recent swing high and swing low
recent_swing_high = ta.highest(high, swing_lookback)
recent_swing_low = ta.lowest(low, swing_lookback)

// Determine dynamic stop-loss levels based on user input
var float long_stop_loss = na
var float short_stop_loss = na

if (stop_loss_type == "Swing Low/High") 
    // Stop Loss based on recent swing low/high with a buffer
    long_stop_loss := recent_swing_low - (stop_loss_buffer * atr_value)
    short_stop_loss := recent_swing_high + (stop_loss_buffer * atr_value)
else if (stop_loss_type == "ATR-Based")
    // Stop Loss based purely on ATR
    long_stop_loss := close - (stop_loss_buffer * atr_value)
    short_stop_loss := close + (stop_loss_buffer * atr_value)

// Calculate position size based on percentage of total balance
capital_to_use = strategy.equity * (risk_per_trade / 100)
position_size = capital_to_use / close

// ATR Filter: Only trade when ATR is above the minimum threshold
atr_filter = atr_value > min_atr_threshold

// Buy and Sell Conditions with ATR Filter
long_condition = atr_filter and ta.crossover(MACD, signal) and close > slow_ema and close > fast_ema and MACD < 0 and signal < 0
short_condition = atr_filter and ta.crossunder(MACD, signal) and close < slow_ema and close < fast_ema and MACD > 0 and signal > 0

// Check if no open trades exist
no_open_trades = (strategy.opentrades == 0)

// Execute Buy Orders (only on bar close and if no trades are open)
if (long_condition and barstate.isconfirmed and no_open_trades)
    strategy.entry("Long", strategy.long, qty=position_size, stop=long_stop_loss)
    label.new(bar_index, low, "Buy", color=color.green, style=label.style_label_up, textcolor=color.white, size=size.small)

// Execute Sell Orders (only on bar close and if no trades are open)
if (short_condition and barstate.isconfirmed and no_open_trades)
    strategy.entry("Short", strategy.short, qty=position_size, stop=short_stop_loss)
    label.new(bar_index, high, "Sell", color=color.red, style=label.style_label_down, textcolor=color.white, size=size.small)

// Exit Conditions for Long and Short Positions (only on bar close)
long_exit_condition = close < fast_ema
short_exit_condition = close > fast_ema

if (long_exit_condition and barstate.isconfirmed)
    strategy.close("Long")

if (short_exit_condition and barstate.isconfirmed)
    strategy.close("Short")

// Alert Conditions (only on bar close)
alertcondition(long_condition and barstate.isconfirmed, title="Buy Alert", message="Buy Signal")
alertcondition(short_condition and barstate.isconfirmed, title="Sell Alert", message="Sell Signal")

// Exit Signal Alerts
alertcondition(long_exit_condition and barstate.isconfirmed, title="Long Exit Alert", message="Exit Long Signal")
alertcondition(short_exit_condition and barstate.isconfirmed, title="Short Exit Alert", message="Exit Short Signal")

---

• 다중 지표 융합 평균 반전 추세 전략
• 골든 모멘텀 캡처 전략: 멀티 타임프레임 기하급수적 이동 평균 크로스오버 시스템
• 유동성 높은 통화 쌍을 위한 단기 단기 판매 전략
• 옵션 거래 제안 시스템과 함께 다 기간 기하급수적 이동 평균 크로스오버 전략
• 상위 윗부분의 윗부분의 윗부분의 윗부분의 윗부분의
• 부피 기반의 동적 DCA 전략
• 엘리엇 파동 이론 4-9 충동 파동 자동 탐지 거래 전략
• ML 경고 템플릿
• 역동 다차원 분석과 함께 고급 멀티 타임프레임 Ichimoku 클라우드 거래 전략
• K의 반전 지표 I

---

• 다중 시간 프레임 RSI 과잉 매출 역전 전략
• 지능형 기관 거래 구조 추진 전략
• 가우스십 EMA 트렌드 리트레이싱 전략
• EMA MACD 모멘텀 추적 전략
• 역동적 위치 관리 RSI 과잉 매수 역전 전략
• 다 구역 RSI 거래 전략
• 기계 학습 향상된 리스크 관리와 함께 전략에 따라 역동적인 경향
• 평형 촛불 모멘텀 전략과 함께 크로스오버 이동 평균
• 일일 수익 목표와 함께 두 개의 이동 평균 크로스오버 전략
• 동적 스톱 로스 이동 평균 크로스오버 전략
• RSI 모멘텀 디버전스 브레이크업 전략
• 다중 지표 시너지 장기 거래 전략
• 골든 모멘텀 캡처 전략: 멀티 타임프레임 기하급수적 이동 평균 크로스오버 시스템
• 트리플 슈퍼트렌드 크로스오버 전략
• 역동 다차원 분석과 함께 고급 멀티 타임프레임 Ichimoku 클라우드 거래 전략
• 이중 이동 평균 추진력 거래 전략: 시간 최적화 트렌드 추적 시스템
• 포괄적인 출구 조건으로 강화된 EMA/WMA 크로스오버 전략
• 슈퍼트렌드와 EMA의 크로스오버 양적 거래 전략
• EMA, SMA, 이동 평균 크로스오버, 모멘텀 지표
• SMA 크로스오버 전략과 적정 가치 격차 풀백을 결합한 포괄적인 거래 시스템