وسائل لوڈ ہو رہے ہیں... لوڈنگ...
  1. مربع
  2. RSI اصلاح کے نظام کے ساتھ ڈبل ٹائم فریم سپر ٹرینڈ

RSI اصلاح کے نظام کے ساتھ ڈبل ٹائم فریم سپر ٹرینڈ

مصنف:چاؤ ژانگ، تاریخ: 2024-11-25 17:27:21
ٹیگز:آر ایس آئیاے ٹی آر

img

جائزہ

یہ حکمت عملی سپر ٹرینڈ اشارے اور آر ایس آئی پر مبنی ایک دوہری ٹائم فریم ٹریڈنگ سسٹم ہے۔ یہ 120 منٹ اور 15 منٹ کے ٹائم فریم سے تکنیکی تجزیہ کے اشارے کو جوڑتا ہے ، جس میں منافع لینے کے لئے آر ایس آئی کا استعمال کرتے ہوئے درمیانی مدتی رجحان کی سمت کو حاصل کرنے کے لئے سپر ٹرینڈ کا استعمال ہوتا ہے۔ حکمت عملی فیصد الاٹمنٹ کے ذریعہ پوزیشن سائزنگ کو نافذ کرتی ہے اور اس میں فیصد پر مبنی منافع لینے کی شرائط شامل ہیں۔

حکمت عملی کے اصول

بنیادی منطق کئی اہم عناصر پر مبنی ہے:

  1. 120 منٹ کے ٹائم فریم سپر ٹرینڈ اشارے کو اہم رجحان کا تعین کرنے کے آلے کے طور پر استعمال کرتا ہے ، جس میں اے ٹی آر کی مدت 14 اور فیکٹر 3.42 ہے۔
  2. سپر ٹرینڈ لائن کے ساتھ قیمت کراسور کے ذریعے تجارتی سگنل تیار کرتا ہے - لمبی اندراجات کے لئے اوپر کی کراس اور مختصر اندراجات کے لئے نیچے کی کراس
  3. 15 منٹ کے ٹائم فریم آر ایس آئی اشارے کا استعمال کرتا ہے جس میں مدت 5 ہے جو مارکیٹ کی زیادہ خرید / زیادہ فروخت کی حالتوں کے لئے ایک اضافی آلہ ہے
  4. جب RSI زیادہ خریدے گئے زون (95) تک پہنچ جاتا ہے تو طویل پوزیشنیں بند کردیتی ہیں اور زیادہ فروخت والے زون (5) میں مختصر پوزیشنیں
  5. اوسط اندراج کی قیمت کے مقابلے میں حساب لگایا 30٪ منافع لینے کی سطح مقرر کرتا ہے

حکمت عملی کے فوائد

  1. متعدد ٹائم فریم کا امتزاج سگنل کی وشوسنییتا کو بہتر بناتا ہے اور جھوٹے سگنل کو کم کرتا ہے
  2. زیادہ سے زیادہ ٹریڈنگ سے بچنے کے ساتھ ساتھ بہتر سپر ٹرینڈ پیرامیٹرز ٹرینڈ حساسیت کو متوازن کرتے ہیں
  3. سخت RSI انتہائی اقدار (5 اور 95) صرف انتہائی حالات میں پوزیشن بند کرنے کو یقینی بناتے ہیں
  4. پوزیشن سائزنگ میں ایکویٹی کا مقررہ فیصد (35٪) استعمال کیا جاتا ہے ، جو منافع کی صلاحیت کو برقرار رکھتے ہوئے خطرہ کو مؤثر طریقے سے کنٹرول کرتا ہے
  5. خودکار طور پر نئی پوزیشن کھولنے سے پہلے ریورس پوزیشن بند کرتا ہے، بیک وقت طویل اور مختصر نمائش سے بچنے کے

حکمت عملی کے خطرات

  1. ڈبل ٹائم فریم نقطہ نظر مختلف مارکیٹوں میں تاخیر پیدا کرسکتا ہے ، جس سے ڈراؤنڈ مینجمنٹ کی ضرورت ہوتی ہے
  2. سخت RSI انتہائی اقدار منافع لینے کے مواقع کو کھو سکتے ہیں
  3. 30٪ منافع لینے کی سطح جارحانہ ہے، ممکنہ طور پر اتار چڑھاؤ مارکیٹوں میں ابتدائی باہر نکلنے کی قیادت
  4. سٹاپ نقصان کی شرائط کی عدم موجودگی کے نتیجے میں اچانک رجحان کی تبدیلی کے دوران اہم نقصانات ہوسکتے ہیں
  5. 35٪ پوزیشن سائزنگ نسبتاً جارحانہ ہے، انتہائی اتار چڑھاؤ کے دوران اعلی خطرہ پیدا کرتی ہے

اصلاح کی ہدایات

  1. اے ٹی آر پر مبنی ٹرائلنگ اسٹاپ کو مدنظر رکھتے ہوئے متحرک اسٹاپ نقصان کے طریقہ کار کو شامل کرنے کی سفارش کریں
  2. بہتر موافقت کے لیے آر ایس آئی کی زیادہ خرید/زیادہ فروخت کی حدوں کو 10 اور 90 پر ایڈجسٹ کیا جا سکتا ہے۔
  3. سگنل کی تصدیق کے لئے حجم کے اشارے شامل کیے جاسکتے ہیں
  4. اے ٹی آر یا اتار چڑھاؤ کے اشارے کا استعمال کرتے ہوئے مارکیٹ کی اتار چڑھاؤ پر مبنی متحرک پوزیشن سائزنگ پر غور کریں
  5. کمزور رجحانات کو فلٹر کرنے کے لئے ڈی ایم آئی یا اے ڈی ایکس جیسے رجحان کی طاقت فلٹرز کو شامل کرنے کا مشورہ دیتے ہیں

خلاصہ

یہ واضح منطق کے ساتھ ایک اچھی طرح سے منظم رجحان کی پیروی کرنے والی حکمت عملی ہے۔ یہ خطرہ کنٹرول کو برقرار رکھتے ہوئے رجحانات کو حاصل کرنے کے لئے مختلف ٹائم فریم تکنیکی اشارے کو جوڑتا ہے۔ اگرچہ اصلاح کی گنجائش ہے ، لیکن مجموعی ڈیزائن مقداری تجارتی اصولوں کے مطابق ہے۔ تاجروں کو براہ راست تجارت سے پہلے پیرامیٹرز کو بیک ٹیسٹ اور بہتر بنانا چاہئے اور اپنی رسک رواداری کے مطابق پوزیشن سائزنگ کو ایڈجسٹ کرنا چاہئے۔

/*backtest
start: 2024-10-01 00:00:00
end: 2024-10-31 23:59:59
period: 1h
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © felipemiransan

//@version=5
strategy("Supertrend Strategy", overlay=true)

// Function for Supertrend
supertrend(_factor, _atrPeriod) =>
    [out, _] = ta.supertrend(_factor, _atrPeriod)
    out

// Supertrend Settings
factor = input.float(3.42, title="Supertrend Factor")
atrPeriod = input.int(14, title="ATR Period")
tf2 = input.timeframe("120", title="Supertrend Timeframe")

// RSI Settings
rsi_tf = input.timeframe("15", title="RSI Timeframe")
rsiLength = input.int(5, title="RSI Length")
rsiUpper = input.int(95, title="RSI Upper Limit")  
rsiLower = input.int(5, title="RSI Lower Limit")   

// RSI Timeframe
rsi_tf_value = request.security(syminfo.tickerid, rsi_tf, ta.rsi(close, rsiLength), lookahead=barmerge.lookahead_off, gaps=barmerge.gaps_off)

// Supertrend Timeframe
supertrend_tf2 = request.security(syminfo.tickerid, tf2, supertrend(factor, atrPeriod), lookahead=barmerge.lookahead_off, gaps=barmerge.gaps_off)

// Take Profit Settings (Percentage in relation to the average price)
takeProfitPercent = input.float(30, title="Take Profit", step=0.1) / 100

// Entry conditions based on price crossover with Supertrend Timeframe
longCondition = ta.crossover(close, supertrend_tf2) and barstate.isconfirmed
shortCondition = ta.crossunder(close, supertrend_tf2) and barstate.isconfirmed

// Execution of reversal orders with closing of previous position
if (longCondition)
    // Close a short position before opening a long position
    if (strategy.position_size < 0)
        strategy.close("Short", comment="Close Short for Long Entry")
    strategy.entry("Long", strategy.long)

if (shortCondition)
    // Close long position before opening short position
    if (strategy.position_size > 0)
        strategy.close("Long", comment="Close Long for Short Entry")
    strategy.entry("Short", strategy.short)

// Calculate take profit levels relative to the average entry price
if (strategy.position_size > 0)
    takeProfitLong = strategy.position_avg_price * (1 + takeProfitPercent)
    strategy.exit("Take Profit Long", "Long", limit=takeProfitLong)

if (strategy.position_size > 0 and (rsi_tf_value >= rsiUpper))
    strategy.close("Long", comment="RSI Take Profit Long")

if (strategy.position_size < 0)
    takeProfitShort = strategy.position_avg_price * (1 - takeProfitPercent)
    strategy.exit("Take Profit Short", "Short", limit=takeProfitShort)

if (strategy.position_size < 0 and (rsi_tf_value <= rsiLower))
    strategy.close("Short", comment="RSI Take Profit Short")

// Plot Supertrend timeframe with commit check to avoid repainting
plot(barstate.isconfirmed ? supertrend_tf2 : na, color=color.blue, title="Supertrend Timeframe (120 min)", linewidth=1)

// Plot RSI for visualization
plot(rsi_tf_value, "RSI", color=color.purple)
hline(rsiUpper, "RSI Upper", color=color.red)
hline(rsiLower, "RSI Lower", color=color.green)
متعلقہ
مزید

2019 FMZ - تمام حقوق محفوظ ہیں